Johannes 的榨汁机

类是面向对象编程中的核心概念。 在 Crystal 中，一切都是对象，每个对象都有类型，并且能响应某些方法。 类是创建对象的蓝图，它为状态（例如变量）提供初始值，并提供行为的实现（例如方法）。 对象是类的实例，它持有所有实例变量和状态。

类的定义

使用 class 关键字定义类，后面跟上用 UpperCamelCase 写成的类名。

class Account
end

创建实例

要创建类的实例，可以对类名调用 new 方法。

class Account
end

account = Account.new

在上面的例子中，变量account是类Account的一个实例。

创建实例时，一个名为 initialize 的特殊方法充当构造函数。 实例被创建时就会调用它。 构造函数让你可以设置实例的初始状态。 initialize 方法可以接收实参，这些实参在创建实例时传入。

class Account
  def initialize(number)
    5 + number # => 9
  end
end

Account.new(4)

class Account
  def initialize(number)
    5 + number
  end
end

Account.new(4)
# => #<Account:0x7f5dc33dcea0>

实例方法

实例方法是类的实例可以使用的方法，可以在该实例上调用。 实例方法使用 def 关键字定义，后面跟上方法名。 它们定义在类定义的内部。

class Account
  def balance
    100
  end
end

account = Account.new
account.balance # => 100

实例变量

实例变量是在实例的所有方法中都可以使用的变量。 要访问实例变量，你需要定义一个实例方法。 它们可以在 initialize 方法中初始化。 它们使用 @ 前缀定义。

class Account
  def initialize
    @balance = 100
  end

  def balance
    @balance
  end
end

account = Account.new
account.balance
# => 100

实例变量也可以定义在类定义内部。

class Account
  @age = 0
end

带初始化的实例变量

实例变量可以用传给 initialize 方法的实参来初始化。 由于 Crystal 无法推断初始化时所用实参的类型，因此必须显式指定类型。 如果你想了解更多，可以阅读：类型推断。 要指定变量的类型，可以使用 : 符号，后面跟上类型。 例如，如果你想创建一个名为 balance、类型为 Int32 的实例变量，可以这样写：@balance : Int32。 或者，如果你想创建一个名为 raining、类型为 Bool 的实例变量，可以这样写：@raining : Bool。

有几种实现方式。一种是在 initialize 方法中声明带类型的实参，然后把实例变量赋值为该实参，如下例所示：

class Account
  def initialize(balance : Int32)
    @balance = balance
  end

  def balance
    @balance
  end
end

account = Account.new(1)
account_2 = Account.new(5)

account.balance
# => 1

account_2.balance
# => 5

另一种方式是在类定义中声明实例变量的类型，形式为 @<variable> : <Type>，如下例所示：

class Weather

  @raining : Bool

  def initialize(raining)
    @raining = raining
  end

  def raining
    @raining
  end
end

weather = Weather.new(true)
weather.raining
# => true

修改实例变量

方法可以修改实例变量。 这些方法可以在类的实例上调用。 当方法修改实例变量时，这一改动只在你调用它的那个实例中生效。

class Account
  def initialize(balance : Int32)
    @balance = balance
  end

  def withdraw(amount)
    @balance -= amount
  end

  def balance
    @balance
  end
end

account = Account.new(10)
account_2 = Account.new(10)
account.balance
# => 10

account_2.balance
# => 10

account.withdraw(5)
account.balance
# => 5

account_2.balance
# => 10

类方法

类方法是为类而非类的实例定义的方法。 它们让你可以创建不依赖实例状态的方法。 它们使用 def 关键字定义，后面跟上 self.<method name>。 self 是对调用 self 时所处的命名空间的引用。 在这里，它指的是类 Account。 这与你写成 Account. 是一样的，但 self. 是更推荐的方式。

class Account
  def self.balance
    100
  end
end

Account.balance
# => 100