Johannes 的果汁機

類別是物件導向程式設計中的核心概念。 在 Crystal 中，萬物皆為物件，每個物件都有型別，並且能回應某些方法。 類別是建立物件的藍圖，為狀態（例如變數）提供初始值，並提供行為的實作（例如方法）。 物件是類別的實例，持有所有實例變數與狀態。

類別定義

使用class關鍵字定義類別，後面接著以UpperCamelCase撰寫的類別名稱。

class Account
end

建立實例

若要建立類別的實例，請使用new方法呼叫類別名稱。

class Account
end

account = Account.new

在上面的範例中，變數account是類別Account的實例。

建立實例時，一個名為initialize的特殊方法會扮演建構子的角色。 建立實例時會呼叫它。 建構子讓你設定實例的初始狀態。 initialize方法可以接受引數，並在建立實例時傳入。

class Account
  def initialize(number)
    5 + number # => 9
  end
end

Account.new(4)

class Account
  def initialize(number)
    5 + number
  end
end

Account.new(4)
# => #<Account:0x7f5dc33dcea0>

實例方法

實例方法是可供類別實例使用的方法，並且可以在該實例上呼叫。 實例方法使用def關鍵字定義，後面接著方法名稱。 它們定義在類別定義內。

class Account
  def balance
    100
  end
end

account = Account.new
account.balance # => 100

實例變數

實例變數是實例中所有方法都能使用的變數。 若要存取實例變數，你需要定義一個實例方法。 它們可以在initialize方法中初始化。 它們使用@前綴定義。

class Account
  def initialize
    @balance = 100
  end

  def balance
    @balance
  end
end

account = Account.new
account.balance
# => 100

實例變數也可以定義在類別定義內。

class Account
  @age = 0
end

帶初始化的實例變數

實例變數可以使用傳入initialize方法的引數來初始化。 由於 Crystal 無法推斷初始化時所用引數的型別，因此必須明確指定。 如果你想進一步了解，可以閱讀：型別推斷。 若要指定變數的型別，可以使用:符號，後面接著型別。 例如，如果你想建立一個型別為Int32、名為balance的實例變數，可以這麼做：@balance : Int32。 或者，如果你想建立一個型別為Bool、名為raining的實例變數，可以這麼做：@raining : Bool。

有幾種實作方式，其中一種是在initialize方法中將引數宣告為該型別，再將實例變數指定給該引數，如下面的範例：

class Account
  def initialize(balance : Int32)
    @balance = balance
  end

  def balance
    @balance
  end
end

account = Account.new(1)
account_2 = Account.new(5)

account.balance
# => 1

account_2.balance
# => 5

另一種方式是在類別定義中，以下列形式宣告實例變數的型別：@<variable> : <Type>，如下面的範例：

class Weather

  @raining : Bool

  def initialize(raining)
    @raining = raining
  end

  def raining
    @raining
  end
end

weather = Weather.new(true)
weather.raining
# => true

修改實例變數

方法可以修改實例變數。 這些方法可以在類別的實例上呼叫。 當方法修改實例變數時，該變更只會在呼叫它的那個類別實例中生效。

class Account
  def initialize(balance : Int32)
    @balance = balance
  end

  def withdraw(amount)
    @balance -= amount
  end

  def balance
    @balance
  end
end

account = Account.new(10)
account_2 = Account.new(10)
account.balance
# => 10

account_2.balance
# => 10

account.withdraw(5)
account.balance
# => 5

account_2.balance
# => 10

類別方法

類別方法是為類別定義、而非為其實例定義的方法。 它們提供了一種建立不依賴實例狀態之方法的方式。 它們使用def關鍵字定義，後面接著self.<method name>。 self是對呼叫 self 時所在命名空間的參照。 在這個例子中，它指的是類別Account。 這等同於撰寫Account.，但self.是較建議的寫法。

class Account
  def self.balance
    100
  end
end

Account.balance
# => 100