轨道
/
Factor
Factor
/
练习
/
日志级别
日志级别

日志级别

学习练习

简介

Factor 中的字符串是字符序列。sequences词汇表中的大多数单词都能作用于字符串,此外还有 splitting、ascii等词汇表中专门处理字符串的单词。

字符串字面量

字符串用双引号书写。常见的转义都支持:\n、\t、\r、\\、\":

"hello, world" .                 ! => "hello, world"
"first\nsecond" print            ! prints two lines

长度与下标

因为字符串是序列,sequences词汇表中的length和nth等单词可以直接作用于它。

length返回字符的数量:

"hello" length .    ! => 5

nth接受一个从 0 开始的下标和序列,返回该位置上的元素。对于字符串来说,元素是一个字符,也就是一个码点(一个整数),而不是长度为 1 的子字符串:

0 "hello" nth .     ! => 104   (CHAR: h)
4 "hello" nth .     ! => 111   (CHAR: o)

从字符回到字符串

要把单个码点变成只含一个字符的字符串,可以使用 strings词汇表中的1string ( char -- str )。CHAR:是字面量码点在解析期的写法:

CHAR: A 1string .                ! => "A"
0 "hello" nth 1string .          ! => "h"

拆分

splitting词汇表能把字符串切成若干片段。

split1在分隔符第一次出现的位置切开,返回前后两部分:

split1 ( seq subseq -- before after )
"foo: bar" ": " split1 .s
! => "foo"
! => "bar"

split按分隔符集合中任意一个字符切开,可能产生空片段:

"[ERROR]: Stack overflow" "[]" split .
! => { "" "ERROR" ": Stack overflow" }

harvest(位于sequences中)会丢弃空片段:

"[ERROR]: Stack overflow" "[]" split harvest .
! => { "ERROR" ": Stack overflow" }

取出某个片段

字符串被拆分成由片段组成的数组后,first、second、third和fourth(位于sequences中)会返回对应位置上的片段:

"apple,bee,carrot,duck" "," split first .    ! => "apple"
"apple,bee,carrot,duck" "," split second .   ! => "bee"
"apple,bee,carrot,duck" "," split third .    ! => "carrot"
"apple,bee,carrot,duck" "," split fourth .   ! => "duck"

如果想一次把所有开头的片段都放到栈上,first2和first3可以一步取出两个或三个:

"apple,bee,carrot,duck" "," split first2 .s
! => "apple"
! => "bee"

"apple,bee,carrot,duck" "," split first3 .s
! => "apple"
! => "bee"
! => "carrot"

直接对字符串使用时,first返回的是第一个字符,也就是一个码点,而不是子字符串:

"hello" first .                         ! => 104   (CHAR: h)

去除空白

[ blank? ] trim(来自sequences,其中的blank?来自ascii词汇表)会去除首尾空白:

"  Disk full \r\n" [ blank? ] trim .
! => "Disk full"

大小写转换

>lower和>upper(来自ascii)会返回一个改变了大小写的新字符串:

"WARNING" >lower .    ! => "warning"
"hello" >upper .      ! => "HELLO"

连接

sequences词汇表中的两个单词可以拼装字符串:

surround用前缀和后缀把字符串包起来:

surround ( seq pre post -- new-seq )
"warning" "(" ")" surround .    ! => "(warning)"

glue用分隔符把两个字符串连起来:

glue ( s1 s2 sep -- s )
"Disk full" "(error)" " " glue .    ! => "Disk full (error)"

说明

在本练习中,你将处理日志行。

每个日志行都是一个格式为 "[<LEVEL>]: <MESSAGE>" 的字符串。

日志共有三个级别:INFO、WARNING 和 ERROR。

你有三个任务。每个任务从栈中取出一条日志行。

1. 从日志行中获取消息

定义 message,让它返回日志行中的消息。开头和结尾的所有空白字符都应去掉。

"[ERROR]: Invalid operation" message .
! => "Invalid operation"

"[WARNING]:  Disk almost full\r\n" message .
! => "Disk almost full"

2. 从日志行中获取日志级别

定义 log-level,返回日志行的级别,并转换为小写。

"[ERROR]: Invalid operation" log-level .
! => "error"

3. 重新格式化日志行

定义 reformat,把消息放在最前面,并在后面用括号加上小写的日志级别。

"[INFO]: Operation completed" reformat .
! => "Operation completed (info)"

注意: 本练习中的所有字符串都是 ASCII。后续练习会处理支持 Unicode 的字符串。

通过 GitHub 编辑 链接将在新窗口或新标签页中打开
Factor Exercism

准备好开始 日志级别 了吗?

注册 Exercism,借助 47 个概念163 个练习 和真人导师指导,学习并掌握 Factor,全部免费。