Una cadena de caracteres en Factor es una secuencia de caracteres. La mayoría de las palabras del vocabulario sequences funcionan con strings, además de las palabras dedicadas al manejo de strings que hay en splitting, ascii y compañía.
Los strings se escriben entre comillas dobles. Se admiten los escapes habituales, como \n, \t, \r, \\, \":
"hello, world" . ! => "hello, world"
"first\nsecond" print ! prints two lines
Como un string es una secuencia, las palabras length y nth de sequences funcionan directamente sobre él.
length devuelve el número de caracteres:
"hello" length . ! => 5
nth recibe un índice que empieza en 0 y la secuencia, y devuelve el elemento que está en esa posición. En el caso de un string, el elemento es un carácter, es decir, un punto de código (un número entero), no una subcadena de un solo carácter:
0 "hello" nth . ! => 104 (CHAR: h)
4 "hello" nth . ! => 111 (CHAR: o)
Para convertir un único punto de código en un string de un solo carácter, usa 1string ( char -- str ), del vocabulario strings. CHAR: es la forma en tiempo de análisis de un punto de código literal:
CHAR: A 1string . ! => "A"
0 "hello" nth 1string . ! => "h"
El vocabulario splitting corta un string en fragmentos.
split1 corta por la primera aparición de un separador y devuelve ambas mitades:
split1 ( seq subseq -- before after )
"foo: bar" ": " split1 .s
! => "foo"
! => "bar"
split corta por cualquiera de los caracteres de un conjunto de separadores y puede producir fragmentos vacíos:
"[ERROR]: Stack overflow" "[]" split .
! => { "" "ERROR" ": Stack overflow" }
harvest (en sequences) descarta los fragmentos vacíos:
"[ERROR]: Stack overflow" "[]" split harvest .
! => { "ERROR" ": Stack overflow" }
Una vez que un string se ha dividido en un array de fragmentos, first, second, third y fourth (en sequences) devuelven el fragmento que está en esa posición:
"apple,bee,carrot,duck" "," split first . ! => "apple"
"apple,bee,carrot,duck" "," split second . ! => "bee"
"apple,bee,carrot,duck" "," split third . ! => "carrot"
"apple,bee,carrot,duck" "," split fourth . ! => "duck"
Cuando quieras tener en la pila todos los fragmentos iniciales a la vez, first2 y first3 desempaquetan dos o tres de ellos en un solo paso:
"apple,bee,carrot,duck" "," split first2 .s
! => "apple"
! => "bee"
"apple,bee,carrot,duck" "," split first3 .s
! => "apple"
! => "bee"
! => "carrot"
Aplicado a un string, first devuelve el primer carácter, un punto de código, en lugar de una subcadena:
"hello" first . ! => 104 (CHAR: h)
[ blank? ] trim (de sequences, con blank? del vocabulario ascii) elimina los espacios en blanco al principio y al final:
" Disk full \r\n" [ blank? ] trim .
! => "Disk full"
>lower y >upper (de ascii) devuelven un string nuevo con las mayúsculas y minúsculas cambiadas:
"WARNING" >lower . ! => "warning"
"hello" >upper . ! => "HELLO"
Dos palabras de sequences construyen strings:
surround envuelve un string con un prefijo y un sufijo:
surround ( seq pre post -- new-seq )
"warning" "(" ")" surround . ! => "(warning)"
glue une dos strings con un separador entre ellos:
glue ( s1 s2 sep -- s )
"Disk full" "(error)" " " glue . ! => "Disk full (error)"
En este ejercicio vas a procesar líneas de registro.
Cada línea de registro es un string con el formato "[<LEVEL>]: <MESSAGE>".
Hay tres niveles de registro: INFO, WARNING y ERROR.
Tienes tres tareas. Cada una recibe una única línea de registro de la pila.
Define message para que devuelva el mensaje de la línea de registro. Hay que eliminar los espacios en blanco que haya al principio y al final.
"[ERROR]: Invalid operation" message .
! => "Invalid operation"
"[WARNING]: Disk almost full\r\n" message .
! => "Disk almost full"
Define log-level para que devuelva el nivel de la línea de registro, en minúsculas.
"[ERROR]: Invalid operation" log-level .
! => "error"
Define reformat para que ponga el mensaje primero y, a continuación, el nivel de registro en minúsculas entre paréntesis.
"[INFO]: Operation completed" reformat .
! => "Operation completed (info)"
Nota: Todos los strings de este ejercicio son ASCII. En ejercicios posteriores se abordará el tratamiento de strings con Unicode.
Regístrate en Exercism para aprender y dominar Factor con 47 conceptos163 ejercicios y mentoría humana real, todo gratis.