观鸟者

数组

F# 中的array是一种可变集合，包含零个或多个值，且长度固定。也就是说，数组一旦创建，它的大小就无法改变，但其中的值可以改变。数组中的所有值必须具有相同的类型。数组可以这样定义：

let empty = [| |]
let emptyAlternative = Array.empty

let singleValue = [| 5 |]
let singleValueAlternative = Array.singleton 5

let threeValues = [| "a"; "b"; "c" |]

可以使用下标给数组中的元素赋值，也可以用它从中取值。F# 数组的下标从零开始，也就是说，第一个元素的下标始终是零：

let numbers = [| 2; 3; 5 |]

// Update value in array
numbers[2] <- 9

// Read value from array
numbers[2]
// => 9

操作数组的方式有两种：使用Array模块中定义的函数和运算符，或者使用 数组 模式手动进行模式匹配：

let describe array =
    match array with
    | [| |] -> "Empty"
    | [| 1; 2; three |] -> sprintf "1, 2, %d" three
    | _ -> "Other"

describe [| |]         // => "Empty"
describe [| 1; 2; 4 |] // => "1, 2, 4"
describe [| 5; 7; 9 |] // => "Other"

在模式匹配时，你也可以 丢弃 某个值；当你在某个具体分支中不关心某个值时（也就是说，你不会_使用_这个值），可以用一个下划线（'_'）来表示：

let describe array =
    match array with
    | [| |] -> "Empty array"
    | [| x |] -> "Array with one item"
    | [| _; y |] -> "Array with two items (first item ignored)"
    | _ -> "Array with many items (all items ignored)"

describe [| |]          // => "Empty array"
describe [| 1 |]        // => "Array with one item"
describe [| 5; 7 |]     // => "Array with two items (first item ignored)"
describe [| 5; 7; 9 |]  // => "Array with many items (all items ignored)"

模式匹配时，单个'_'应该始终放在_最后_，所有与其它分支都不匹配的值都会由这个分支来处理。