賞鳥者

陣列

F# 中的array是一個可變的集合，內含零個或多個值，長度固定。這表示陣列一旦建立，大小就無法改變，但裡面的值可以改變。陣列中的值必須全部是相同的型別。陣列可以這樣定義：

let empty = [| |]
let emptyAlternative = Array.empty

let singleValue = [| 5 |]
let singleValueAlternative = Array.singleton 5

let threeValues = [| "a"; "b"; "c" |]

可以使用索引將元素指定到陣列中，或從陣列取出元素。F# 陣列以零為基準，也就是第一個元素的索引永遠是零：

let numbers = [| 2; 3; 5 |]

// Update value in array
numbers[2] <- 9

// Read value from array
numbers[2]
// => 9

操作陣列的方式，可以是使用Array模組中定義的函式和運算子，也可以使用 array 模式手動進行模式比對：

let describe array =
    match array with
    | [| |] -> "Empty"
    | [| 1; 2; three |] -> sprintf "1, 2, %d" three
    | _ -> "Other"

describe [| |]         // => "Empty"
describe [| 1; 2; 4 |] // => "1, 2, 4"
describe [| 5; 7; 9 |] // => "Other"

在模式比對時，你也可以_捨棄_某個值；當你在某個情況下_不_在意某個值（也就是你不打算_使用_這個值）時，可以用底線（'_'）來表示：

let describe array =
    match array with
    | [| |] -> "Empty array"
    | [| x |] -> "Array with one item"
    | [| _; y |] -> "Array with two items (first item ignored)"
    | _ -> "Array with many items (all items ignored)"

describe [| |]          // => "Empty array"
describe [| 1 |]        // => "Array with one item"
describe [| 5; 7 |]     // => "Array with two items (first item ignored)"
describe [| 5; 7; 9 |]  // => "Array with many items (all items ignored)"

在模式比對時，單獨的'_'一定要放在_最後_，任何_不符合_其他情況的值，都會由這個情況來處理。