程序员一般都力求写出完美的软件，但往往做不到。
事情总会出乎意料地出错，而我们需要有能力应对。
有些语言设计者认为，首要任务是尽快检测到错误，然后终止执行，并给出一条有助于调试的提示信息。
数据科学类的语言往往采取更细腻的做法。有些错误非常严重，必须立即终止；但很多时候，更好的做法是把问题标记出来留待以后处理，然后继续执行。
我们在空值概念中看到，Julia 为有问题的值提供了各种占位符：missing、NaN 和 Inf。在具体情况下，这些做法是否比直接终止程序更好，要由程序员自己判断。
关于命名的一点说明：在展开细节之前先讲清楚，Julia 文档基本把 “error” 和 “exception” 这两个词当作可以互换使用。下文的用法可能同样前后不一致。
标准错误类型
学到这里，你一定已经见过很多 Julia 给出的错误信息了。例如：
julia> Int(3.14)
ERROR: InexactError: Int64(3.14)
把浮点数转换为整数会损失精度，所以会得到 InexactError。
InexactError 是一个类型，是 Julia 内置的若干标准类型之一（目前有 25 种）。它们全都是 Exception 的子类型：
julia> supertype(InexactError)
Exception
throw()
有些标准错误类型，你可能也会想在自己的代码里抛出。
和所有具体类型一样，这些错误也有构造函数。它们接受的实参各不相同，所以要使用哪一种，请查阅文档。
julia> DomainError(42, "out of range")
DomainError(42, "out of range")
要使用这个错误，把构造函数包在 throw() 函数里：
julia> throw(DomainError(42, "out of range"))
ERROR: DomainError with 42:
out of range
error()
如果只想简单粗暴地处理，error() 函数会很方便。它接受一个字符串（或字符串的各个组成部分）作为实参：
julia> happy = false;
julia> happy || error("😞 something went wrong")
ERROR: 😞 something went wrong
自定义错误
创建新的错误类型原则上非常简单。只要再加一个 Exception 的子类型即可：
julia> struct MyError <: Exception end
julia> throw(MyError)
ERROR: MyError
断言
断言的基本想法是：“这个判定应该是真的，如果是假的就大声报错。” 它的价值主要体现在调试期间，因为生产代码不应该让断言失败。
我们在类型概念中看到，可以添加类型断言，比如用来检查函数的返回值类型。
julia> 42::Number
42
julia> "two"::Number
ERROR: TypeError: in typeassert, expected Number, got a value of type String
更一般地说，@assert 宏可以测试任何求值为布尔值的表达式：
julia> n = 22;
julia> @assert isodd(n) "n must be odd"
ERROR: AssertionError: n must be odd
try...catch
有些错误必然是致命的，但很多时候我们希望程序能优雅地恢复。
默认情况下，错误会立即终止当前函数，并把错误（连同任何提示信息）传给调用它的函数。
这样一路沿着调用栈向上传递，直到顶层代码带着错误信息终止。
在任何一层，都可以用 try...catch 块拦截错误并尝试处理它。
julia> n = -1;
julia> try
log_n = log(n)
catch problem
if problem isa DomainError # number out of range
# See next section for more on @warn and @info
@warn "you may have supplied a negative real number: $n"
@info "trying with complex argument"
log_n = log(Complex(n)) # fallback calculation
elseif problem isa MethodError # no idea what n is
@error "please supply a valid argument"
else
rethrow() # the error could be anything else
end
end
┌ Warning: you may have supplied a negative real number: -1
└ @ Main REPL[3]:5
[ Info: trying with complex argument
0.0 + 3.141592653589793im # success
在上面的例子里，log(n) 要求 n 要么是正实数，要么是任意的复数。try ... catch 会捕获负实数带来的问题，并返回用数学记号表示的正确答案 iπ。
比如，如果你传入的是字符串实参，那就无法恢复，只能请用户改正。
作为最后的兜底，我们加了 rethrow()，用来处理既不是 DomainError 也不是 MethodError 的情况。
***注意：***有时候 try...catch 确实是你需要的，但请避免过度使用。如果能改用 if...else 块，它的性能会比捕获异常好得多。
日志记录
注意，前面讨论的 error() 函数，不要和 @error 宏混淆。
这个函数会生成一个异常，除非被捕获，否则它会沿着调用栈向上传递。
@error 宏和它的 @debug、@info、@warn 同类一样，属于 Logging 模块，目的是生成提示信息而不改变程序的执行流程。
默认情况下，输出会送到终端（按严重程度用颜色区分），不过在真实的应用程序里还有很多其他可能。
julia> @warn "Something looks not quite right"
┌ Warning: Something looks not quite right
└ @ Main REPL[55]:1
julia> @error "Panic!"
┌ Error: Panic!
└ @ Main REPL[56]:1
另请参见前面 try...catch 一节的示例。
学习练习
