程式設計師通常會努力寫出完美的軟體，但通常都會失敗。
事情總是會出乎意料地出錯，而我們必須有能力處理這些狀況。
有些語言設計者認為，首要之務是盡快偵測到錯誤，然後結束執行，並附上有助於除錯的說明訊息。
資料科學領域的語言則傾向採取更細膩的做法。
有些錯誤嚴重到必須立刻結束程式，但很多時候，比較好的做法是把問題標記起來、留待之後處理，然後繼續執行。
我們在虛無概念中看過，Julia 針對有問題的值提供了各種佔位符號：missing、NaN和Inf。
在特定情況下，這些做法是否比結束程式更好，取決於程式設計師的判斷。
在深入細節之前，先說明一下用詞：Julia 的文件大致上把「error」和「exception」這兩個詞視為可互換。
底下的內容可能也同樣前後不一致。
標準錯誤型別
課程大綱進行到這裡，你一定已經看過不少 Julia 的錯誤訊息了吧。
例如：
julia> Int(3.14)
ERROR: InexactError: Int64(3.14)
把浮點數轉型成整數會損失精確度，因此會得到InexactError。
InexactError是一種型別，是 Julia 眾多內建標準型別（目前有 25 種）的其中之一。
它們全都是Exception的子型別：
julia> supertype(InexactError)
Exception
throw()
有些標準錯誤型別，或許在你自己的程式碼裡也用得上。
和所有具體型別一樣，這些錯誤也有建構子。
它們接受的引數各不相同，所以請查閱文件，了解你想用的那個型別。
julia> DomainError(42, "out of range")
DomainError(42, "out of range")
要使用這個錯誤，請把建構子包在throw()函式裡：
julia> throw(DomainError(42, "out of range"))
ERROR: DomainError with 42:
out of range
error()
如果想走快速簡便的路線，error()函式會很方便。
它接受一個字串（或字串的組成部分）作為引數：
julia> happy = false;
julia> happy || error("😞 something went wrong")
ERROR: 😞 something went wrong
自訂錯誤
建立新的錯誤型別，原則上非常簡單。
只要再加上一個Exception的子型別就行了：
julia> struct MyError <: Exception end
julia> throw(MyError)
ERROR: MyError
斷言
斷言的基本想法是「這個敘述應該是對的，如果不對就大聲抱怨」。
這個做法主要在除錯時有價值，因為正式環境的程式碼不應該讓斷言失敗。
我們在型別概念中看過，我們可以加上型別斷言，例如檢查函式的回傳型別。
julia> 42::Number
42
julia> "two"::Number
ERROR: TypeError: in typeassert, expected Number, got a value of type String
更一般地說，@assert巨集讓我們可以測試任何算出布林值的運算式：
julia> n = 22;
julia> @assert isodd(n) "n must be odd"
ERROR: AssertionError: n must be odd
try...catch
有些錯誤注定是致命的，但很多時候，我們希望程式能優雅地復原。
根據預設，錯誤會立刻結束目前的函式，並把這個錯誤（連同說明訊息）傳給呼叫它的函式。
這個過程會沿著呼叫堆疊一路往上，直到頂層程式碼帶著錯誤訊息結束為止。
在任何階段，都可以用try...catch區塊攔截這個錯誤，試著處理它。
julia> n = -1;
julia> try
log_n = log(n)
catch problem
if problem isa DomainError # number out of range
# See next section for more on @warn and @info
@warn "you may have supplied a negative real number: $n"
@info "trying with complex argument"
log_n = log(Complex(n)) # fallback calculation
elseif problem isa MethodError # no idea what n is
@error "please supply a valid argument"
else
rethrow() # the error could be anything else
end
end
┌ Warning: you may have supplied a negative real number: -1
└ @ Main REPL[3]:5
[ Info: trying with complex argument
0.0 + 3.141592653589793im # success
在上面的例子裡，log(n)需要n是正實數，或是任意的複數。
try ... catch會攔下負實數造成的問題，並以數學符號回傳正確的複數答案iπ。
如果你傳入的是字串之類的引數，那就沒得補救，只能請使用者修正。
作為最後的萬用防線，我們針對既不是DomainError也不是MethodError的情況加上了rethrow()。
注意： 有時候，try...catch正是你需要的，但請避免過度使用。
如果能改用if...else區塊，效能會比攔截例外好得多。
記錄
請注意，前面討論過的error()函式，別和@error巨集搞混了。
這個函式會產生例外，除非被攔截，否則它會沿著呼叫堆疊往上傳。
@error巨集和它的同伴@debug、@info和@warn一樣，都屬於Logging模組，用途是產生說明訊息，而不改變程式的流程。
輸出預設會送到終端機（並依嚴重程度標上顏色），不過在實際的應用程式裡，還有很多其他的可能性。
julia> @warn "Something looks not quite right"
┌ Warning: Something looks not quite right
└ @ Main REPL[55]:1
julia> @error "Panic!"
┌ Error: Panic!
└ @ Main REPL[56]:1
也請參考前面try...catch一節的範例。
學習練習
