مستشعرات المصنع

يحاول المبرمجون عمومًا كتابة برمجيات مثالية، وغالبًا ما يفشلون.

تسير الأمور على نحو خاطئ، وبشكل غير متوقع، ونحتاج إلى القدرة على التعامل مع ذلك.

يعتقد بعض مصممي اللغات أن الأولوية هي اكتشاف الخطأ بأسرع ما يمكن، ثم إنهاء التنفيذ برسالة مفيدة تساعد في تصحيح الأخطاء.

أما لغات علم البيانات فتميل إلى اتباع أسلوب أكثر دقة. فبعض الأخطاء خطيرة لدرجة أن الإنهاء الفوري ضروري، لكن غالبًا ما يكون من الأفضل الإشارة إلى المشكلة على أنها شيء يجب التعامل معه لاحقًا، ثم متابعة التنفيذ.

رأينا في مفهوم العدم أن Julia توفر عدة قيم نائبة للقيم الإشكالية: missing وNaN وInf. وما إذا كانت هذه أفضل من إنهاء البرنامج في موقف معين هو أمر متروك لتقدير المبرمج.

ملاحظة حول المصطلحات قبل الخوض في التفاصيل: يتعامل توثيق Julia مع كلمتي «خطأ» و«استثناء» على أنهما متبادلتان إلى حد كبير. وقد يكون المحتوى الواقع أدناه غير متسق بالقدر ذاته.

أنواع الأخطاء القياسية

بحلول هذه المرحلة من المنهج الدراسي، لا بد أنك رأيت الكثير من رسائل الأخطاء من Julia. على سبيل المثال:

julia> Int(3.14)
ERROR: InexactError: Int64(3.14)

تحويل عدد عشري إلى عدد صحيح يتضمن فقدانًا للدقة، لذا نحصل على InexactError.

InexactError نوع، وهو واحد من عدة أنواع (حاليًا 25) مدمجة في Julia بشكل قياسي. وكلها أنواع فرعية من Exception:

julia> supertype(InexactError)
Exception

throw()

قد يكون من المفيد توليد بعض أنواع الأخطاء القياسية في الكود الخاص بك.

وكما هو الحال مع جميع الأنواع الملموسة، للأخطاء منشئات. وهي تأخذ وسائط متنوعة، لذا راجع التوثيق من أجل النوع الذي تريد استخدامه.

julia> DomainError(42, "out of range")
DomainError(42, "out of range")

لاستخدام الخطأ، غلّف المنشئ داخل دالة throw():

julia> throw(DomainError(42, "out of range"))
ERROR: DomainError with 42:
out of range

error()

للحصول على حلٍّ سريع، قد تكون دالة error() مريحة. فهي تأخذ سلسلة نصية (أو مكوّنات سلسلة نصية) كوسيط:

julia> happy = false;
julia> happy || error("😞 something went wrong")
ERROR: 😞 something went wrong

أخطاء مخصصة

إنشاء أنواع أخطاء جديدة سهل جدًا من حيث المبدأ. ما عليك سوى إضافة نوع فرعي آخر من Exception:

julia> struct MyError <: Exception end

julia> throw(MyError)
ERROR: MyError

التأكيدات

الفكرة الأساسية للتأكيد هي أن «هذه القضية ينبغي أن تكون صحيحة، فاشتكِ بصوت عالٍ إن كانت خاطئة». وتكمن قيمته أساسًا أثناء تصحيح الأخطاء، إذ لا ينبغي لكود الإنتاج أن يفشل في تأكيد.

رأينا في مفهوم الأنواع أنه يمكننا إضافة تأكيدات النوع، مثل التحقق من نوع الإرجاع لدالة.

julia> 42::Number
42

julia> "two"::Number
ERROR: TypeError: in typeassert, expected Number, got a value of type String

وبشكل أعم، تتيح لنا الماكرو @assert اختبار أي تعبير يُقيَّم إلى قيمة منطقية:

julia> n = 22;
julia> @assert isodd(n) "n must be odd"
ERROR: AssertionError: n must be odd

try...catch

بعض الأخطاء قاتلة بالضرورة، لكننا غالبًا نتوقع أن يتعافى البرنامج بسلاسة.

افتراضيًا، يُنهي الخطأ الدالة الحالية فورًا، ويُمرَّر الخطأ (مع أي رسالة مفيدة) إلى الدالة المستدعية.

ويستمر هذا صعودًا في مكدس الاستدعاءات، حتى يتوقف كود المستوى الأعلى برسالة خطأ.

وفي أي مرحلة، يمكن اعتراض الخطأ بواسطة كتلة try...catch التي تحاول التعامل معه.

julia> n = -1;
julia> try
           log_n = log(n)
       catch problem
           if problem isa DomainError # number out of range
               # See next section for more on @warn and @info
               @warn "you may have supplied a negative real number: $n"
               @info "trying with complex argument"
               log_n = log(Complex(n))  # fallback calculation

           elseif problem isa MethodError # no idea what n is
               @error "please supply a valid argument"
 
           else
              rethrow() # the error could be anything else
           end
      end
┌ Warning: you may have supplied a negative real number: -1
└ @ Main REPL[3]:5
[ Info: trying with complex argument
0.0 + 3.141592653589793im  # success

في المثال أعلاه، تحتاج log(n) إلى أن تكون n قيمة حقيقية موجبة أو أي قيمة مركّبة. وتلتقط try ... catch المشكلات المتعلقة بالقيم الحقيقية السالبة، فتُرجع الإجابة المركّبة الصحيحة iπ بالترميز الرياضي.

إذا مرّرت، على سبيل المثال، وسيطًا من نوع سلسلة نصية، فلا يوجد تعافٍ إلا بمطالبة المستخدم بتصحيحه.

وكحل أخير شامل، أضفنا rethrow() لأي خطأ ليس من نوع DomainError ولا MethodError.

ملاحظة: أحيانًا تكون try...catch هي ما تحتاجه، لكن تجنّب الإفراط في استخدامها. فإذا أمكن استخدام كتلة if...else بدلًا منها، فستكون أكثر كفاءة بكثير من التقاط الاستثناءات.

التسجيل

لاحظ أن دالة error() التي ناقشناها أعلاه لا ينبغي الخلط بينها وبين الماكرو @error.

تولّد الدالة استثناءً، يُمرَّر صعودًا في مكدس الاستدعاءات ما لم يُلتقط.

أما الماكرو @error، إلى جانب نظيراته @debug و@info و@warn، فهو جزء من وحدة Logging، ويهدف إلى توليد رسائل مفيدة دون تغيير مسار البرنامج.

ويذهب الخرج إلى الطرفية افتراضيًا (مع ترميز لوني حسب الخطورة)، رغم وجود إمكانات أخرى كثيرة في تطبيق حقيقي.

julia> @warn "Something looks not quite right"
┌ Warning: Something looks not quite right
└ @ Main REPL[55]:1

julia> @error "Panic!"
┌ Error: Panic!
└ @ Main REPL[56]:1

راجع أيضًا المثال السابق في قسم try...catch.