到目前為止，課程大綱還沒有深入談到型別，但很明顯 Julia 裡確實有型別：
julia> vals = (42, 4.3, π, "hello", 'Q')
(42, 4.3, π, "hello", 'Q')
julia> typeof(vals)
Tuple{Int64, Float64, Irrational{:π}, String, Char}
我們從未指定型別，但 Julia 還是自動幫它們指定了。
- Julia 有
types，這是它設計上的核心。
- Julia 通常能「猜」出型別，靠的是
Type Inference。
JIT 編譯器會檢視（所有）程式碼，看看變數如何被使用，然後_推斷_出一個適合該用途的預設型別。
型別指定
依賴型別推斷來解簡單的教學練習沒問題，但對於較大的程式，你很可能需要更精確的控制。
在多數現代處理器上，整數的預設型別是Int64。
我們在Numbers概念中看過，值可以轉換成特定的非預設型別。
julia> x = Int16(42)
42
julia> typeof(x)
Int16
不過，變數x仍然可以重新指定成不同的型別：
julia> x = "changed"
"changed"
julia> typeof(x)
String
這叫做type instability，它的特點是：
- 在小型腳本裡非常方便。
- 在較大的程式裡，對效能和可靠性都不好。
我們可以用::運算子來設定x的型別：
julia> y::Int16 = 42
42
julia> typeof(y)
Int16
julia> y = "changed"
ERROR: MethodError: Cannot `convert` an object of type String to an object of type Int16
The function `convert` exists, but no method is defined for this combination of argument types.
現在y的型別是Int16，而且永遠都會是。
因此，編譯器知道要為它保留多少位元組，也能放心把其餘程式碼最佳化，依賴這個穩定的型別。
這樣一來，這個變數就和 C 這類靜態型別語言裡的變數差不多。
型別階層
Int64、Int16、String、Char：這些型別到底_從哪來的_。
在許多物件導向（OO）語言中，每個型別都是一個類別，子類別化把它們排進類別階層，而類別方法則定義了各種行為。
Java 和 Ruby 是這種模式的明顯例子，但就連 Python 在內部也類似。
Julia 沒有類別。
官方文件給的理由是，OO 功能會干擾 JIT 編譯器，並損害執行時的效能。
不過，看看這段程式碼：
julia> y::Int16 = 42
42
julia> typeof(y)
Int16
julia> supertype(Int16)
Signed
julia> supertypes(Int16)
(Int16, Signed, Integer, Real, Number, Any)
補充一些細節：
-
Int16是一種型別，我們可以建立這種型別的變數。
-
Int16是Signed的子型別，supertype()函式會告訴我們這件事。
- 型別構成一組階層，往上經過
Integer、Real和Number，最頂端是Any，而subtypes()會為我們列出階層的這個分支。
所有分支最後都終止於Any，它的獨特之處在於它是自己的父型別。
julia> supertypes(String)
(String, AbstractString, Any)
julia> supertype(Any)
Any
所以，Julia 沒有class階層，但它_確實_有type階層。
之後我們會試著拆解它的運作方式，但首先還有很多東西要探索。
測試型別
我們可以用typeof()依照平常的方式測試是否相等。
julia> typeof(11)
Int64
julia> typeof(11) == Int64
true
julia> typeof(11) == Number
false
型別相等必須完全一致，因為這種比較方式並不理解型別階層。
更有彈性的是，isa會告訴我們某個值是否和比較對象同型別，或是它的子型別。
它可以用函式形式或中綴形式來寫。
julia> 12 isa Int64
true
julia> 12 isa Number
true
julia> isa(12, Number)
true
julia> 12 isa String
false
注意，isa左邊要放的是value，不是type。
用這種方式比較兩個_型別_會得到意想不到的結果。
正確的運算子是<:，之後的概念我們還會經常看到它。
julia> Int64 isa Number ## Don't do this!
false
julia> Int64 <: Number
true
抽象型別與具體型別
我們看到型別階層會形成樹狀結構（就電腦科學的意義來說，根在最上面）。
樹裡的每一項都是一個node，而它們可以分成幾類：
- 有子型別的節點叫做
abstract。
- 沒有子型別的葉節點叫做
concrete。
julia> subtypes(Integer) # an abstract type
3-element Vector{Any}:
Bool
Signed
Unsigned
julia> subtypes(Int64) # a concrete type
Type[]
這是個重要的區別，因為只有具體型別可以instantiated成變數。
julia> a::Int16 = 42
42
julia> typeof(a)
Int16
julia> b::Integer = 42
42
julia> typeof(b)
Int64
注意，嘗試使用抽象型別（在這個情況下）不會產生錯誤訊息，但編譯器會建立一個適當的具體型別：Int64，而不是Integer。
學習練習
