চ্যানেল স্যুইজল

SIMD: ক্রস-লেন অপারেশন

এখন পর্যন্ত প্রতিটি SIMD অপারেশন লেন ধরে ধরে কাজ করেছে। ফলাফলের i নম্বর লেনের মান হিসাব করা হয় ইনপুটের i নম্বর লেন থেকেই।

তবে অনেক সময়েই লেনের মধ্যে মান এক লেন থেকে আরেক লেনে নেওয়া প্রয়োজন বা কাঙ্ক্ষিত হয়। উদাহরণস্বরূপ, আমাদের যে হিসাবটি করতে হবে তার জন্য লেনগুলো হয়তো এলোমেলো ক্রমে আছে।

অনেক রকমের SIMD ইনস্ট্রাকশন আছে যেগুলো ভিন্ন ভিন্ন উপায়ে লেনের এপার-ওপার ডেটা সরায়।

শাফলিং

একটি শাফল রেজিস্টারের বাইট বা লেনের ক্রম বদলে দেয়, আর প্রতিটি ডেস্টিনেশন লেনের জন্য সোর্স লেন নেয় যেকোনো জায়গা থেকেই। এরা একই লেনকে ভিন্ন ভিন্ন ডেস্টিনেশনে বসাতে পারে, ফলে এরা মান ব্রডকাস্টও করতে সক্ষম।

শাফলিং ইনস্ট্রাকশনগুলো তাদের সাইজ ও এক্সিকিউশন ডোমেইন অনুযায়ী ভিন্নভাবে আচরণ করে।

ইমিডিয়েট দিয়ে লেন নির্বাচন

pshufd ইনস্ট্রাকশনটি তার সোর্সের চারটি 32-বিট লেন নতুন করে ডেস্টিনেশনে সাজায়।

নির্বাচনটি একটি 8-বিট ইমিডিয়েট, যা চারটি 2-বিট ফিল্ড হিসেবে পড়া হয়, প্রতিটি ডেস্টিনেশন লেনের জন্য একটি। প্রতিটি ফিল্ড ঠিক করে চারটি সোর্স লেনের মধ্যে কোনটি ওই ডেস্টিনেশন লেনে কপি হবে:

ইমিডিয়েটে ফিল্ডটির অবস্থান, যা ডান থেকে বাঁয়ে পড়া হয়, বলে দেয় নির্বাচিত লেনটি কোথায় বসানো হবে। একটি সোর্স লেন একাধিকবার নির্বাচিত হতে পারে, এভাবেই একটি লেন পুরো রেজিস্টার জুড়ে ব্রডকাস্ট করা হয়:

; The bit fields are read right-to-left
pshufd xmm1, xmm0, 0b00_01_10_11 ; reverse: lane 0 takes source 0b11 (3), lane 1 takes source 0b10 (2), and so on
pshufd xmm3, xmm2, 0b00_00_00_00 ; broadcast source lane 0 into all four lanes

ফ্লোটিং-পয়েন্ট লেন শাফল করা

ফ্লোটিং-পয়েন্ট শাফল ইনস্ট্রাকশন আছে দুইটি, যারা একই সাধারণ সিনট্যাক্স অনুসরণ করে: shuf + p + সাইজ সাফিক্স (s অথবা d)।

এরাও লেন নির্বাচনের জন্য একটি ইমিডিয়েট ব্যবহার করে। shufps আগের ইন্টিজার শাফলগুলোর মতোই 2-বিট ফিল্ড এনকোডিং ব্যবহার করে। তবে 128-বিট অপারেন্ডে মাত্র ২টি 64-বিট লেন থাকায় shufpd শুধু 1-বিট ফিল্ড এনকোডিং ব্যবহার করে।

এই ইনস্ট্রাকশনগুলো তাদের ইন্টিজার সমকক্ষ থেকে আলাদা, কারণ এরা একটির বদলে দুইটি অপারেন্ড থেকে লেন নেয়:

• ফলাফলের নিচের অর্ধেক নেওয়া হয় ডেস্টিনেশন অপারেন্ড থেকে।
• উপরের অর্ধেক নেওয়া হয় সোর্স অপারেন্ড থেকে।

shufps xmm0, xmm1, 0b11_10_01_00 ; xmm0 = {xmm0[0], xmm0[1], xmm1[2], xmm1[3]}
shufps xmm2, xmm3, 0b00_00_00_00 ; xmm2 = {xmm2[0], xmm2[0], xmm3[0], xmm3[0]}
shufpd xmm4, xmm5, 0b0_1         ; xmm4 = {xmm4[1], xmm5[0]}

যেহেতু দুইটি অপারেন্ডই ফলাফলে অবদান রাখে, তাই এগুলো দিয়ে এক ধাপেই দুইটি ভেক্টর ইন্টারলিভ করা যায়। সোর্স আর ডেস্টিনেশন যদি একই রেজিস্টার হয়, তাহলে প্রতিটি লেনই তার থেকেই নেওয়া হয়।

বাইট শাফল

pshufb হলো সবচেয়ে সাধারণ শাফল। pshufb আর pshufd-এর নাম প্রায় একই, শুধু সাইজ সাফিক্সে আলাদা, তবু এরা খুব ভিন্ন কাজ করে।

প্রথমত, pshufd যেখানে লেনের অবস্থান নির্বাচনে ইমিডিয়েট ব্যবহার করে, pshufb সেখানে সোর্স অপারেন্ডে একটি কন্ট্রোল ভেক্টর ব্যবহার করে। এই কন্ট্রোল ভেক্টরটি একটি xmm রেজিস্টার বা 16-বাইটের মেমোরি অপারেন্ড।

১৬টি ডেস্টিনেশন লেনের প্রতিটির জন্য কন্ট্রোল ভেক্টরের নিচের চারটি বিট একটি সোর্স বাইট ইনডেক্স দেয়, 0 থেকে 15 পর্যন্ত। কন্ট্রোল ভেক্টরের লেন i-এ যদি সোর্স বাইট ইনডেক্স j থাকে, তাহলে ডেস্টিনেশনের j-th-তম লেনটি i-তম লেনে সরানো হবে।

এটি দুইটি ইনস্ট্রাকশনের মধ্যে দ্বিতীয় পার্থক্যটি তুলে ধরে। pshufd যেখানে শাফল করার লেনগুলো নেয় অন্য একটি সোর্স অপারেন্ড থেকে, pshufb সেখানে শাফল করে ডেস্টিনেশনেই, ইন-প্লেস।

section .rodata
align 16
reverse: db 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0

section .text
fn:
  pshufb xmm0, [rel reverse]
  ; xmm0[0] = xmm0[reverse[0]] (xmm0[15])
  ; xmm0[1] = xmm0[reverse[1]] (xmm0[14])
  ; ...
  ; in the end, the bytes in xmm0 are reversed

pshufb তার চেয়েও বেশি নমনীয়: এটি যেকোনো লেন ক্লিয়ার করতে পারে। কন্ট্রোল ভেক্টরের লেন i-এ যদি টপ বিট সেট থাকে, তাহলে ডেস্টিনেশনের লেন i-th শূন্য করে দেওয়া হয়। এতে pshufb একই ইনস্ট্রাকশনে ইচ্ছেমতো বাইট পারমিউটেশন আর বাছাই করে ক্লিয়ার, দুটোই হয়ে ওঠে।

যেহেতু pshufb বাইট গ্র্যানুলারিটিতে কাজ করে, তাই পাশাপাশি লেনগুলোকে গ্রুপ করে ভিন্ন আকারের লেনও শাফল করা যায়। উদাহরণস্বরূপ, এটি দিয়ে ডোয়ার্ড শাফল করা যায়:

section .rodata
align 16
input: dd 13, 25, 37, 49 ; each number takes 4 bytes
reverse_dwords: db 12, 13, 14, 15, 8, 9, 10, 11, 4, 5, 6, 7, 0, 1, 2, 3 ; aligned too, since input spans 16 bytes

section .text
fn:
  movdqa xmm0, [rel input] ; xmm0 = {13, 25, 37, 49}
  pshufb xmm0, [rel reverse_dwords]
  ; xmm0 = {49, 37, 25, 13}

লেন ইন্টারলিভ করা

আনপ্যাক ইনস্ট্রাকশনগুলো দুইটি অপারেন্ড থেকে লেন নিয়ে সেগুলো একসাথে বুনে দেয়, পালাক্রমে দুইটির মধ্যে ঘুরে ঘুরে। এগুলোর ইন্টিজার ও ফ্লোট ভ্যারিয়েন্ট আছে এবং এরা মূলত একই সাধারণ সিনট্যাক্স গঠন অনুসরণ করে, তবে দুইটি পার্থক্য নিয়ে:

1. একটি l বা h সাফিক্স থাকে, যা বোঝায় এটি প্রতিটি অপারেন্ডের নিচের অর্ধেক (l) নাকি উপরের অর্ধেক (h)-এ কাজ করে।
2. ইন্টিজার ভ্যারিয়েন্টগুলো দুইটি সাইজ সাফিক্স নেয়, যার দ্বিতীয়টি প্রথমটির দ্বিগুণ বোঝায়। উদাহরণস্বরূপ, bw বা qdq (16 বাইটের সাইজ সাফিক্স হলো dq, যেমন movdqu-তে)।

punpcklwd xmm0, xmm1 ; p + unpck + l + wd
; this interleaves the first 4 words of xmm0 and xmm1 into 4 dwords
; for each dword in the result, the first word is taken from xmm0 and the second, from xmm1
; xmm0 = {xmm0[0], xmm1[0], xmm0[1], xmm1[1], xmm0[2], xmm1[2], xmm0[3], xmm1[3]}

unpckhps xmm2, xmm3 ; unpck + h + p + s
; this interleaves the high 32-bit floats of xmm2 and xmm3
; xmm2 = {xmm2[2], xmm3[2], xmm2[3], xmm3[3]}

স্যাচুরেশন দিয়ে ন্যারোয়িং

প্যাক ইনস্ট্রাকশনগুলো উল্টো দিকে চলে, দুইটি অপারেন্ডের লেনগুলোকে ডেস্টিনেশনের অর্ধ-প্রস্থের লেনে মিলিয়ে দেয়।

এই ইনস্ট্রাকশনগুলো p প্রিফিক্স নেয় না। তা ছাড়া, এর সিনট্যাক্স এমন কিছু উপাদানের সমন্বয় যা আমরা আগেই দেখেছি:

• যে অপারেশনটি করা হচ্ছে, pack।
• একটি s বা u, যা বোঝায় আউটপুট মানগুলো যথাক্রমে সাইনড নাকি আনসাইনড।
• একটি s, স্যাচুরেটিং-এর জন্য, যেমন আগের একটি কনসেপ্টে দেখা স্যাচুরেটিং অ্যারিথমেটিক।
• দুইটি সাইজ সাফিক্স, যার দ্বিতীয়টি প্রথমটির অর্ধেক প্রস্থ বোঝায় (unpck-এর ঠিক উল্টো আচরণ)।

যেহেতু প্যাক অপারেশনটি ন্যারোয়িং, তাই এর l বা h সাফিক্স দরকার হয় না:

packssdw xmm0, xmm1 ; pack + s (for signed) + s (for saturating) + dw (dword to word)
packuswb xmm2, xmm3 ; pack + u (for unsigned) + s (for saturating) + wb (word to byte)

এই ইনস্ট্রাকশনগুলো স্যাচুরেটিং, অর্থাৎ আউটপুট মানগুলো সংকীর্ণ রেঞ্জে ক্ল্যাম্প করা হয়। এগুলো ডোয়ার্ড থেকে ওয়ার্ডে এবং ওয়ার্ড থেকে বাইটে কাজ করে। কিউওয়ার্ড থেকে ডোয়ার্ড ভ্যারিয়েন্ট নেই।

খেয়াল করুন, ইনপুট সবসময় সাইনড হিসেবে ব্যাখ্যা করা হয়। টাইপটি, সাইনড বা আনসাইনড যা-ই হোক, সেটি আউটপুটের জন্য। এটি বোঝায় কোন রেঞ্জে ক্ল্যাম্প করতে হবে। উদাহরণস্বরূপ, packsswb একটি সাইনড বাইটের রেঞ্জে ক্ল্যাম্প করে, অর্থাৎ [-128, 127]।

ফলাফলের নিচের লেনগুলো আসে ডেস্টিনেশন অপারেন্ড থেকে আর উপরের লেনগুলো সোর্স থেকে:

packusdw xmm0, xmm1   ; 8 words, each clamped to 0..65535
; xmm0 = {xmm0[0], xmm0[1], xmm0[2], xmm0[3], xmm1[0], xmm1[1], xmm1[2], xmm1[3]}

এই ইনস্ট্রাকশনগুলোর কোনো ফ্লোটিং-পয়েন্ট সমতুল্য নেই।

আলাদা লেন সরানো

এখন পর্যন্ত আমরা সবসময় movq/movd ব্যবহার করে SIMD রেজিস্টার আর জেনারেল-পারপাস রেজিস্টারের মধ্যে ডেটা সরিয়েছি। এই ইনস্ট্রাকশনগুলো SIMD রেজিস্টারের শুধু নিচের লেনে লিখতে বা তা থেকে পড়তে পারে, আর লেখার সময় বাকি সব লেন ক্লিয়ার করে দেয়।

এমন ইনস্ট্রাকশনও আছে যেগুলো শুধু প্রথমটি নয়, যেকোনো লেনের জন্য একই কাজ করে, অন্য লেনগুলো অপরিবর্তিত রেখে:

• ইনসার্ট ইনস্ট্রাকশনগুলো একটি জেনারেল-পারপাস রেজিস্টার বা মেমোরি থেকে একটি এলিমেন্ট ইমিডিয়েট দিয়ে বেছে নেওয়া একটি লেনে লেখে।
• এক্সট্রাক্ট ইনস্ট্রাকশনগুলো একটি লেন থেকে পড়ে জেনারেল-পারপাস রেজিস্টারে আনে।

দুইটিই ইন্টিজার সিনট্যাক্স অনুসরণ করে: p + insr/extr + সাইজ সাফিক্স (b, w, d, বা q)।

দুই ক্ষেত্রেই জেনারেল-পারপাস রেজিস্টার সাধারণত 32-বিট চওড়া। শুধু pinsrq আর pextrq-এর 64-বিট অপারেন্ড দরকার। মেমোরি অপারেন্ড সবসময় অপারেশনের আকারের হয়: pinsrb/pextrb-এর জন্য 8-বিট, pinsrw/pextrw-এর জন্য 16-বিট, ইত্যাদি।

pinsrb xmm0, eax, 5        ; replace byte 5 of xmm0 with the low byte of eax
pextrb byte [rdx], xmm0, 5 ; copy byte 5 of xmm0 into the memory location indicated by rdx

খেয়াল করুন, এই ইনস্ট্রাকশনগুলো movd আর movq-এর মতোই শুধু কাঁচা বাইট সরায়। এর মানে এগুলো মেমোরিতে বা জেনারেল-পারপাস রেজিস্টারে রাখা ফ্লোটিং-পয়েন্ট মানের জন্যও ব্যবহার করা যায়।