チャンネルスウィズル

SIMD：レーンをまたぐ操作

これまでのSIMD演算は、すべて_レーンごと_に動作してきました。 結果のレーンiの値は、入力のレーンiから計算されます。

しかし、レーン間で値を移動させることが必要だったり、そうしたい場面は数多くあります。 たとえば、これから行いたい計算にとって、レーンの並び順が合っていないことがあります。

データをレーンをまたいで移動させるSIMD命令には、さまざまなやり方のものがあります。

シャッフル

シャッフルは、レジスターのバイトやレーンを並べ替える操作で、転送先の各レーンには、どこにあるものでもよい転送元のレーンから値を持ってきます。 同じレーンを複数の転送先に選ぶこともでき、そのため値をブロードキャストすることもできます。

シャッフル命令は、そのサイズと実行ドメインによって動作が異なります。

即値でレーンを選ぶ

pshufd命令は、転送元の4つの32ビットレーンを並べ替えて転送先に格納します。

選択には8ビットの即値を使い、これを2ビットずつの4つのフィールドとして読みます。フィールドは転送先のレーンごとに1つです。 各フィールドは、4つある転送元レーンのうちどれをその転送先レーンにコピーするかを選びます。

即値の中でフィールドがどの位置にあるか（右から左へ読む）が、選んだレーンをどこに挿入するかを示します。 転送元のレーンは複数回選ぶこともでき、これが1つのレーンをレジスター全体にブロードキャストする方法です。

; The bit fields are read right-to-left
pshufd xmm1, xmm0, 0b00_01_10_11 ; reverse: lane 0 takes source 0b11 (3), lane 1 takes source 0b10 (2), and so on
pshufd xmm3, xmm2, 0b00_00_00_00 ; broadcast source lane 0 into all four lanes

浮動小数点レーンのシャッフル

浮動小数点のシャッフル命令は2つあり、どちらも同じ一般的な構文に従います。shuf + p + サイズ接尾辞（sまたはd）です。

これらの命令も、レーンを選ぶのに即値を使います。 shufpsは、先ほどの整数のシャッフルと同じ2ビットのフィールド符号化を使います。 ただし、128ビットのオペランドには64ビットのレーンが2つしかないため、shufpdは1ビットのフィールド符号化しか使いません。

これらの命令が対応する整数命令と違うのは、レーンを1つではなく_2つ_のオペランドから取る点です。

• 結果の下位半分は転送先オペランドから取ります。
• 上位半分は転送元オペランドから取ります。

shufps xmm0, xmm1, 0b11_10_01_00 ; xmm0 = {xmm0[0], xmm0[1], xmm1[2], xmm1[3]}
shufps xmm2, xmm3, 0b00_00_00_00 ; xmm2 = {xmm2[0], xmm2[0], xmm3[0], xmm3[0]}
shufpd xmm4, xmm5, 0b0_1         ; xmm4 = {xmm4[1], xmm5[0]}

両方のオペランドが結果に寄与するため、2つのベクターを1ステップでインターリーブするのに使えます。 転送元と転送先が同じレジスターであれば、すべてのレーンがそこから取られます。

バイトのシャッフル

pshufbはもっとも汎用的なシャッフルです。 pshufbとpshufdは名前がよく似ていてサイズ接尾辞だけが違いますが、行う操作はまったく異なります。

まず、pshufdはレーンの位置を選ぶのに即値を使うのに対し、pshufbは転送元オペランドの制御ベクターを使います。 この制御ベクターは、xmmレジスターか16バイトのメモリーオペランドです。

16ある転送先レーンのそれぞれについて、制御ベクターの下位4ビットが転送元のバイトのインデックス（0〜15）を与えます。 制御ベクターのレーンiが転送元のバイトのインデックスjを保持しているなら、転送元のj-th番目のレーンが転送先のi番目のレーンに移動します。

これは、2つの命令の2つ目の違いを浮き彫りにします。 pshufdはシャッフルするレーンを別の転送元オペランドから取りますが、pshufbは転送先の中でその場でシャッフルを行います。

section .rodata
align 16
reverse: db 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0

section .text
fn:
  pshufb xmm0, [rel reverse]
  ; xmm0[0] = xmm0[reverse[0]] (xmm0[15])
  ; xmm0[1] = xmm0[reverse[1]] (xmm0[14])
  ; ...
  ; in the end, the bytes in xmm0 are reversed

pshufbはさらに柔軟で、任意のレーンをクリアできます。 制御ベクターのレーンiで最上位ビットが立っていると、転送先のレーンi-thはゼロにされます。 これによりpshufbは、1つの命令で、任意のバイトの並べ替えと選択的なクリアの両方をこなします。

pshufbはバイト単位で動作するため、隣り合うレーンをまとめることで、異なるサイズのレーンをシャッフルするのにも使えます。 たとえば、ダブルワードをシャッフルするのに使えます。

section .rodata
align 16
input: dd 13, 25, 37, 49 ; each number takes 4 bytes
reverse_dwords: db 12, 13, 14, 15, 8, 9, 10, 11, 4, 5, 6, 7, 0, 1, 2, 3 ; aligned too, since input spans 16 bytes

section .text
fn:
  movdqa xmm0, [rel input] ; xmm0 = {13, 25, 37, 49}
  pshufb xmm0, [rel reverse_dwords]
  ; xmm0 = {49, 37, 25, 13}

レーンのインターリーブ

アンパック命令は、2つのオペランドからレーンを取り出し、2つを交互に織り交ぜます。 整数版と浮動小数点版があり、どちらもほぼ同じ一般的な構文構造に従いますが、2つの違いがあります。

1. lまたはhの接尾辞があり、各オペランドの下位半分（l）と上位半分（h）のどちらに作用するかを示します。
2. 整数版はサイズ接尾辞を2つ取り、2つ目は1つ目の2倍のサイズを表します。 たとえばbwやqdqです（16バイトのサイズ接尾辞は、movdquのようにdqです）。

punpcklwd xmm0, xmm1 ; p + unpck + l + wd
; this interleaves the first 4 words of xmm0 and xmm1 into 4 dwords
; for each dword in the result, the first word is taken from xmm0 and the second, from xmm1
; xmm0 = {xmm0[0], xmm1[0], xmm0[1], xmm1[1], xmm0[2], xmm1[2], xmm0[3], xmm1[3]}

unpckhps xmm2, xmm3 ; unpck + h + p + s
; this interleaves the high 32-bit floats of xmm2 and xmm3
; xmm2 = {xmm2[2], xmm3[2], xmm2[3], xmm3[3]}

飽和による縮小

パック命令は逆方向の操作で、2つのオペランドのレーンを組み合わせて、転送先の半分の幅のレーンにします。

これらの命令にはpの接頭辞が付きません。 それ以外の点では、構文はこれまでに見てきた要素を組み合わせたものになっています。

• 行う操作、pack。
• 出力値がそれぞれ_符号付き_か_符号なし_かを示すsまたはu。
• _飽和_を表すs（以前のコンセプトで見た飽和演算と同じ）。
• 2つのサイズ接尾辞。2つ目は1つ目の_半分_の幅を示します（unpckとは逆の挙動です）。

_パック_操作は幅を狭めるので、lやhの接尾辞は必要ありません。

packssdw xmm0, xmm1 ; pack + s (for signed) + s (for saturating) + dw (dword to word)
packuswb xmm2, xmm3 ; pack + u (for unsigned) + s (for saturating) + wb (word to byte)

これらの命令は飽和します。つまり、出力値はより狭い範囲にクランプされます。 ダブルワードからワードへ、ワードからバイトへと動作します。 クワッドワードからダブルワードへの版はありません。

入力は常に符号付きとして解釈されることに注意してください。 符号付きか符号なしかという型は、_出力_に対するものです。 クランプする範囲を示しています。 たとえばpacksswbは、符号付きバイトの範囲、つまり[-128, 127]にクランプします。

結果の下位のレーンは転送先オペランドから、上位のレーンは転送元から来ます。

packusdw xmm0, xmm1   ; 8 words, each clamped to 0..65535
; xmm0 = {xmm0[0], xmm0[1], xmm0[2], xmm0[3], xmm1[0], xmm1[1], xmm1[2], xmm1[3]}

これらの命令に相当する浮動小数点命令はありません。

個々のレーンを移動する

これまでは、SIMDレジスターと汎用レジスターの間でデータを移動させるのに、いつもmovq/movdを使ってきました。 これらの命令は、SIMDレジスターの最下位のレーンにしか書き込めず、そこからしか読み取れません。また、書き込むときは他のすべてのレーンをクリアします。

先頭だけでなく任意のレーンに対して同じことを行い、他のレーンには手を付けない命令もあります。

• インサート命令は、汎用レジスターまたはメモリーから1つの要素を、即値で選んだレーンに書き込みます。
• エクストラクト命令は、1つのレーンから汎用レジスターへ読み出します。

どちらも整数の構文に従います。p + insr/extr + サイズ接尾辞（b、w、d、qのいずれか）です。

どちらの場合も、汎用レジスターは通常32ビット幅です。 pinsrqとpextrqだけが64ビットのオペランドを必要とします。 メモリーオペランドは常に操作のサイズと同じです。pinsrb/pextrbなら8ビット、pinsrw/pextrwなら16ビット、といった具合です。

pinsrb xmm0, eax, 5        ; replace byte 5 of xmm0 with the low byte of eax
pextrb byte [rdx], xmm0, 5 ; copy byte 5 of xmm0 into the memory location indicated by rdx

これらの命令は、movdやmovqとよく似ていて、生のバイトをそのまま移動させるだけであることに注意してください。 つまり、メモリーや汎用レジスターに格納された浮動小数点値にも使えます。