Πάρε νούμερο Deluxe

GenServer

Το GenServer (γενικός διακομιστής) είναι μια συμπεριφορά που παρέχει μια αφαίρεση για τις κοινές αλληλεπιδράσεις πελάτη-διακομιστή μεταξύ διεργασιών της Elixir.

Θυμάσαι τον βρόχο λήψης από τότε που μάθαμε για τις διεργασίες; Η συμπεριφορά GenServer παρέχει αφαιρέσεις για την υλοποίηση τέτοιων βρόχων και για την ανταλλαγή μηνυμάτων με μια διεργασία που εκτελεί έναν τέτοιο βρόχο. Κάνει ευκολότερη τη διατήρηση της κατάστασης και την εκτέλεση ασύγχρονου κώδικα.

Η συμπεριφορά GenServer ορίζει ένα υποχρεωτικό callback, το init/1, και μερικά ενδιαφέροντα προαιρετικά callback: handle_call/3, handle_cast/2 και handle_info/3. Οι πελάτες που χρησιμοποιούν ένα GenServer δεν πρέπει να καλούν αυτά τα callback απευθείας. Αντίθετα, το module GenServer παρέχει συναρτήσεις που μπορούν να χρησιμοποιήσουν οι πελάτες για να επικοινωνήσουν με μια διεργασία GenServer.

Συχνά, ένα μόνο module ορίζει και το API πελάτη, ένα σύνολο συναρτήσεων που μπορούν να καλέσουν άλλα μέρη της εφαρμογής σου σε Elixir για να επικοινωνήσουν με αυτή τη διεργασία GenServer, και τις υλοποιήσεις των callback του διακομιστή, που περιέχουν τη λογική αυτού του GenServer.

Ας δούμε πρώτα ένα απλό παράδειγμα GenServer και μετά ας μάθουμε τι σημαίνει κάθε callback.

Παράδειγμα

Αυτός είναι ένα παράδειγμα διακομιστή που μπορεί να απαντά στις επαναλαμβανόμενες ερωτήσεις ενοχλητικών επιβατών σε ένα μεγάλο οδικό ταξίδι, ή πιο συγκεκριμένα στην ερώτηση: "Φτάσαμε;". Κρατάει τον αριθμό των φορών που έχει γίνει αυτή η ερώτηση, επιστρέφοντας όλο και πιο εκνευρισμένες απαντήσεις.

defmodule AnnoyingPassengerAutoresponder do
  use GenServer
  # Client API

  def start_link(init_arg) do
    GenServer.start_link(__MODULE__, init_arg)
  end

  def are_we_there_yet?(pid) do
    GenServer.call(pid, :are_we_there_yet?)
  end

  # Server callbacks

  @impl GenServer
  def init(_init_arg) do
    # the initial count of questions asked is always 0
    state = 0
    {:ok, state}
  end

  @impl GenServer
  def handle_call(:are_we_there_yet?, _from, state) do
    reply =
      cond do
        state <= 3 -> "No."
        state <= 10 -> "I told you #{state} times already. No."
        true -> "..."
      end

    # increase the count of questions asked
    new_state = state + 1
    # reply to the caller
    {:reply, reply, new_state}
  end
end

Callback

init/1

Μπορείς να ξεκινήσεις έναν διακομιστή καλώντας το GenServer.start/3 ή το GenServer.start_link/3. Μάθαμε τη διαφορά ανάμεσα σε αυτές τις συναρτήσεις στην έννοια links.

Αυτές οι δύο συναρτήσεις:

• Δέχονται ως πρώτο όρισμα ένα module που υλοποιεί τη συμπεριφορά GenServer.
• Δέχονται ως δεύτερο όρισμα οτιδήποτε, το οποίο ονομάζεται init_arg. Όπως υποδηλώνει το όνομα, αυτό το όρισμα περνάει στο callback init/1.
• Δέχονται ένα προαιρετικό τρίτο όρισμα με προχωρημένες επιλογές για την εκτέλεση της διεργασίας, τις οποίες δεν θα καλύψουμε τώρα.

Η εκκίνηση ενός διακομιστή με κλήση του GenServer.start/3 ή του GenServer.start_link/3 θα καλέσει το callback init/1 μπλοκάροντας. Η τιμή επιστροφής του init/1 καθορίζει αν ο διακομιστής μπορεί να ξεκινήσει με επιτυχία.

Το callback init/1 συνήθως επιστρέφει μία από αυτές τις τιμές:

• {:ok, state}. Ο διακομιστής θα ξεκινήσει τον βρόχο λήψης του χρησιμοποιώντας το state ως αρχική κατάσταση. Το state μπορεί να είναι οποιουδήποτε τύπου.
• {:stop, reason}. Το reason μπορεί να είναι οποιουδήποτε τύπου. Ο διακομιστής δεν θα ξεκινήσει τον βρόχο λήψης του. Η διεργασία θα τερματιστεί με τη δεδομένη αιτία.

Υπάρχουν επίσης πιο προχωρημένες δυνατότητες που δεν θα καλύψουμε τώρα.

Αν ξεκινήσει ο βρόχος λήψης του διακομιστή, οι συναρτήσεις GenServer.start/3 και GenServer.start_link/3 επιστρέφουν μια πλειάδα {:ok, pid}. Διαφορετικά επιστρέφουν {:error, reason}

handle_call/3

Μπορείς να στείλεις ένα μήνυμα που απαιτεί απάντηση σε μια διεργασία διακομιστή με το GenServer.call/2. Αυτή η συνάρτηση περιμένει ως πρώτο όρισμα το pid μιας ενεργής διεργασίας διακομιστή και ως δεύτερο όρισμα το μήνυμα. Το μήνυμα μπορεί να είναι οποιουδήποτε τύπου.

Το callback handle_call/3 είναι υπεύθυνο για τον χειρισμό και την απάντηση σε σύγχρονα μηνύματα. Δέχεται τρία ορίσματα:

1. message - η τιμή που περνάει ως δεύτερο όρισμα στο GenServer.call/2.
2. from - το pid της διεργασίας που καλεί το GenServer.call/2. Τις περισσότερες φορές αυτό το όρισμα μπορεί να αγνοηθεί.
3. state - η τρέχουσα κατάσταση του διακομιστή. Θυμήσου ότι η αρχική της τιμή ορίστηκε στο callback init/1.

Το callback handle_call/3 συνήθως επιστρέφει μια πλειάδα 3 στοιχείων, {:reply, reply, state}. Αυτό σημαίνει ότι το δεύτερο στοιχείο της πλειάδας, ένα reply που μπορεί να είναι οποιουδήποτε τύπου, θα σταλεί πίσω σε αυτόν που κάλεσε. Το τρίτο στοιχείο της πλειάδας, state, είναι η νέα κατάσταση του διακομιστή μετά τον χειρισμό αυτού του μηνύματος.

Υπάρχουν επίσης πιο προχωρημένες δυνατότητες που δεν θα καλύψουμε τώρα.

handle_cast/2

Μπορείς να στείλεις ένα μήνυμα που δεν απαιτεί απάντηση σε μια διεργασία διακομιστή με το GenServer.cast/2. Τα ορίσματά του είναι ίδια με αυτά του GenServer.call/2.

Το callback handle_cast/2 είναι υπεύθυνο για τον χειρισμό αυτών των μηνυμάτων. Δέχεται δύο ορίσματα, message και state, που είναι τα ίδια ορίσματα όπως στο callback handle_call/3 (εκτός από το from).

Το callback handle_cast/2 συνήθως επιστρέφει μια πλειάδα 2 στοιχείων, {:noreply, state}.

Υπάρχουν επίσης πιο προχωρημένες δυνατότητες που δεν θα καλύψουμε τώρα.

Να χρησιμοποιήσω call ή cast;

Σχεδόν πάντα χρησιμοποίησε το call, ακόμα κι αν ο κώδικας του πελάτη σου δεν χρειάζεται την απάντηση από τον διακομιστή.

Η χρήση του call περιμένει την απάντηση, η οποία λειτουργεί ως μηχανισμός backpressure (για να εμποδίζει τους πελάτες να στέλνουν πάρα πολλά μηνύματα ταυτόχρονα). Το να λάβεις απάντηση από τον διακομιστή είναι επίσης ο μόνος τρόπος να είσαι σίγουρος ότι ο διακομιστής έλαβε και χειρίστηκε το μήνυμα του πελάτη.

handle_info/2

Τα μηνύματα μπορούν επίσης να καταλήξουν στο γραμματοκιβώτιο του διακομιστή με άλλους τρόπους εκτός από την κλήση του GenServer.call/2 ή του GenServer.cast/2, για παράδειγμα καλώντας την απλή συνάρτηση send/2.

Για να χειριστείς τέτοια μηνύματα, χρησιμοποίησε το callback handle_info/2. Αυτό το callback λειτουργεί με τον ίδιο ακριβώς τρόπο όπως το handle_cast/2.

Η συμπεριφορά GenServer παρέχει μια προεπιλεγμένη υλοποίηση του handle_info/2 που καλύπτει όλες τις περιπτώσεις και καταγράφει σφάλματα για απροσδόκητα μηνύματα. Αν παρακάμψεις αυτή την προεπιλεγμένη υλοποίηση, φρόντισε να συμπεριλάβεις πάντα τη δική σου υλοποίηση που καλύπτει όλες τις περιπτώσεις. Αν το ξεχάσεις, ο διακομιστής θα καταρρεύσει αν λάβει ένα απροσδόκητο μήνυμα.

Χρονικά όρια

Η τιμή επιστροφής καθενός από τα τέσσερα callback που περιγράφηκαν παραπάνω μπορεί να επεκταθεί με ένα ακόμη στοιχείο πλειάδας, ένα χρονικό όριο. Π.χ. αντί να επιστρέψεις {:ok, state} από το init/1, επέστρεψε {:ok, state, timeout}.

Το χρονικό όριο μπορεί να χρησιμοποιηθεί για να εντοπίσει την απουσία μηνυμάτων στο γραμματοκιβώτιο για ένα συγκεκριμένο διάστημα. Αν ο διακομιστής επιστρέψει ένα χρονικό όριο από ένα από τα callback του και περάσει ο καθορισμένος αριθμός χιλιοστών του δευτερολέπτου χωρίς να φτάσει κανένα μήνυμα, το handle_info/2 καλείται με το :timeout ως πρώτο όρισμα.