SIMD: maszkok és feltételek
A skaláris kód arra támaszkodik, hogy a különféle utasítások jelzőbiteket állítanak be, és ezek alapján egy adott feltétel hatására elágazik.
A csomagolt értékek viszont nem egyetlen értéket, hanem egyszerre többet képviselnek.
Egyetlen feltétel az egyik sávban megbukhat, miközben a másikban teljesül.
Ezért a SIMD-kód alapértelmezés szerint elágazásmentes.
A jelzőbitekre támaszkodás helyett a csomagolt összehasonlítások általában egy maszkot állítanak elő a céloperandusba.
Az összehasonlítás minden sáv esetében az egész sávot egyesekkel tölti fel, ha a feltétel igaz, és nullákkal, ha hamis.
Előjeles egészként értelmezve egy igaz sáv -1, egy hamis sáv pedig 0.
Ez a maszk aztán bitenkénti műveletekkel kombinálható, hogy adott sávokat kiszűrjünk.
Csomagolt összehasonlítások
A skaláris cmp abban az értelemben általános, hogy egyszerre több jelzőbit beállítására szolgál.
Egy másik utasítás aztán felhasználhatja ezeket a jelzőbiteket, hogy elágazást hajtson végre vagy számításokat végezzen.
Mivel azonban egy csomagolt összehasonlítás egyszerre ellenőriz egy feltételt és számít ki egy maszkot, nem általános.
Az összehasonlításnak meg kell adni a pontosan vizsgált feltételt.
Erre kétféle módon van lehetőség:
- Az egész összehasonlításoknál a feltételt utótagként adjuk meg:
eq az egyenlőséghez, gt a nagyobb, mint relációhoz.
A többi változat ezek eredményének kombinálásával áll elő.
- A lebegőpontos összehasonlításoknál a feltételt egy immediate konstansban kódolva adjuk meg.
Az immediate különböző értékei más-más vizsgált feltételnek felelnek meg.
A szintaxis ugyanazt a szerkezetet követi, amit már láttunk, azzal a kivétellel, hogy az egész összehasonlításoknál egy meghatározott feltétel-utótagot használunk:
- Egészeknél:
p + cmp + feltétel + méret (b, w, d vagy q).
- Lebegőpontos számoknál:
cmp + p + méret (s vagy d).
A feltételt egy immediate konstansban, extra operandusként adjuk át.
Egész összehasonlítások
Ahogy említettük, egészeknél csak egyenlőségre és nagyobb, mint relációra van összehasonlítás:
| utasítás |
leírás |
pcmpeqb, pcmpeqw, pcmpeqd, pcmpeqq
|
sávonkénti egyenlőség |
pcmpgtb, pcmpgtw, pcmpgtd, pcmpgtq
|
sávonkénti előjeles nagyobb, mint |
movdqa xmm0, [rel scores]
pcmpgtd xmm0, [rel threshold] ; lane i = 0xFFFFFFFF (-1) if scores[i] > threshold[i], else 0
Kisebb, mint összehasonlítás létrehozásához használd a gt-t felcserélt operandusokkal: a < b == b > a.
Figyeld meg, hogy az összehasonlítás előjeles.
Előjel nélküli összehasonlításhoz mindkét operandus legfelső bitjét át kell billenteni.
Ez egy olyan maszkkal végzett XOR művelettel tehető meg, amelyben csak a legfelső bit van beállítva.
Két hasznos idióma:
- Ha egy regisztert önmagával XOR-ozunk, csupa nulla lesz az eredmény.
- Ha egy regisztert önmagával hasonlítunk össze, csupa egyes lesz az eredmény.
Például:
pxor xmm4, xmm4 ; xmm4 = all zeros
pcmpeqd xmm7, xmm7 ; xmm7 = all ones
A csupa nulla és a csupa egyes gyakori maszkok arra, hogy rendre a „mindenhol hamis” és a „mindenhol igaz” állapotot kódolják.
Arra is használhatók, hogy csomagolt 0-t vagy csomagolt -1-et ábrázoljanak, amelyek gyakori őrértékek.
Például a string végét jelölő NUL egy 0.
Lebegőpontos összehasonlítások
A lebegőpontos sávok más felépítést használnak: egyetlen utasítás, a cmpps (illetve 64 bites sávoknál a cmppd), amelynél a feltétel immediate konstansként szerepel:
movaps xmm0, [rel readings]
cmpps xmm0, [rel limits], 1 ; condition 1 is "less than": lane i = all ones if readings[i] < limits[i]
A NASM-nak vannak olyan pszeudo-műveletei is, amelyek a helyes immediate értékre képződnek le, és könnyebben megjegyezhetők.
Az alábbiakban a px-ben szereplő x lehet s (32 bites lebegőpontos) vagy d (64 bites lebegőpontos):
| pszeudo-művelet |
immediate |
összehasonlítás |
cmpeqpx |
0 |
a == b |
cmpltpx |
1 |
a < b |
cmplepx |
2 |
a <= b |
cmpunordpx |
3 |
a vagy b NaN |
cmpneqpx |
4 |
a != b |
cmpnltpx |
5 |
a >= b |
cmpnlepx |
6 |
a > b |
cmpordpx |
7 |
sem a, sem b nem NaN |
Kiválasztás maszkkal
A maszk egy feltétel eredményét kódolja.
Ezután arra használható, hogy sávonként válasszunk két értékhalmaz között e feltétel alapján.
Az egyik értékből vesszük a sávot ott, ahol a maszk igaz, a másikból ott, ahol hamis:
; result = (a AND mask) OR (b AND NOT mask)
movdqa xmm2, xmm0 ; xmm0 holds the mask, keep a copy
pand xmm2, xmm3 ; xmm2 = a AND mask: lanes of a where mask is true
pandn xmm0, xmm4 ; xmm0 = NOT mask AND b: lanes of b where mask is false
por xmm2, xmm0 ; combine the two halves
Figyeld meg, hogy a pandn aszimmetriája itt kifizetődik: a maszk a céloperandusban van, ott negálódik, és egyetlen utasításban választ a b-ből.
Ez a minta az elágazásmentes kiválasztás csomagolt formája.
Minden sáv kiszámítódik, és egyedül a maszk dönti el, melyik érték marad meg; jcc sehol sem szerepel.
Dedikált blend utasítások
Vannak olyan utasítások, amelyek közvetlenül elvégzik ugyanezt a kiválasztást, és elemenként egy bitet olvasnak ki egy maszkregiszterből.
Ezeket blend utasításoknak nevezzük:
| utasítás |
elem |
maszk forrása |
pblendvb |
bájt |
implicit xmm0
|
blendvps |
32 bites sáv |
implicit xmm0
|
blendvpd |
64 bites sáv |
implicit xmm0
|
Figyeld meg, hogy az első utasítás az egész szintaxist követi, míg a másik kettő a lebegőpontosét.
Mivel azonban ezek az utasítások egyszerűen nyers bájtokat választanak ki, bármelyikük használható egészekkel és lebegőpontos számokkal is.
A blend minden elemnél megtartja a céloperandust, ha a hozzá tartozó maszkelem legfelső bitje törölt, és a forrásoperandust veszi, ha az be van állítva.
Csak azt a legfelső bitet veszi figyelembe, amit egy összehasonlításból származó maszk teljesít is, hiszen a sávjai csupa egyesek vagy csupa nullák.
A maszkregiszter mindig xmm0, ami implicit:
movaps xmm0, [rel mask] ; the selecting mask must be in xmm0
movaps xmm1, [rel b] ; destination: kept where the mask bit is clear
blendvps xmm1, [rel a] ; source: taken where the mask bit is set
A pblendvb-vel más méreteknél is kiválaszthatók sávok egy összehasonlítási maszkból.
Mivel egy igaz sávban minden bájt csupa egyes, a pblendvb az összeset kiválasztja.
Ezek az utasítások mind a v betűt fűzik az elvégzett művelet (blend) után.
Ez a v a változó szót jelöli, mert a kiválasztás nem statikus: egy regisztertől függ.
Vannak v nélküli változatok is, amelyek egy immediate érték alapján választanak.
Ezek ugyanazt a mintát követik: kiválasztják az i sávot, ha az immediate i. bitje be van állítva.
A maszktól vissza a skaláris világba
Bár hatékony, a SIMD-kód messze nem olyan rugalmas, mint a skaláris kód.
Sok helyzetben szükség van arra, hogy egy csomagolt regiszterből visszatérjünk a skaláris utasítások világába.
A movmsk utasításcsalád hidat képez a két világ között.
Ezek az utasítások minden sáv legfelső bitjét emelik ki egy általános célú regiszterbe:
| utasítás |
mit gyűjt ki |
az eredmény szélessége |
pmovmskb |
16 bájt legfelső bitje |
16 bit |
movmskps |
4 duplaszó legfelső bitje |
4 bit |
movmskpd |
2 négyszeres szó legfelső bitje |
2 bit |
Ha összehasonlítás után használjuk, minden beállított bit egy „igaz” sávot jelöl, minden törölt bit pedig egy „hamis” sávot.
Ez az eredmény aztán a szokásos módon manipulálható skaláris utasításokkal.
Például a popcnt megszámolja az egyezések számát, a tzcnt pedig megkeresi az elsőt.
Az általános célú regiszter 32 vagy 64 bites szélességű lehet.
Egy teljes vektor vizsgálata
A skaláris test utasításnak is van csomagolt változata: a ptest.
Hasonlít a skaláris megfelelőjéhez abban, hogy AND műveletet végez két operandus között, anélkül hogy módosítaná őket.
A test-tel ellentétben a ptest ANDN műveletet is végez, amely tagadja az első operandust.
Így a ptest felfogható a pand és a pandn nem roncsoló változataként, amely az eredmény alapján állítja be a jelzőbiteket.
Akárcsak ez a két utasítás, a ptest is egyetlen sávként kezeli a teljes SIMD-regisztert, ezért nem vesz fel méretelőtagot.
Ha egy AND művelet eredménye 0, akkor a ZF beáll, ha pedig az ANDN művelet eredménye 0, akkor a CF áll be.
Ez azt jelenti, hogy a ptest egyszerre használható csupa egyes és csupa nulla maszk vizsgálatára:
- Ha a
ptest-et egy regiszterre önmagával futtatjuk, az csak akkor állítja be a ZF-et, ha a regiszter csupa nulla.
Ez utánozza azt a gyakori skaláris idiómát, amikor a test-et egy regiszterre önmagával futtatjuk 0 ellenőrzésére.
- Ha a
ptest-et egy regiszterre csupa egyes maszkkal futtatjuk, az csak akkor állítja be a CF-et, ha a regiszter csupa egyes.
Ráadásul a ZF-et csak akkor állítja be, ha a regiszter csupa nulla, így egyszerre mindkét maszk ellenőrizhető.
pxor xmm0, xmm0 ; all zeros
pcmpeqb xmm1, xmm1 ; all ones
pcmpeqb xmm2, xmm2
ptest xmm0, xmm0 ; ZF set: a register against itself detects all zeros
ptest xmm0, xmm1 ; ZF set, CF clear: xmm0 is all zeros, not all ones
ptest xmm2, xmm1 ; CF is set only if xmm2 is all ones
A ptest eredménye a szokásos módon használható elágazáshoz vagy elágazásmentes utasításokban, például a setcc-ben vagy a cmovcc-ben.
Tanulófeladat
