Tracks on Tracks on Tracks

Listas

Uma lista em Gleam é uma coleção imutável de zero ou mais valores. Os valores em uma lista devem ter todos o mesmo tipo. Como listas são imutáveis, uma vez que uma lista foi construída, seu valor nunca pode mudar. Quaisquer funções/operadores que pareçam modificar uma lista (como adicionar um elemento) na verdade retornarão uma nova lista.

Listas podem ser definidas assim:

let empty = []
let singleValue = [5]
let threeValues = ["a", "b", "c"]

A forma mais comum de adicionar um elemento a uma lista é por meio da sintaxe de espalhamento:

let two_to_four = [2, 3, 4]
let one_to_four = [1, ..two_to_four]
// -> [1, 2, 3, 4]

O módulo gleam/list da biblioteca padrão do Gleam contém muitas funções úteis para trabalhar com listas. Esse módulo é muito usado em código Gleam, então vale a pena se familiarizar com ele.

Padrões de listas podem ser usados em expressões case para corresponder a listas e atribuir os valores contidos a variáveis:

pub fn describe(list: List(String)) -> String {
  case list {
    [] -> "Empty list"
    [x] -> "List with one item: " <> x
    [x, y] -> "List with two items: " <> x <> " and " <> y
    _ -> "List with three or more items"
  }
}

Além de corresponder a listas de comprimento exato, a sintaxe de espalhamento pode ser usada para corresponder a listas com pelo menos um determinado comprimento:

pub fn describe(list: List(String)) -> String {
  case list {
    [_, _, ..] -> "List with at least two items"
    [_] -> "List with one item"
    [] -> "Empty list"
  }
}

A sintaxe de espalhamento também pode ser usada para atribuir o restante da lista a uma variável:

pub fn remove_first_item(list: List(String)) -> List(String) {
  case list {
    // Return the list without the first item
    [_, ..rest] -> rest

    // There's no first item to remove, return an empty list
    _ -> []
  }
}

Expressões case devem ter um padrão para todo valor possível do tipo com o qual se está fazendo correspondência, então um padrão de descarte final (_) costuma ser usado para lidar com quaisquer valores restantes.