Треки на треках на треках

Масиви

Масив у Gleam - це незмінна колекція з нуля або більше значень. Усі значення в масиві мусять мати той самий тип. Оскільки масиви незмінні, то щойно масив створено, його значення вже не може змінитися. Будь-які функції чи оператори, які нібито змінюють масив (наприклад, додають елемент), насправді повертають новий масив.

Масиви можна визначити так:

let empty = []
let singleValue = [5]
let threeValues = ["a", "b", "c"]

Найпоширеніший спосіб додати елемент до масиву - скористатися синтаксисом розгортання:

let two_to_four = [2, 3, 4]
let one_to_four = [1, ..two_to_four]
// -> [1, 2, 3, 4]

Модуль gleam/list зі стандартної бібліотеки Gleam містить багато корисних функцій для роботи з масивами. Цей модуль дуже часто використовують у коді Gleam, тож варто з ним ознайомитися.

Шаблони масивів можна використовувати у виразах case, щоб зіставляти масиви та присвоювати змінним значення, які в них містяться:

pub fn describe(list: List(String)) -> String {
  case list {
    [] -> "Empty list"
    [x] -> "List with one item: " <> x
    [x, y] -> "List with two items: " <> x <> " and " <> y
    _ -> "List with three or more items"
  }
}

Крім зіставлення з масивами точної довжини, синтаксис розгортання дає змогу зіставляти масиви довжиною щонайменше певного розміру:

pub fn describe(list: List(String)) -> String {
  case list {
    [_, _, ..] -> "List with at least two items"
    [_] -> "List with one item"
    [] -> "Empty list"
  }
}

Синтаксис розгортання також дає змогу присвоїти решту масиву змінній:

pub fn remove_first_item(list: List(String)) -> List(String) {
  case list {
    // Return the list without the first item
    [_, ..rest] -> rest

    // There's no first item to remove, return an empty list
    _ -> []
  }
}

Вирази case повинні мати шаблон для кожного можливого значення типу, з яким зіставляють, тож останній шаблон ігнорування (_) часто використовують, щоб обробити всі решта значень.