متجر الملصقات

الأنواع الوهمية

الأنواع الوهمية هي معاملات نوع في نوع مخصص لا تُستخدم في أي من مُنشئات القيم الخاصة بذلك النوع.

قد يبدو هذا مجردًا بعض الشيء، فإليك مثال:

pub type Length(unit) {
  Length(amount: Float)
}

في هذا المثال، لا يُستخدم معامل النوع unit في مُنشئ القيمة Length، لذا فإن unit نوع وهمي.

قد يبدو معامل النوع غير المستخدم بلا فائدة، لكن يمكن استخدامه لإضافة مزيد من القيود على طريقة استخدام قيم Length.

على سبيل المثال، يمكن أن تكون لدينا دالة double تضاعف الطول. إنها تعمل مع أطوال من أي وحدة، لذا فإن معامل النوع متغير نوع عام.

// This function accepts all Length values
pub fn double(length: Length(unit)) -> Length(unit) {
  Length(length.amount *. 2.0)
}

يمكن أن تكون لدينا أيضًا دالة add_inch لا تعمل إلا إذا كان الطول بالبوصة.

// A unit type for inches. It is never constructed so we don't
// define any constructors for it.
pub type Inches

pub fn add_inch(length: Length(Inches)) -> Length(Inches) {
  Length(length.amount +. 1.0)
}

لن تقبل دالة add_inch أطوالًا بأي معامل وحدة آخر، فقد استُخدم النوع الوهمي لضمان استخدام الوحدة الصحيحة فقط.

يمكن أيضًا كتابة دالة تضمن أن قيمتي طول تنتميان إلى الوحدة نفسها، باستخدام متغير النوع نفسه لكليهما.

pub fn add(a: Length(unit), b: Length(unit)) -> Length(unit) {
  Length(a.amount +. b.amount)
}

let two_meters: Length(Meters) = Length(2.0)
let two_inches: Length(Inches) = Length(2.0)

add(two_meters, two_meters)
// -> Length(4.0): Length(Meters)

add(two_meters, two_inches)
// Type error! The unit type parameters do not match.

يمكن أن تعمل الأنواع الوهمية جيدًا مع الأنواع المعتمة. إذا لم تتمكن وحدات أخرى من إنشاء قيم Length، فيمكننا ضمان عدم إنشائها بنوع وحدة غير صالح، وأن الدوال المعرّفة أعلاه وحدها هي التي يمكن استخدامها معها.