كل من استخدم Python قد استخدم على الأرجح استيعابات المصفوفات، وهي جزء محوري من صياغة Python منذ إصداراتها المبكرة.
والشيء المريح إلى هذا الحد يجد طريقه تدريجيًا إلى لغات أخرى، ومنها Julia.
الاستيعابات خيار وليست ضرورة لمبرمجي Julia، إذ توجد عادةً بدائل (البثّ، والدوال عالية الرتبة، وما إلى ذلك).
مع ذلك، غالبًا ما يوفّر الاستيعاب طريقة بسيطة ومقروءة وعالية الأداء لبناء مصفوفة.
واستخدامه في النهاية مسألة ذوق شخصي، ورأيك في Python مقابل اللغات الوظيفية.
الصياغة في معظمها نسخة مباشرة من Python، لكن مع امتدادات للمصفوفات متعددة الأبعاد.
متغير واحد
أسلوب Pythonي خالص، بما في ذلك جملة if الاختيارية.
julia> [x^2 for x in 1:3]
3-element Vector{Int64}:
1
4
9
julia> [x^2 for x in 1:3 if isodd(x^2)]
2-element Vector{Int64}:
1
9
يتوقف شكل المخرجات على تفاصيل الاستيعاب: فهو عادةً يماثل مجموعة الإدخال في الحالات البسيطة، لكنه يُسطَّح إلى Vector بفعل جملة if.
julia> m
2×3 Matrix{Int64}:
1 2 3
4 5 6
julia> [x^2 for x in m]
2×3 Matrix{Int64}:
1 4 9
16 25 36
julia> [x^2 for x in m if isodd(x^2)]
3-element Vector{Int64}:
1
25
9
متغيرات متعددة، ومخرجات من نوع Vector
وكما في Python، يمكننا استخدام عدة جمل for بمتغيرات مختلفة، مع مجموعات إدخال متشابهة أو مختلفة.
julia> [x * y for x in 1:3 for y in 4:6]
9-element Vector{Int64}:
4
5
6
8
10
12
12
15
18
julia> [x * y for x in 1:3 for y in 4:6 if isodd(x * y)]
2-element Vector{Int64}:
5
15
وهذا مكافئ لحلقات متداخلة.
وتكون المخرجات أحادية البعد، حتى عندما يكون الإدخال مصفوفة.
julia> m
2×3 Matrix{Int64}:
1 2 3
4 5 6
julia> [x*y for x in m for y in m]
36-element Vector{Int64}:
1
4
2
5
(truncated output...)
متغيرات متعددة، ومخرجات متعددة الأبعاد
وصف القسم السابق عدة جمل for تفصل بينها مسافات فقط.
وفي هذا القسم توجد جملة for واحدة، والمتغيرات مفصولة بفواصل.
julia> [(x, y) for x in 1:3, y in 4:6]
3×3 Matrix{Tuple{Int64, Int64}}:
(1, 4) (1, 5) (1, 6)
(2, 4) (2, 5) (2, 6)
(3, 4) (3, 5) (3, 6)
كل متغير في الاستيعاب يُنشئ بُعدًا جديدًا في المخرجات، مع عنصر مقابل لكل تركيبة ممكنة من المتغيرات.
في المثال أعلاه، يزداد x نزولًا مع الصفوف، ويزداد y عرضًا مع الأعمدة.
ويمكن الوصول إلى أبعاد أعلى، مع التحذيرات المعتادة بشأن سهولة قراءة المخرجات.
تعبيرات المولّد
ركّزت الأقسام السابقة على مخرجات المصفوفات، حيث يوضع الاستيعاب داخل الأقواس المربعة [ ... ].
وعندما نستبدل الأقواس المربعة بالأقواس الهلالية ( ... ) يحدث شيء مختلف: نحصل على generator expression، وهو مكرّر يُقيَّم عند الحاجة ويمكنه إنتاج القيمة التالية عند الطلب.
julia> g = ((x, y) for x in 1:3, y in 4:6)
Base.Generator{Base.Iterators.ProductIterator{Tuple{UnitRange{Int64}, UnitRange{Int64}}}, var"#9#10"}(var"#9#10"(), Base.Iterators.ProductIterator{Tuple{UnitRange{Int64}, UnitRange{Int64}}}((1:3, 4:6)))
# Indexing fails with a generator, the entries don't exist yet
julia> g[1, 2]
ERROR: MethodError: no method matching getindex(::Base.Generator{Base.Iterators.ProductIterator{Tuple{UnitRange{…}, UnitRange{…}}}, var"#9#10"}, ::Int64, ::Int64)
# conversion to array
julia> collect(g)
3×3 Matrix{Tuple{Int64, Int64}}:
(1, 4) (1, 5) (1, 6)
(2, 4) (2, 5) (2, 6)
(3, 4) (3, 5) (3, 6)
# generators are mainly designed for iteration
julia> [i * j for (i, j) in g]
3×3 Matrix{Int64}:
4 5 6
8 10 12
12 15 18
عندما تُستخدم نتيجة الاستيعاب فورًا في مزيد من المعالجة، فقد يكون المولّد موفّرًا للذاكرة، إذ يغني عن تخزين مصفوفة وسيطة كبيرة.
ولا يحتاج المولّد المستخدَم كوسيط دالة إلى أقواس إضافية.
# inefficient
julia> v = [x^2 for x in 1:1e6];
julia> sum(v)
3.333338333335e17
# better - use a generator
julia> sum(x^2 for x in 1:1e6)
3.3333383333312755e17
صياغة المولّد مطابقة لصياغة الاستيعاب، فيما عدا الأقواس المحيطة.
وقد تكون المولّدات ملائمة أيضًا عند إنشاء القواميس.
julia> Dict(x => x^2 for x in 1:5)
Dict{Int64, Int64} with 5 entries:
5 => 25
4 => 16
2 => 4
3 => 9
1 => 1
تمرين تعلّمي
