Τα μαγικά της Elyse

Ένας κεντρικός στόχος της Julia είναι να μπορεί να εκτελεί υπολογισμούς σε αριθμητικά δεδομένα, γρήγορα και αποδοτικά. Πάρα πολλά αριθμητικά δεδομένα.

Συνήθως, τα δεδομένα αποθηκεύονται σε πίνακες (ή σε κάποιον συναφή τύπο), οπότε είναι λογικό να πούμε ότι οι πίνακες βρίσκονται στην καρδιά της γλώσσας Julia.

Οι πίνακες μπορούν να έχουν αυθαίρετο μέγεθος (με μόνο περιορισμό τη μνήμη του υλικού σου) και αυθαίρετα πολλές διαστάσεις.

Αυτή η εισαγωγική έννοια επικεντρώνεται στα βασικά των μονοδιάστατων πινάκων, που ονομάζονται Vector.

Δημιουργία Vector

Στη Julia, ένα Vector είναι μια διατεταγμένη ακολουθία τιμών, στις οποίες μπορείς να έχεις πρόσβαση με αριθμό θέσης.

Ο απλούστερος τρόπος για να δημιουργήσεις ένα Vector είναι να απαριθμήσεις τις τιμές μέσα σε αγκύλες:

julia> num_vec = [1, 4, 9]
3-element Vector{Int64}:
 1
 4
 9

julia> str_vec = ["arrays", "are", "important"]
3-element Vector{String}:
 "arrays"
 "are"
 "important"

Ο τύπος Vector ταιριάζει με τον τύπο κάθε στοιχείου.

Άρα τα Vector πρέπει να είναι ομογενή (όλα τα στοιχεία ίδιου τύπου);

Σε κάποιο βαθμό, ναι, και συνιστάται να το επιδιώκεις αυτό, αν θέλεις την καλύτερη απόδοση. Ωστόσο, η Julia μπορεί να παρακάμψει αυτόν τον περιορισμό (όταν χρειάζεται) χρησιμοποιώντας τον τύπο Any:

julia> mixed_vector = [1, "str", 'c']
3-element Vector{Any}:
 1
  "str"
  'c': ASCII/Unicode U+0063 (category Ll: Letter, lowercase)

Όταν δημιουργείς ένα κενό Vector, η Julia χρησιμοποιεί από προεπιλογή τον τύπο στοιχείου Any, αλλά αυτό μπορεί να οριστεί πιο συγκεκριμένα, δηλώνοντας τον κενό πίνακα με τον επιθυμητό τύπο στοιχείου.

julia> empty_vec = []
Any[]

julia> empty_int_vec = Int64[]
Int64[]

Διάβασε και θυμήσου αυτόν τον κανόνα:

• Από προεπιλογή, η προσπέλαση με θέση στη Julia ξεκινά από το 1, όχι από το 0.

Αυτό είναι οικείο σε όποιον έχει χρησιμοποιήσει άλλες γλώσσες επιστήμης δεδομένων (R, Matlab, Fortran...), αλλά μπορεί να φαίνεται σοκαριστικό σε επιστήμονες υπολογιστών με υπόβαθρο σε γλώσσες τύπου C.

Κατά τα άλλα, οι θέσεις λειτουργούν όπως ίσως μαντεύεις: απλώς βάλ' τες μέσα σε αγκύλες:

squares = [0, 1, 4, 9, 16]
squares[1]  # 0
squares[3]  # 4
squares[begin]  # 0 ("begin" is synonym for 1)
squares[end]  # 16 ("end" is synonym for length(squares))

Πρόσεξε την ευκολία της προσπέλασης με end (που είναι πολύ χρήσιμη) και begin (που μάλλον δεν είναι).

Οι προγραμματιστές Python ίσως αναρωτιούνται για τις αρνητικές θέσεις. Μην το κάνεις: δεν υπάρχουν στη Julia και θα πετάξουν ένα BoundsError, όπως και οποιαδήποτε θέση μικρότερη από το 1 ή μεγαλύτερη από το length(squares).

Λειτουργίες με Vector

Τα Vector στη Julia είναι μεταβλητά: μπορούμε να αλλάξουμε το περιεχόμενο μεμονωμένων κελιών.

julia> vals = [1, 3, 5, 7]
4-element Vector{Int64}:
 1
 3
 5
 7

julia> vals[2] = 4  # reassign the value of this element
4

# Only the value at position 2 changes:
julia> vals
4-element Vector{Int64}:
 1
 4
 5
 7

Υπάρχουν πολλές συναρτήσεις διαθέσιμες για τον χειρισμό Vector, αν και η τεκμηρίωση της Julia τις γενικεύει σε "συλλογές" αντί για Vector.

Σημείωσε ότι, κατά σύμβαση, οι συναρτήσεις που μεταβάλλουν το όρισμά τους έχουν ! στο όνομά τους. Ο μεταγλωττιστής δεν θα το επιβάλει, αλλά είναι μια πολύ ισχυρή σύμβαση στον κόσμο της Julia.

Αυτές είναι μερικές από τις χρήσιμες συναρτήσεις:

• Για να προσθέσεις τιμές στο τέλος του Vector, χρησιμοποίησε την push!().
• Για να αφαιρέσεις την τελευταία τιμή, χρησιμοποίησε την pop!().
• Για να επέμβεις στην αρχή του Vector, οι αντίστοιχες συναρτήσεις είναι οι pushfirst!() και popfirst!().
• Για να εισαγάγεις ή να αφαιρέσεις ένα στοιχείο σε οποιαδήποτε θέση, υπάρχουν οι insert!() και deleteat!().

julia> vals = [1, 3]
2-element Vector{Int64}:
 1
 3

julia> push!(vals, 5, 6)  # can add multiple values
4-element Vector{Int64}:
 1
 3
 5
 6

julia> pop!(vals)  # mutates vals, return popped value
6

julia> vals
3-element Vector{Int64}:
 1
 3
 5