Чари Еліз

Одна з головних цілей Julia - уміти швидко й ефективно виконувати обчислення над числовими даними. Багато числових даних.

Зазвичай дані зберігаються в масивах (або в якомусь спорідненому типі), тож цілком слушно сказати, що масиви лежать у самому серці мови Julia.

Масиви можуть бути довільного розміру (обмеженого лише обсягом памʼяті обладнання) і мати довільну кількість вимірів.

Цей вступний концепт зосереджується на основах одновимірних масивів, які називають векторами.

Створення векторів

У Julia вектор - це впорядкована послідовність значень, доступ до яких можна отримати за номером індексу.

Найпростіший спосіб створити вектор - перелічити значення в квадратних дужках:

julia> num_vec = [1, 4, 9]
3-element Vector{Int64}:
 1
 4
 9

julia> str_vec = ["arrays", "are", "important"]
3-element Vector{String}:
 "arrays"
 "are"
 "important"

Тип Vector відповідає типу кожного елемента.

То вектори мають бути однорідними (усі елементи одного типу)?

Певною мірою так, і якщо ми хочемо найкращої продуктивності, варто до цього прагнути. Однак Julia, коли потрібно, оминає це обмеження за допомогою типу Any:

julia> mixed_vector = [1, "str", 'c']
3-element Vector{Any}:
 1
  "str"
  'c': ASCII/Unicode U+0063 (category Ll: Letter, lowercase)

Коли ми створюємо порожній вектор, Julia типово використовує тип елементів Any, але його можна задати конкретніше, вказавши потрібний тип елементів для порожнього масиву.

julia> empty_vec = []
Any[]

julia> empty_int_vec = Int64[]
Int64[]

Прочитаймо це правило й запамʼятаймо його:

• Індексація в Julia типово починається з 1, а не з 0.

Це звично кожному, хто користувався іншими мовами для аналізу даних (R, Matlab, Fortran...), але може видатися шокуючим для фахівців із компʼютерних наук, які мають досвід роботи з мовами, схожими на C.

В іншому разі індекси працюють так, як неважко здогадатися: просто беремо їх у квадратні дужки:

squares = [0, 1, 4, 9, 16]
squares[1]  # 0
squares[3]  # 4
squares[begin]  # 0 ("begin" is synonym for 1)
squares[end]  # 16 ("end" is synonym for length(squares))

Звернімо увагу на зручність індексації за допомогою end (це дуже корисно) і begin (а це, мабуть, ні).

Програмісти Python можуть замислитися про відʼємні індекси. Не варто: у Julia їх немає, і вони спричинять помилку BoundsError, як і будь-який індекс, менший за 1 або більший за length(squares).

Операції з векторами

Вектори в Julia змінювані: ми можемо змінювати вміст окремих елементів.

julia> vals = [1, 3, 5, 7]
4-element Vector{Int64}:
 1
 3
 5
 7

julia> vals[2] = 4  # reassign the value of this element
4

# Only the value at position 2 changes:
julia> vals
4-element Vector{Int64}:
 1
 4
 5
 7

Є чимало функцій для роботи з векторами, хоча документація Julia узагальнює їх до «колекцій», а не векторів.

Зауважмо, що за домовленістю функції, які змінюють свої вхідні дані, мають ! у назві. Компілятор цього не перевіряє, але в світі Julia це дуже стійка домовленість.

Ось кілька корисних функцій:

• Щоб додати значення в кінець вектора, використаймо push!().
• Щоб видалити останнє значення, використаймо pop!().
• Для роботи з початком вектора є відповідні функції: pushfirst!() і popfirst!().
• Щоб вставити або видалити елемент у будь-якій позиції, є insert!() і deleteat!().

julia> vals = [1, 3]
2-element Vector{Int64}:
 1
 3

julia> push!(vals, 5, 6)  # can add multiple values
4-element Vector{Int64}:
 1
 3
 5
 6

julia> pop!(vals)  # mutates vals, return popped value
6

julia> vals
3-element Vector{Int64}:
 1
 3
 5