Parcours
/
Factor
Factor
/
Exercices
/
Chorégraphie de coordonnées
Chorégraphie de coordonnées

Chorégraphie de coordonnées

Exercice d'apprentissage

Introduction

Quand une quotation a besoin de se souvenir de valeurs de son environnement, ce que d'autres langages appellent une closure, Factor utilise deux outils : le mot curry et la syntaxe fry '[ ].

curry : capturer une valeur

curry (dans kernel) prend une valeur et une quotation et renvoie une nouvelle quotation avec cette valeur incorporée :

curry ( value quot -- newquot )
3 [ + ] curry .
! => [ 3 + ]

10 3 [ + ] curry call .
! => 13

Applique curry deux fois pour capturer deux valeurs :

2 3 [ + + ] curry curry .
! => [ 2 3 + + ]

compose : assembler deux quotations

compose (dans kernel) colle deux quotations ensemble :

compose ( quot1 quot2 -- quot )
[ 1 + ] [ 2 * ] compose .
! => [ 1 + 2 * ]

5 [ 1 + ] [ 2 * ] compose call .
! => 12

Les quotations fry : capturer plusieurs valeurs

Au-delà d'une ou deux captures, les appels enchaînés à curry deviennent difficiles à lire. La syntaxe fry utilise '[ … ] avec un ou plusieurs _ comme emplacements réservés ; chaque _ est remplacé par une valeur prise sur la pile de données, dans l'ordre :

2 3 '[ _ _ + + ] .
! => [ 2 3 + + ]

curry comme la syntaxe fry consomment leurs valeurs sur la pile au moment où la closure est construite. La ligne ci-dessus ne laisse rien sur la pile et remplace directement [ + + ] curry curry.

Les emplacements sont remplis de gauche à droite avec les valeurs de la pile du bas vers le haut : 2 3 '[ _ _ ] donne [ 2 3 ], et non [ 3 2 ].

La syntaxe fry atteint aussi l'intérieur des quotations imbriquées, ce qui permet de placer les valeurs capturées exactement là où on le souhaite :

2 '[ [ _ > ] filter ] { 1 2 3 4 5 } swap call( s -- s ) .
! => { 3 4 5 }

Le _ se trouve à l'intérieur du [ … ] interne, mais fry le remplit quand même.

call avec un effet déclaré

Quand on finit par exécuter une quotation mémorisée, on déclare son effet de pile sur call pour que le compilateur puisse en vérifier les types :

{ 3 4 5 } [ first2 + ] call( p -- n ) .
! => 7

{ 3 4 5 } [ first ] call( p -- n ) .
! => 3

Arithmétique vectorielle

Le vocabulaire math.vectors combine deux séquences de même longueur élément par élément. v+ et v* les additionnent ou les multiplient ; vmax et vmin gardent la plus grande ou la plus petite de chaque composante. Chacun renvoie un tableau de 2 éléments :

{ 1 1 } { 3 4 } v+ .    ! => { 4 5 }
{ 2 5 } { 3 -1 } v* .   ! => { 6 -5 }
{ 1 9 } { 4 4 } vmax .  ! => { 4 9 }
{ 1 9 } { 4 4 } vmin .  ! => { 1 4 }

Instructions

Ton équipe de design délaisse les transformations CSS au profit de Factor pour une partie de son travail de mise en page. Pour faire plaisir au reste de l'équipe, tu vas construire de petites transformations réutilisables, sous forme de quotations qui prennent un point 2D et renvoient un point 2D.

Un point est un tableau de deux éléments : { x y }.

1. Effectue une translation des coordonnées

Définis translate-2d pour qu'elle prenne deux valeurs dx et dy de la pile et renvoie une quotation qui applique une translation de (dx, dy) à un point.

{ 4 8 } 2 0 translate-2d call( p -- p' ) .
! => { 6 8 }

2. Mets les coordonnées à l'échelle

Définis scale-2d de la même façon : elle renvoie une quotation qui met un point à l'échelle selon (sx, sy).

{ 6 -3 } 2 2 scale-2d call( p -- p' ) .
! => { 12 -6 }

3. Compose deux transformations

Définis compose-transformations pour qu'elle prenne deux quotations de transformation f et g et renvoie une seule quotation qui applique f d'abord, puis g.

{ 0 1 } 2 0 translate-2d 2 2 scale-2d compose-transformations
call( p -- p' ) .
! => { 4 2 }

4. Applique une transformation

Définis apply-transformation pour qu'elle prenne de la pile un point et une quotation de transformation, et renvoie le point transformé.

{ 4 8 } 2 0 translate-2d apply-transformation .
! => { 6 8 }

5. Transforme plusieurs points à la fois

Définis transform-points pour qu'elle prenne un tableau de points et une quotation de transformation, et renvoie le tableau des points transformés.

{ { 0 0 } { 1 1 } { 2 2 } } 1 0 translate-2d transform-points .
! => { { 1 0 } { 2 1 } { 3 2 } }
Modifie via GitHub Le lien s'ouvre dans une nouvelle fenêtre ou un nouvel onglet
Factor Exercism

Prêt à commencer Chorégraphie de coordonnées ?

Inscris-toi sur Exercism pour apprendre et maîtriser Factor avec 47 concepts163 exercices, et un vrai mentorat humain, le tout gratuitement.