Elixir representerの正規化

Elixirのリプレゼンターは、いくつかの正規化を行います。 詳しくは、コードまたはテストデータを参照してください。

コメントとドキュメントを削除する

すべてのコメント、ドキュメント、モジュールドキュメント、型ドキュメントは削除されます。

変更前

defmodule Fake do
  @moduledoc """
  Fake module to demonstrate stuff
  """

  @doc "Not much to see here"
  def foo do
    # TODO: return bar
    nil
  end
end

変更後

defmodule Fake do
  def foo do
    nil
  end
end

インポートの順序を並べ替える

モジュールまたは関数の先頭にあるインポート文は、alias、use、require、importの順に並べ替えられます。

変更前

defmodule Fake do
  import D
  alias A.U.V
  use B
  alias A.{T, S}
  require C

  def foo do
    import Z
    alias X
    use Y
  end

  import NotTouched
  alias NotTouched
end

変更後

defmodule Fake do
  alias A.{S, T}
  alias A.U.V
  use B
  require C
  import D

  def foo do
    alias X
    use Y
    import Z
  end

  import NotTouched
  alias NotTouched
end

コードをフォーマットする

コードは[mix code][mix-code]を使ってフォーマットされ、do endブロックが強制されます。 パイプの中にある関数はすべて括弧を付けて書かれます。 型は括弧を付けずに書かれます。

変更前

defmodule    Fake   do
        @type foo() :: integer() | atom
def foo, do:    nil |> bar
end

変更後

defmodule Fake do
  @type foo() :: integer | atom
  def foo do
    nil |> bar()
  end
end

識別子を正規化する

識別子はプレースホルダーの値に正規化されます。 一部の特別な変数とモジュール属性（_、@spec、__MODULE__など）は置き換えられません。 マップ、構造体、キーワードリストのキーは正規化されません。

変更前

defmodule Fake do
  alias Fake, as: SuperFake
  @my_constant 42

  @impl true
  def foo(bar) when is_integer(bar) do
    bar + @my_constant
  end

  def foo(%{a: a} = bar) do
    %{bar | a: a + @my_constant}
  end

  def foo(_), do: nil
end

変更後

defmodule Placeholder_1 do
  alias Placeholder_1, as: Placeholder_2
  @placeholder_6 42
  @impl true
  def placeholder_4(placeholder_5) when is_integer(placeholder_5) do
    placeholder_5 + @placeholder_6
  end

  def placeholder_4(%{a: placeholder_7} = placeholder_5) do
    %{placeholder_5 | a: placeholder_7 + @placeholder_6}
  end

  def placeholder_4(_) do
    nil
  end
end

マップと構造体のキーを並べ替える

マップと構造体のキーは並べ替えられます。 キーワードリストのキーは並べ替えられません。

変更前

defmodule Fake do
  def foo do
    %MyStruct{z: 3, y: 2, x: 1}
    m = %{c: 3, a: 1, b: 2}
    %{m | b: 20, a: 10}
    [b: 2, a: 1]
  end
end

変更後

defmodule Fake do
  def foo do
    %MyStruct{x: 1, y: 2, z: 3}
    placeholder_3 = %{a: 1, b: 2, c: 3}
    %{placeholder_3 | a: 10, b: 20}
    [b: 2, a: 1]
  end
end