タプルとは、要素を順番に並べた有限のリストで、イミュータブルです。
タプルでは、すべての位置が固定された型を持っている必要があります。
そのため、コンパイラーは各位置にどの型があるかを把握しています。
タプルで使われる型は位置ごとに異なっていてもかまいませんが、それらの型はコンパイル時に判明している必要があります。
タプルの作成
タプルの値の型をコンパイル時に解釈できるかどうかに応じて、タプルの作成方法は異なります。
値がコンパイル時に判明している場合は、タプルリテラルの構文でタプルを作成できます。そうでない場合は、明示的に宣言する必要があります。
また、値の型がタプルで指定した型と一致していること、そして値の個数が指定した型の個数と一致していることも重要です。
タプルリテラルの構文で定義する例を次に示します。
tuple = {1, "foo", 'c'} # Tuple(Int32, String, Char)
Tupleクラスを使ってタプルを作成することもできます。
tuple = Tuple(Int32, String, Char).new(1, "foo", 'c')
あるいは、タプルを代入する変数の型を明示的に指定することもできます。
tuple : Tuple(Int32, String, Char) = {1, "foo", 'c'}
タプルの型を明示的に指定すると、ある位置がユニオン型を保持するように定義できるため、便利なことがあります。
つまり、1つの位置に複数の型を入れられるということです。
tuple : Tuple(Int32 | String, String, Char) = {1, "foo", 'c'}
変換
配列からタプルを作成する
Tupleクラスのfromメソッドを使うと、配列からタプルを作成できます。
そのためには、タプルの型を指定する必要があります。
array = [1, "foo", 'c']
tuple = Tuple(Int32, String, Char).from(array)
配列への変換
to_aメソッドを使うと、タプルを配列に変換できます。
変換後の配列の要素の型は、タプルの各要素の型のユニオンになります。
tuple = {1, "foo", 'c'}
array = tuple.to_a
array # => [1, "foo", 'c']
要素へのアクセス
配列と同じく、タプルのインデックスは0から始まります。つまり、最初の要素のインデックスは0です。
ただし配列と違い、各要素の型は固定されていてコンパイル時に判明しています。そのため、タプルのインデックスを指定したとき、要素の型はその位置に固有のものになります。
タプルの要素にアクセスするには、[]演算子を使います。
array = [1, "foo", 'c']
array[0] # => 1
typeof(array[0]) # => Int32 | String | Char
tuple = {1, "foo", 'c'}
tuple[0] # => 1
typeof(tuple[0]) # => Int32
配列から要素にアクセスする場合とのもう1つの違いは、インデックスを指定すると、コンパイラーがそのインデックスがタプルの範囲内にあるかどうかをチェックすることです。
つまり、実行時エラーではなくコンパイル時エラーになります。
tuple = {1, "foo", 'c'}
tuple[3]
# => Error: index out of bounds for Tuple(Int32, String, Char) (3 not in -3..2)
ただし、インデックスが変数に格納されている場合、コンパイラーはコンパイル時にそのインデックスがタプルの範囲内にあるかどうかを確認できないため、代わりに実行時エラーになります。
部分タプル
[]演算子に範囲を指定すると、タプルの部分タプルを取得できます。
返されるのは、指定した範囲の要素を持つ新しいタプルです。
範囲はコンパイル時に与える必要があります。そうでないと、コンパイラーは部分タプルの要素の型を把握できません。
つまり、範囲は範囲リテラルでなければならず、変数に代入してはいけません。
tuple = {1, "foo", 'c'}
subtuple = tuple[0..1] # Tuple(Int32, String)
i = 0..1
tuple[i]
# Error: Tuple#[](Range) can only be called with range literals known at compile-time
タプルを使う場面
決まった個数の値をまとめたいときで、しかも値の型がコンパイル時に判明している場合に、タプルは役立ちます。
なぜなら、タプルはイミュータブルであるため、配列よりもメモリを消費せず、高速だからです。
もう1つの用途は、メソッドから複数の値を返すことです。
値の型が異なる場合に特に便利です。タプルの位置ごとに異なる型を持てるからです。
サイズが大きくなったり小さくなったりするデータ構造が必要な場合や、頻繁に変更する必要がある場合には、タプルを使うべきではありません。
シンボルとは、値を参照するために使える名前付きの識別子です。
シンボルはシンボルリテラルで作成します。名前の前に:を付ける形で、たとえば:fooのようになります。
引用符で囲んで書くこともでき、たとえば:"foo"のように書きます。これにより、たとえば名前に空白を入れられます。
:foo # => :foo
:"foo boo" # => :"foo boo"
:foo == :"foo" # => true
シンボルは、名前付きタプルのキーや、メソッドや変数の名前を表すためなど、言語のさまざまな場所で使われます。
Crystalのシンボル
Crystalのシンボルは、Rubyのシンボルとはかなり異なります。
Crystalでは、シンボルは定数の一種であり、そのためコンパイル時に割り当てられます。
つまり、Rubyでは可能なシンボルの動的な作成が、Crystalではできません。
CrystalのシンボルはInt32として表現されるため、非常に効率的です。
変換
シンボルは文字列に変換できますが、その逆はできません。
シンボルはコンパイル時に作成され、文字列は実行時に作成されるからです。
:foo.to_s # => "foo"
学習演習
