ランダム
Elmのような純粋関数型言語では、同じ引数で呼び出された関数は、常に同じ値を返さなければなりません。
そのため、型シグネチャがrand : Intである関数はrand = 4としか実装できません。これでは乱数を生成するには心もとない話です。
では、Elmでランダムな値はどうやって生成するのでしょうか？ 問題を2つに分けます。まず、生成したい値をRandom.Generator aで記述し、次に値を生成します。
値を生成する1つ目の方法は、initialSeed : Int -> SeedでRandom.Seedを作り、次にstep : Generator a -> Seed -> ( a, Seed )を使うことです。これは値と新しいシードを返します。
どちらの関数も純粋なので、同じ引数で2回呼び出すと、同じ値が生成されることに注意してください。
値を生成する2つ目の方法は、generate : (a -> msg) -> Generator a -> Cmd msgを使うことですが、これはElmアプリケーションの中でしか行えません。
その場合、Elmランタイムはstepだけでなく、外部の純粋でないリソースも使ってシードを生成することがあります。
ここからは、ジェネレーターに焦点を当てます。
例を示すために、initialSeedとstepを使って、ジェネレーターからいくつかの値を生成する関数generate : Int -> Generator a -> List aを定義したとしましょう。
Randomモジュールには、特定の範囲の整数と小数を生成するための基本的なジェネレーターが2つ用意されています。
generate 5 (Random.int -5 5)
--> [0, 3, -5, 5, 0]
generate 3 (Random.float 0 5)
--> [1.61803, 3.14159, 2.71828]
これらの値は、タプルにまとめたり、値の配列にまとめたりできます。
generate 2 (Random.list 3 (Random.int 0 3))
--> [[0, 3, 3], [1, 3, 2]]
generate 2 (Random.pair (Random.int 0 3) (Random.float 10 10.3))
--> [(0, 10.23412), (2, 10.17094)]
elm-community/random-extraパッケージには、文字列、日付、辞書、配列、集合など、さまざまなデータ構造のためのジェネレーターがたくさん用意されています。
Random.constantを使うと、常に1つの値だけを返すジェネレーターを作れます。
generate 4 (Random.constant "hello")
--> ["hello", "hello", "hello", "hello"]
Random.uniformを使うと、与えられた要素の中から等しい確率でランダムに選べます。
generate 5 (Random.uniform Red [Green, Blue])
--> [Red, Blue, Blue, Green, Red]
Random.uniformが2つの引数（Redと[Green, Blue]）を取るのは、選べる値が少なくとも1つあることを保証するためです。配列を1つだけ渡すと、空になっている可能性があるからです。
Random.weightedを使えば、確率を調整することもできます。
generate 5 (Random.weighted (80, Red) [(15, Green), (5, Blue)])
--> [Red, Red, Green, Red, Red]
値の合計は100でなくてもかまいません。最終的には正規化されます。
Random.mapを使うと、ジェネレーターの中の値に手を加えられます。
generate 3 (Random.int 1 6 |> Random.map (\n -> n * 10))
--> [30, 60, 10]
Random.map2からRandom.map5までを使えば、より多くのジェネレーターを組み合わせることもできます。
position =
Random.map3
(\x y z -> Position x y z)
(Random.float -100 100)
(Random.float -100 100)
(Random.float -100 100)
generate 1 position
--> [Position 33.788 -98.321 10.0845]
もっと複雑な用途には、Random.andThen : (a -> Generator b) -> Generator a -> Generator bがあります。これは、あるジェネレーターが生成した値を使って別のジェネレーターを作れます。
bool = Random.uniform True [False]
failHalfOfTheTime : Generator a -> Generator (Maybe a)
failHalfOfTheTime generator =
bool
|> Random.andThen
(\boolResult ->
if boolResult then
Random.map Just generator
else
Random.constant Nothing
)
generate 6 (Random.int 0 1 |> failHalfOfTheTime)
--> [Nothing, Just 1, Just 0, Nothing, Just 1, Nothing]
ジェネレーターを自己再帰的に定義すると便利なことがあります。
そのような場合は、コンパイラーがジェネレーターを無限に展開しないように、Random.lazyを使う必要があるかもしれません。
type Peano
= Zero
| Next Peano
peano : Generator Peano
peano =
Random.uniform (Random.constant Zero)
[ Random.map Next (Random.lazy (\_ -> peano))
]
|> Random.andThen identity
generate 12 peano
--> [Zero, Next(Next(Zero)), Zero, Next(Zero), Zero, Zero, Next(Zero), Zero, Zero, Next(Zero), Next(Next(Next(Zero)))]
この例は少し重いので、分解してみましょう。
Peanoは正の整数を表す型です。Zeroが0、Next(Zero)が1、Next(Next(Zero))が2、というようになります。
peanoは、ランダムなPeanoの数値を得るために定義します。
まず、Random.lazyはロジックに何も付け加えず、コンパイラーがpeanoをpeanoの中に無限に書き込むのを防ぐだけであることに注意してください。
Random.uniformを使って、0（50%の確率）か、別のPeanoの数値に1を足したもの（50%の確率）のどちらかを選びます。
ただし、前の例とは違い、Random.uniformは値（Zeroなど）から選ぶのではなく、ジェネレーター（Random.constant Zeroなど）から選びます。peano自身を使いたいからです。
これはつまり、Random.uniformがGenerator (Generator Peano)型の値を返すということで、必要なものではありません。
ジェネレーターを「平坦化」するには、それをRandom.andThen : (a -> Generator b) -> Generator a -> Generator bにパイプします。ここではbがPeanoであってほしいところです。
Generator aはGenerator (Generator Peano)なので、aはGenerator Peanoでなければならず、関数(a -> Generator b)は(Generator Peano -> Generator Peano)型でなければなりません。
何も変更したくないので、identityが適切な選択です。
最後に、peanoはどんな数値を生成するのでしょうか？ 50%の確率で0を、50%の確率で自分自身をもう1回繰り返して1を足したものを生成することがわかります。
つまり、数値は0（50%の確率）、1（25%の確率）、2（12%の確率）、3（6%の確率）…となります。
peanoはいくらでも大きな数値を生成できますが、その確率は指数的に小さくなります。
学習演習
