名札

多くのプログラミング言語には、存在しない値を表すためにnullやnoneのような仕組みがあります。 Juliaは大量の（しばしば雑然とした）データを扱えるように設計されているため、「何もないこと」を表す形が複数用意されています。

全体のねらいは、見つかった欠損値や疑わしい値をその場で示し、例外を発生させずに処理を続けることです。

nothing

値が本当に存在しない場合、それはnothingで表されます。これはおそらくC（NULL）やPython（None）の動作に最も近いものです。

julia> n = nothing

julia> isnothing(n)
true

julia> typeof(n)
Nothing

つまりnothingは型Nothingの単一の値で、それかどうかをテストできます。

nothingのよくある使い方の1つは、副作用（出力、ネットワーク設定など）のためだけに使われる関数の戻り値（実際には何も返さない値）としてです。

missing

理論上は値が存在するものの、それが何かわからない場合にはmissingを使います。 たとえば、道路を走る車を数えるとき、人間の観測者が休憩を取る必要があったり、自動センサーが故障したりしても、交通の流れは続いています。

このようにmissingはプレースホルダーであり、データの欠けをどう扱うかを人間が決める必要があることを警告します。

julia> mv = [1, 2, missing]
3-element Vector{Union{Missing, Int64}}:
 1
 2
  missing

julia> typeof(mv)
Vector{Union{Missing, Int64}} (alias for Array{Union{Missing, Int64}, 1})

julia> ismissing.(mv)  # broadcast function, displays as 1 for true, 0 for false
3-element BitVector:
 0
 0
 1

この機能を標準で備えている言語はほとんどありませんが、近いものとしてRのNAやSQLのNULLがあります。

missing値が含まれている場合、式は通常デフォルトでmissingを返します。 これらの値を無視したい場合は、skipmissing()関数を使ってその意図を明示します。

julia> mv = [1, 2, missing]
3-element Vector{Union{Missing, Int64}}:
 1
 2
  missing

julia> sum(mv)  # missing in, missing out
missing

julia> skipmissing(mv)
skipmissing(Union{Missing, Int64}[1, 2, missing])

julia> collect(skipmissing(mv))
2-element Vector{Int64}:
 1
 2

julia> sum(skipmissing(mv))  # functions like sum() can work with iterators
3

skipmissingはイテレーターを作るので、ベクトルが必要な場合はcollect()で包みます。

missing値を何らかのデフォルト値で置き換えると便利なこともあります。 @coalesce()マクロがこれに便利で、最初のmissing以外の値（他になければmissing）を返します。

julia> str = ["I", "exist", missing]
3-element Vector{Union{Missing, String}}:
 "I"
 "exist"
 missing

julia> [@coalesce(s, "-") for  s in str]
3-element Vector{String}:
 "I"
 "exist"
 "-"

NaN

「Not a Number」の略であるNaNは、数値が期待される場面で計算上の問題が起きたことを示します。

julia> v = [0, 1, -1]
3-element Vector{Int64}:
  0
  1
 -1

julia> v / 0
3-element Vector{Float64}:
 NaN
  Inf
 -Inf
 
julia> sum(v / 0)
NaN

NaNを含むデータに対するあらゆる計算は、NaNという結果になります。

現在、NaN値を取り除く専用の関数はありませんが、標準のfilter()関数を使えば簡単にできます。 与えられた条件がtrueになる値だけが結果の配列にコピーされます。

julia> filter(!isnan, [1, 2, NaN])
2-element Vector{Float64}:
 1.0
 2.0