Lasagna

Noções básicas

Variáveis

Elixir é uma linguagem de tipagem dinâmica, o que significa que o tipo de uma variável só é verificado em tempo de execução. Usando o operador de correspondência =, podemos vincular um valor de qualquer tipo a um nome de variável:

# Bound an integer value of 1
count = 1
# You may re-bind variables
count = 2

# You may re-bind any type to a variable
count = false

# Strings can be created by enclosing characters within double quotes
message = "Success!"

Módulos

Elixir é uma linguagem de programação funcional e exige que todas as funções nomeadas sejam definidas em um módulo. A palavra-chave defmodule é usada para definir um módulo. Todos os módulos estão disponíveis para todos os outros módulos em tempo de execução e não exigem um modificador de acesso para ficarem visíveis para outras partes do programa. Um módulo é análogo a uma classe em outras linguagens de programação.

defmodule Calculator do
  # ...
end

Funções nomeadas

Funções nomeadas precisam ser definidas em um módulo. A palavra-chave def é usada para definir uma função nomeada pública.

Cada função pode ter zero ou mais argumentos. O valor da última expressão de uma função é sempre retornado implicitamente.

defmodule Calculator do
  def add(x, y) do
    x + y
  end
end

Para invocar uma função, especificamos o nome do módulo e da função e passamos argumentos para cada um dos argumentos da função.

sum = Calculator.add(1, 2)
# => 3

A palavra-chave defp pode ser usada em vez de def para definir uma função privada. Funções privadas só podem ser usadas de dentro do mesmo módulo que as definiu.

Ao invocar uma função dentro do mesmo módulo em que ela foi definida, o nome do módulo pode ser omitido.

Você também pode escrever funções curtas usando uma sintaxe de uma linha (repare na vírgula , e nos dois-pontos : em volta da palavra-chave do).

defmodule Calculator do
  def subtract(x, y) do
    private_subtract(x, y)
  end

  defp private_subtract(x, y), do: x - y
end

difference = Calculator.subtract(7, 2)
# => 5

difference = Calculator.private_subtract(7, 2)
# => ** (UndefinedFunctionError) function Calculator.private_subtract/2 is undefined or private
#       Calculator.private_subtract(7, 2)

Aridade das funções

É comum nos referirmos às funções pela sua aridade. A aridade de uma função é o número de argumentos que ela aceita.

# add/3 because this function has three arguments, thus an arity of 3
def add(x, y, z) do
  x + y + z
end

Convenções de nomenclatura

Nomes de módulos devem usar PascalCase. Um nome de módulo precisa começar com uma letra maiúscula A-Z e pode conter letras a-zA-Z, números 0-9 e sublinhados _.

Nomes de variáveis e funções devem usar snake_case. Um nome de variável ou função precisa começar com uma letra minúscula a-z ou um sublinhado _, pode conter letras a-zA-Z, números 0-9 e sublinhados _, e pode terminar com um ponto de interrogação ? ou um ponto de exclamação !.

Biblioteca padrão

Elixir tem uma biblioteca padrão muito rica e bem documentada. A documentação está disponível online em hexdocs.pm/elixir. Salve este link em algum lugar: você vai usá-lo muito!

A maioria dos tipos de dados embutidos tem um módulo correspondente que oferece funções para trabalhar com aquele tipo de dados, por exemplo: existe o módulo Integer para números inteiros, o módulo String para strings, o módulo List para listas e assim por diante.

Um módulo notável é o módulo Kernel. Ele fornece as capacidades básicas sobre as quais o resto da biblioteca padrão é construído, como operadores aritméticos, macros de fluxo de controle e muito mais. As funções do módulo Kernel são importadas automaticamente, então você pode usá-las sem o prefixo Kernel..

Comentários no código

Os comentários podem ser usados para deixar anotações para outros desenvolvedores que leem o código-fonte. Comentários de uma linha em Elixir são precedidos por #.