Λαζάνια

Τα βασικά

Μεταβλητές

Η Elixir είναι μια γλώσσα με δυναμικούς τύπους, που σημαίνει ότι ο τύπος μιας μεταβλητής ελέγχεται μόνο κατά την εκτέλεση. Χρησιμοποιώντας τον τελεστή αντιστοίχισης =, μπορούμε να δεσμεύσουμε μια τιμή οποιουδήποτε τύπου σε ένα όνομα μεταβλητής:

# Bound an integer value of 1
count = 1
# You may re-bind variables
count = 2

# You may re-bind any type to a variable
count = false

# Strings can be created by enclosing characters within double quotes
message = "Success!"

Αρθρώματα

Η Elixir είναι μια γλώσσα συναρτησιακού προγραμματισμού και απαιτεί όλες οι συναρτήσεις με όνομα να ορίζονται μέσα σε ένα άρθρωμα. Η λέξη-κλειδί defmodule χρησιμοποιείται για να ορίσεις ένα άρθρωμα. Όλα τα αρθρώματα είναι διαθέσιμα σε όλα τα άλλα αρθρώματα κατά την εκτέλεση και δεν χρειάζονται τροποποιητή πρόσβασης για να γίνουν ορατά σε άλλα μέρη του προγράμματος. Ένα άρθρωμα είναι ανάλογο με μια κλάση σε άλλες γλώσσες προγραμματισμού.

defmodule Calculator do
  # ...
end

Συναρτήσεις με όνομα

Οι συναρτήσεις με όνομα πρέπει να ορίζονται μέσα σε ένα άρθρωμα. Η λέξη-κλειδί def χρησιμοποιείται για να ορίσεις μια δημόσια συνάρτηση με όνομα.

Κάθε συνάρτηση μπορεί να έχει μηδέν ή περισσότερα ορίσματα. Η τιμή της τελευταίας έκφρασης σε μια συνάρτηση επιστρέφεται πάντα έμμεσα.

defmodule Calculator do
  def add(x, y) do
    x + y
  end
end

Για να καλέσεις μια συνάρτηση, δίνεις το όνομα του αρθρώματος και της συνάρτησης και περνάς ορίσματα για κάθε όρισμα της συνάρτησης.

sum = Calculator.add(1, 2)
# => 3

Η λέξη-κλειδί defp μπορεί να χρησιμοποιηθεί αντί για def για να ορίσεις μια ιδιωτική συνάρτηση. Οι ιδιωτικές συναρτήσεις μπορούν να χρησιμοποιηθούν μόνο μέσα από το ίδιο άρθρωμα που τις όρισε.

Όταν καλείς μια συνάρτηση μέσα στο ίδιο άρθρωμα όπου έχει οριστεί, μπορείς να παραλείψεις το όνομα του αρθρώματος.

Μπορείς επίσης να γράψεις σύντομες συναρτήσεις με σύνταξη μιας γραμμής (πρόσεξε το κόμμα , και την άνω και κάτω τελεία : γύρω από τη λέξη-κλειδί do).

defmodule Calculator do
  def subtract(x, y) do
    private_subtract(x, y)
  end

  defp private_subtract(x, y), do: x - y
end

difference = Calculator.subtract(7, 2)
# => 5

difference = Calculator.private_subtract(7, 2)
# => ** (UndefinedFunctionError) function Calculator.private_subtract/2 is undefined or private
#       Calculator.private_subtract(7, 2)

Ο αριθμός ορισμάτων των συναρτήσεων

Συνηθίζεται να αναφερόμαστε στις συναρτήσεις με τον αριθμό ορισμάτων τους. Ο αριθμός ορισμάτων μιας συνάρτησης είναι το πλήθος των ορισμάτων που δέχεται.

# add/3 because this function has three arguments, thus an arity of 3
def add(x, y, z) do
  x + y + z
end

Συμβάσεις ονοματοδοσίας

Τα ονόματα των αρθρωμάτων πρέπει να χρησιμοποιούν PascalCase. Το όνομα ενός αρθρώματος πρέπει να ξεκινά με κεφαλαίο γράμμα A-Z και μπορεί να περιέχει γράμματα a-zA-Z, αριθμούς 0-9 και κάτω παύλες _.

Τα ονόματα μεταβλητών και συναρτήσεων πρέπει να χρησιμοποιούν snake_case. Το όνομα μιας μεταβλητής ή συνάρτησης πρέπει να ξεκινά με πεζό γράμμα a-z ή κάτω παύλα _, μπορεί να περιέχει γράμματα a-zA-Z, αριθμούς 0-9 και κάτω παύλες _, και μπορεί να τελειώνει με ερωτηματικό ? ή θαυμαστικό !.

Πρότυπη βιβλιοθήκη

Η Elixir έχει μια πολύ πλούσια και καλά τεκμηριωμένη πρότυπη βιβλιοθήκη. Η τεκμηρίωση είναι διαθέσιμη online στο hexdocs.pm/elixir. Αποθήκευσε αυτόν τον σύνδεσμο κάπου, θα τον χρησιμοποιήσεις πολύ!

Οι περισσότεροι ενσωματωμένοι τύποι δεδομένων έχουν ένα αντίστοιχο άρθρωμα που προσφέρει συναρτήσεις για να δουλεύεις με αυτόν τον τύπο δεδομένων, π.χ. υπάρχει το άρθρωμα Integer για τους ακέραιους, το άρθρωμα String για τις συμβολοσειρές, το άρθρωμα List για τις λίστες και ούτω καθεξής.

Ένα άρθρωμα που ξεχωρίζει είναι το άρθρωμα Kernel. Παρέχει τις βασικές δυνατότητες πάνω στις οποίες χτίζεται η υπόλοιπη πρότυπη βιβλιοθήκη, όπως αριθμητικούς τελεστές, μακροεντολές ελέγχου ροής και πολλά άλλα. Οι συναρτήσεις του αρθρώματος Kernel εισάγονται αυτόματα, οπότε μπορείς να τις χρησιμοποιήσεις χωρίς το πρόθεμα Kernel..

Σχόλια στον κώδικα

Τα σχόλια μπορούν να χρησιμοποιηθούν για να αφήσεις σημειώσεις σε άλλους προγραμματιστές που διαβάζουν τον πηγαίο κώδικα. Τα σχόλια μιας γραμμής στην Elixir ξεκινούν με #.