Lasaña

Fundamentos

Variables

Elixir es un lenguaje de tipado dinámico, lo que significa que el tipo de una variable solo se verifica en tiempo de ejecución. Usando el operador de coincidencia =, podemos vincular un valor de cualquier tipo a un nombre de variable:

# Bound an integer value of 1
count = 1
# You may re-bind variables
count = 2

# You may re-bind any type to a variable
count = false

# Strings can be created by enclosing characters within double quotes
message = "Success!"

Módulos

Elixir es un lenguaje de programación funcional y requiere que todas las funciones con nombre se definan dentro de un módulo. La palabra clave defmodule se usa para definir un módulo. Todos los módulos están disponibles para todos los demás módulos en tiempo de ejecución y no requieren un modificador de acceso para que sean visibles para otras partes del programa. Un módulo es análogo a una clase en otros lenguajes de programación.

defmodule Calculator do
  # ...
end

Funciones con nombre

Las funciones con nombre deben definirse dentro de un módulo. La palabra clave def se usa para definir una función con nombre pública.

Cada función puede tener cero o más argumentos. El valor de la última expresión de una función siempre se devuelve de forma implícita.

defmodule Calculator do
  def add(x, y) do
    x + y
  end
end

Para invocar una función, se especifica el nombre de su módulo y de la función, y se pasan argumentos para cada uno de los argumentos de la función.

sum = Calculator.add(1, 2)
# => 3

La palabra clave defp se puede usar en lugar de def para definir una función privada. Las funciones privadas solo se pueden usar desde dentro del mismo módulo que las definió.

Cuando invocas una función dentro del mismo módulo donde está definida, se puede omitir el nombre del módulo.

También puedes escribir funciones cortas usando una sintaxis de una sola línea (fíjate en la coma , y los dos puntos : alrededor de la palabra clave do).

defmodule Calculator do
  def subtract(x, y) do
    private_subtract(x, y)
  end

  defp private_subtract(x, y), do: x - y
end

difference = Calculator.subtract(7, 2)
# => 5

difference = Calculator.private_subtract(7, 2)
# => ** (UndefinedFunctionError) function Calculator.private_subtract/2 is undefined or private
#       Calculator.private_subtract(7, 2)

Aridad de las funciones

Es común referirse a las funciones por su aridad. La aridad de una función es la cantidad de argumentos que acepta.

# add/3 because this function has three arguments, thus an arity of 3
def add(x, y, z) do
  x + y + z
end

Convenciones de nombres

Los nombres de los módulos deben usar PascalCase. Un nombre de módulo debe empezar con una letra mayúscula A-Z y puede contener letras a-zA-Z, números 0-9 y guiones bajos _.

Los nombres de variables y funciones deben usar snake_case. Un nombre de variable o función debe empezar con una letra minúscula a-z o un guion bajo _, puede contener letras a-zA-Z, números 0-9 y guiones bajos _, y puede terminar con un signo de interrogación ? o un signo de exclamación !.

Biblioteca estándar

Elixir tiene una biblioteca estándar muy completa y bien documentada. La documentación está disponible en línea en hexdocs.pm/elixir. Guarda este enlace en algún lugar: ¡lo usarás mucho!

La mayoría de los tipos de datos integrados tienen un módulo correspondiente que ofrece funciones para trabajar con ese tipo de datos; por ejemplo, existe el módulo Integer para los números enteros, el módulo String para los strings, el módulo List para las listas, y así sucesivamente.

Un módulo que vale la pena mencionar es el módulo Kernel. Proporciona las capacidades básicas sobre las que se construye el resto de la biblioteca estándar, como operadores aritméticos, macros de control de flujo y mucho más. Las funciones del módulo Kernel se importan automáticamente, así que puedes usarlas sin el prefijo Kernel..

Comentarios en el código

Los comentarios se pueden usar para dejar notas a otros desarrolladores que lean el código fuente. Los comentarios de una sola línea en Elixir van precedidos por #.