Ваги

Гетери та сетери - це методи, які дозволяють читати й записувати значення властивості обʼєкта. У Crystal є макроси, завдяки яким легко визначати гетери та сетери для властивості. Макроси - це спосіб генерувати код під час компіляції, про що йтиметься пізніше в концепції макросів.

У Ruby ці методи визначають за допомогою методів attr_reader, attr_writer та attr_accessor, і зовні вони дуже схожі на реалізацію в Crystal. У Crystal їх визначено як макроси getter, setter і property.

Гетери

getter - це макрос, який визначає метод, що повертає значення змінної екземпляра. Це означає, що більше не потрібно писати @ перед змінною екземпляра, коли ми хочемо отримати до неї доступ (у методах, крім initialize); натомість можна викликати метод, який визначив макрос getter.

Макрос getter може приймати кілька змінних екземпляра, розділених комами.

# This:
class Person
  @name : String
  @age : Int32

  def name
    @name
  end

  def age
    @age
  end
end

# Is the same as this:
class Person
  @name : String
  @age : Int32

  getter name, :age
end

Як бачимо, використання getter зменшує обсяг коду, який ми пишемо, і робить його легшим для читання. Крім того, Ruby та Crystal відрізняються тим, що Crystal приймає і назву змінної, і symbol як аргументи для макросу getter. Символи буде розглянуто пізніше в концепції symbol.

Сетери

setter - це макрос, який визначає метод, що встановлює значення змінної екземпляра. Цей макрос трапляється нечасто, і зазвичай замість нього використовують макрос property. Методи, які буде створено, матимуть вигляд name_of_method=; саме = робить так, що властивість можна встановити.

Це визначення методу трохи особливе, бо аргумент, який отримує метод, стоїть після знака =. Кілька інших особливих методів у Crystal використовують цей синтаксис, наприклад метод +.

Як і з макросом getter, коли ми хочемо оновити значення змінної екземпляра після визначення setter, можна викликати метод, який визначив макрос setter.

# This:
class Person
  @name : String
  @age : Int32

  def name=(name : String)
    @name = name
  end

  def age=(age : Int32)
    @age = age
  end
end

# Is the same as this:
class Person
  @name : String
  @age : Int32

  setter name, :age
end

property

property - це макрос, який визначає і гетер, і сетер для змінної екземпляра.

class Person
  @name : String
  @age : Int32

  property name, :age
end