Гра у вгадування

Вирази case

У Gleam вираз case можна використати, щоб умовно виконати код. За допомогою виразу case значення можна перевірити на відповідність одному або кільком зразкам. Приклад такого зразка — літеральний зразок, який зіставляє значення з літеральним значенням (наприклад, 1 або "hello").

Вирази case записують за допомогою ключового слова case:

pub fn describe(number: Int) -> String {
  case number {
    0 -> "Zero"
    1 -> "One"
  }
}

Хоча це може мати вигляд switch-інструкцій в інших мовах, зіставлення зі зразками розкриває свої переваги тоді, коли ми використовуємо й інші зразки. Один із таких зразків — зразок-змінна, який дозволяє присвоїти значення змінній. У цьому прикладі змінна i отримає значення number, якщо воно не дорівнює 0:

pub fn describe(number: Int) -> String {
  case number {
    0 -> "Zero"
    i -> "Non zero"
  }
}

У деяких випадках може знадобитися додати до зразка додаткову умову. Це називається сторожовою умовою (guard clause), яку можна додати за допомогою ключового слова if:

pub fn describe(number: Int) -> String {
  case number {
    0 -> "Zero"
    i if i < 0 -> "Negative number"
  }
}

З міркувань продуктивності у сторожових умовах дозволені лише базові математичні та булеві оператори, а інші функції використовувати в них не можна.

У наведеному вище прикладі не для всіх можливих вхідних даних знайдеться відповідний зразок. Компілятор це виявить і видасть помилку. Це називається перевіркою вичерпності. Щоб позбутися цього попередження, потрібно обробити всі випадки. Для цього можна скористатися зразком-відкиданням, який збігається з будь-яким значенням:

pub fn describe(number: Int) -> String {
  case number {
    0 -> "Zero"
    i if i < 0 -> "Negative number"
    _ -> "Positive number"
  }
}

// No compiler error

В одній гілці можна зіставити кілька зразків, розділяючи їх знаком |. До однієї гілки можна додати лише одну сторожову умову:

pub fn describe(number: Int) -> String {
  let yell = True
  case number {
    0 -> "Zero"
    3 | 5 -> "One of the first odd prime numbers"
    2 | 4 | 6 | 8 if !yell -> "One of the even numbers less than 10"
    i if i % 2 == 0 && yell -> "[Yelling] I'm telling you! It's a even nunber"
    i if i < 0 -> "Negative number"
    _ -> "Positive number"
  }
}
// No compiler error

Вирази case перевіряють значення на відповідність кожному зразку згори донизу, доки не знайдуть відповідний зразок і не виконають логіку, повʼязану з ним. Порядок зразків має значення!