成績統計

Reduce

假設我們想把一個數字陣列加總。要達成這個目標有很多種做法。

• 在許多語言中，這個問題會用一個帶有累加器變數的迴圈來表達。

• 這個問題也可以寫成遞迴函式。用虛擬碼寫的話，可能會像這樣。

  function Add(X, Sum=0):
    if X is empty then
      return Sum
    else
      return Add(rest(X), Sum + first(X))
    end
  end
  

  這種把問題拆成更小片段的方法，也可以描述成「朝基本情況縮減」。

Reduce是一種把資料結構中所有元素合併成單一值的方法。這個過程會疊代資料結構，對每個元素套用函式，以更新累加的結果。

在jq中，這個過程是用reduce篩選器實作的。在其他語言裡，它可能叫做「fold」、「fold-left」、「inject」或「aggregate」。

jq的reduce運算式看起來像這樣。

reduce STREAM_EXPRESSION as $var (INITIAL_VALUE; UPDATE_EXPRESSION)

• STREAM_EXPRESSION是項目的_串流_，每個項目會依序存入$var變數。
  • 回顧一下，要把陣列串流化，請使用疊代器篩選器.[]：$myArray | .[]。
• INITIAL_VALUE是累加結果的起始值（也就是所謂的「累加器」）。
• UPDATE_EXPRESSION會把目前的值（$var）合併進累加器（也就是「fold」）。
  • 在這個運算式中，.是累加器的值。
  • 運算式的輸出會存入累加器，供下一次疊代使用。
  • 最後一次疊代結束後，累加的結果就是reduce的輸出。

來看個例子：把陣列裡的數字加總。add篩選器做的正是這件事，不過我們會來看看怎麼實作它。

如果我們用[10, 20, 30, 40]當作輸入，並以零作為初始狀態，每一步會像這樣。

用jq語法寫起來，就像這段程式碼。

0 + 10 | . + 20 | . + 30 | . + 40

我們可以用reduce篩選器來表達。

[10, 20, 30, 40] | reduce .[] as $n (0; . + $n)     # => 100

def add: reduce .[] as $x (null; . + $x);

幾個要留意的重點

• 在縮減運算式中，.是累加器。如果輸入是你需要在縮減函式內參照的某個物件，就必須把它存進變數。

  {"apple": 10, "banana": 16, "carrot": 4}
  | . as $obj
  | reduce (keys | .[]) as $key (0; . + $obj[$key])     # => 30
  

• 累加器可以是任何資料型態。舉例來說，你可能想反轉一個陣列。

  ["A", "B", "C", "D"]
  | reduce .[] as $elem ([]; [$elem] + .)       # => ["D", "C", "B", "A"]