إحصاءات الدرجات

الاختزال

لنفترض أننا نريد جمع عناصر مصفوفة من الأعداد. وهناك طرق عديدة لتحقيق هذا الهدف.

• في كثير من اللغات، تُصاغ هذه المسألة على هيئة حلقة مع متغير مراكم.

• ويمكن كتابة هذه المسألة على هيئة دالة عودية. وبصيغة الكود الزائف، قد يكون لدينا ما يلي.

  function Add(X, Sum=0):
    if X is empty then
      return Sum
    else
      return Add(rest(X), Sum + first(X))
    end
  end
  

  ويمكن أيضًا وصف هذه الطريقة في تقسيم المسألة إلى أجزاء أصغر بأنها "اختزال نحو الحالة الأساسية".

الاختزال طريقة لدمج جميع عناصر بنية بيانات في قيمة واحدة. تمرّ العملية على بنية البيانات عنصرًا عنصرًا، فتطبّق دالة على كل عنصر لتحديث النتيجة المتراكمة.

في jq، تُنفَّذ هذه العملية عبر مرشّح reduce. وفي لغات أخرى قد تُسمّى "fold" أو "fold-left" أو "inject" أو "aggregate".

يبدو تعبير reduce في jq على النحو التالي.

reduce STREAM_EXPRESSION as $var (INITIAL_VALUE; UPDATE_EXPRESSION)

• STREAM_EXPRESSION هو تدفّق من العناصر، يُخزَّن كل عنصر منه في المتغير $var بالتبادل.
  • تذكّر أنه لتحويل مصفوفة إلى تدفّق، استخدم مرشّح التكرار .[]: $myArray | .[].
• INITIAL_VALUE هو القيمة الابتدائية للنتيجة المتراكمة (وتُعرف بـ"المراكم").
• يدمج UPDATE_EXPRESSION ("يطوي") القيمة الحالية ($var) في المراكم.
  • في سياق هذا التعبير، ترمز . إلى قيمة المراكم.
  • يُخزَّن ناتج التعبير في المراكم لاستخدامه في التكرار التالي.
  • بعد التكرار الأخير، تكون النتيجة المتراكمة هي ناتج reduce.

لنلقِ نظرة على مثال: جمع الأعداد في مصفوفة. مرشّح add يفعل هذا تمامًا، لكننا سنرى كيف ننفّذه.

إذا استخدمنا [10, 20, 30, 40] كمدخل، واتخذنا الصفر حالةً ابتدائية، فهذا ما تبدو عليه كل خطوة.

في صيغة jq، يبدو هذا كما في الكود التالي.

0 + 10 | . + 20 | . + 30 | . + 40

ويمكننا التعبير عن ذلك باستخدام مرشّح reduce.

[10, 20, 30, 40] | reduce .[] as $n (0; . + $n)     # => 100

def add: reduce .[] as $x (null; . + $x);

بعض الأمور التي يجب أخذها في الاعتبار

• في تعبير الاختزال، ترمز . إلى المراكم. وإذا كان المدخل كائنًا تحتاج إلى الرجوع إليه داخل دالة الاختزال، فعليك تخزينه في متغير.

  {"apple": 10, "banana": 16, "carrot": 4}
  | . as $obj
  | reduce (keys | .[]) as $key (0; . + $obj[$key])     # => 30
  

• يمكن أن يكون المراكم من أي نوع من البيانات. فمثلًا، قد ترغب في عكس ترتيب مصفوفة.

  ["A", "B", "C", "D"]
  | reduce .[] as $elem ([]; [$elem] + .)       # => ["D", "C", "B", "A"]