Estatísticas de Notas

Reduce

Suponhamos que queremos somar um array de números. Há muitas formas de atingir este objetivo.

• Em muitas linguagens, este problema é expresso como um ciclo com uma variável acumuladora.

• Este problema pode ser escrito como uma função recursiva. Em pseudocódigo, poderíamos ter isto.

  function Add(X, Sum=0):
    if X is empty then
      return Sum
    else
      return Add(rest(X), Sum + first(X))
    end
  end
  

  Este método de dividir o problema em partes mais pequenas também pode ser descrito como "reduzir em direção ao caso base".

Reduce é uma forma de combinar todos os elementos de uma estrutura de dados num único valor. O processo itera sobre a estrutura de dados, aplicando uma função a cada elemento para atualizar o resultado acumulado.

Em jq, este processo é implementado no filtro reduce. Noutras linguagens, pode chamar-se "fold", "fold-left", "inject" ou "aggregate".

A expressão reduce do jq tem este aspeto.

reduce STREAM_EXPRESSION as $var (INITIAL_VALUE; UPDATE_EXPRESSION)

• STREAM_EXPRESSION é um fluxo de itens, cada um guardado na variável $var por sua vez.
  • Recorda-te: para transformar um array num fluxo, usa o filtro iterador .[]: $myArray | .[].
• INITIAL_VALUE é o valor inicial do resultado acumulado (conhecido como o "acumulador").
• A UPDATE_EXPRESSION combina ("fold") o valor atual ($var) no acumulador.
  • No contexto desta expressão, . é o valor do acumulador.
  • O resultado da expressão é guardado no acumulador para ser usado na iteração seguinte.
  • Após a última iteração, o resultado acumulado é o resultado de reduce.

Vamos ver um exemplo: somar os números de um array. O filtro add faz precisamente isto, mas vamos ver como implementá-lo.

Se usarmos [10, 20, 30, 40] como entrada e tomarmos zero como estado inicial, cada passo tem este aspeto.

Em sintaxe jq, isto tem o aspeto deste código.

0 + 10 | . + 20 | . + 30 | . + 40

Podemos exprimir isso com o filtro reduce.

[10, 20, 30, 40] | reduce .[] as $n (0; . + $n)     # => 100

def add: reduce .[] as $x (null; . + $x);

Algumas coisas a ter em conta

• Na expressão de redução, . é o acumulador. Se a entrada for um objeto que precisas de referenciar dentro da função de redução, tens de o guardar numa variável.

  {"apple": 10, "banana": 16, "carrot": 4}
  | . as $obj
  | reduce (keys | .[]) as $key (0; . + $obj[$key])     # => 30
  

• O acumulador pode ser de qualquer tipo de dados. Por exemplo, podes querer inverter um array.

  ["A", "B", "C", "D"]
  | reduce .[] as $elem ([]; [$elem] + .)       # => ["D", "C", "B", "A"]