تنسيق المجلة

الماكرو

لغة التجميع المكتوبة يدويًا مليئة بالتكرار. تظهر المجموعة القصيرة نفسها من التعليمات مرارًا وتكرارًا، مع اختلاف ضئيل، ولا توجد سوى قليل من التجريدات لتقليل الكود المتكرر. وليس هذا فقط، فالكود بلغة التجميع يتطلب إدارة قيم بلا دلالة واضحة. فلا توجد معاملات مُسمّاة، ويجب على المبرمج أن يتعامل يدويًا مع معظم تفاصيل الآلة الكامنة.

يوفّر NASM، وهو المُجمِّع المستخدم في المسار، بعض الأدوات التي تساعد المبرمج في كلتا المشكلتين. تعمل هذه الأدوات في وقت التجميع، قبل أن تصل أي تعليمة إلى المعالج. وهي ترشد المُجمِّع إلى كيفية إعادة كتابة النص المصدري قبل تحويله حتى إلى الكود الآلي.

وأهم هذه الأدوات هي الماكرو، الذي يمكن التفكير فيه كوصفة للمُجمِّع. يُوسَّع الماكرو في الموضع الذي يُستخدم فيه، وكأن الكود قد كُتب هناك يدويًا.

يمكن للماكرو أن يأخذ عددًا من الرموز الحرفية كمعاملات، ما يجعله قابلًا لإعادة الاستخدام في سياقات مختلفة. لكنه ليس دالة: فلا يوجد call ولا ret ولا نقل للتحكم إلى نقطة أخرى في الكود.

الماكرو أحادي السطر

أبسط تعريف يمنح اسمًا لقيمة أو تعبير قصير باستخدام %define:

%define WIDTH 8
%define BUFFER_SIZE (WIDTH * 16)

كل ظهور لاحق لـ WIDTH يُستبدل بـ 8 قبل التجميع. الاستبدال نصي، لذا يُستبدل الاسم في أي موضع يظهر فيه، سواء في معامل العملية أو داخل تعريف آخر.

يمكن أن يأخذ %define أيضًا معاملات مُسمّاة، فيتصرف كدالة صغيرة مضمّنة:

%define double(x) ((x) + (x))

    mov eax, double(WIDTH)   ; assembled as mov eax, ((8) + (8))

الأسماء المُعرَّفة بـ %define حساسة لحالة الأحرف. البديل %idefine يجعل الاسم غير حساس لحالة الأحرف، إن أُريد ذلك.

الماكرو أحادي السطر مفيد لإعطاء معنى لأجزاء مختلفة من الكود. وإذا استُخدم بعناية، فإنه يحسّن قابلية القراءة ويقلل احتمال الأخطاء المطبعية. على سبيل المثال، يمكن تعريف سجل له غرض مخصص داخل دالة باسم غرضه:

%define COUNTER rcx
    ...
.loop:
    ...
    dec COUNTER
    jnz .loop
    ...

الماكرو متعدد الأسطر

يمكن التقاط تتابع كامل من الكود، بأي عدد من الأسطر، باستخدام %macro، ويُغلق بـ %endmacro. ويشير الرقم بعد الاسم إلى عدد الوسائط التي يأخذها الماكرو، ويمكن أن يكون صفرًا. وعند تمرير الوسائط، تُفصل بفاصلة (,):

%macro example_macro 0
...
%endmacro

الوسائط في الماكرو متعدد الأسطر ليست مُسمّاة. ويُشار إليها بـ %1 و%2 وهكذا، بالترتيب الذي تُمرَّر به:

; Multiplies two values, returning the result in the first argument
%macro mult_two 2        ; %1 = accumulator, %2 = value
    imul %1, %2
%endmacro

    mult_two eax, ecx    ; multiplies eax and ecx and returns the result into eax
    mult_two r8, r9      ; multiplies r8 and r9 and returns the result into r8

لاحظ أن الوسائط يجب أن تكون صياغتها صحيحة بالنسبة إلى العمليات المنفَّذة في جسم الماكرو. هنا يتم تجميع كلٍّ من mult_two eax, ecx وmult_two r8, r9، لكن mult_two eax, cl لن يُجمّع، لأن imul eax, cl غير معرّفة.

التسميات داخل الماكرو

الماكرو الذي يعرّف تسمية عادية يتعطل لحظة استخدامه مرتين، لأن التسمية ستُعرَّف حينها مرتين أيضًا. لاستخدام تسميات داخل ماكرو قد يُستدعى أكثر من مرة، من الضروري أن تسبق هذه التسمية بـ %%. وهذا يوجّه المُجمِّع إلى إعطاء هذه التسمية اسمًا مختلفًا وفريدًا في كل توسيع:

; clobbers rcx
%macro clear_n 2         ; %1 = base address, %2 = count of dwords to clear
    xor ecx, ecx
%%loop:
    mov dword [%1 + rcx*4], 0
    inc ecx
    cmp ecx, %2          ; %2 is compared with ecx: it is an immediate or a 32-bit operand
    jb %%loop
%endmacro

    clear_n rdi, 4       ; gets its own %%loop
    clear_n rsi, 8       ; a different %%loop, no clash

التكرار في وقت التجميع

يمكن تكرار كتلة كود من سطر واحد باستخدام times. وهذا مفيد بشكل خاص عند تعريف قيم متكررة في الذاكرة:

section .data
negative_block: times 16 db -1
; this assembles to 16 db -1 in sequence, i.e., an array of 16 bytes, all equal to -1

لتكرار الكود متعدد الأسطر، يمكننا استخدام %rep بدلًا من ذلك:

%rep 2          ; number of repetitions: 2
    add rcx, 32
    mov dword [rsi + rcx], 0
%endrep

لاحظ أن عدد التكرارات يُحدَّد مباشرة بعد %rep، وهناك %endrep لإغلاق الكتلة المتكررة.

من الشائع استخدام عدّاد في وقت التجميع داخل كتلة %rep، تمامًا كما تستخدم حلقة وقت التشغيل عدّادًا. وبينما يمكن تعريف ثابت صحيح في وقت التجميع بـ equ، فإننا نستخدم %assign للمتغيرات الصحيحة في وقت التجميع. وعلى عكس %define، يُقيَّم %assign فورًا إلى عدد ويمكن إعادة إسناده:

    xor eax, eax
%assign i 0
%rep 4
    add eax, i           ; add 0, then 1, then 2, then 3
%assign i i + 1
%endrep

بعد تشغيل المعالج القبلي، تختفي الحلقة وتبقى أربع تعليمات add، مع تضمين القيم الفورية 0 و1 و2 و3. هذا هو فك الحلقات الذي يقوم به المُجمِّع: لا سجل عدّاد ولا تفريع، مجرد كود خطّي.

التجميع الشرطي

تتوفر للمعالج القبلي شروط متنوعة. وهي تختار بين عدد من المسارات المختلفة، فتوسّع جسمها في موضعه، لكن فقط عندما يتحقق شرطها.

%if ... %elif ... %else ... %endif تختار فرعًا من اختبار رقمي:

%if WIDTH > 4
    mov eax, 2
%elif WIDTH > 2
    mov eax, 1
%else
    mov eax, 0
%endif

التقسيم إلى ملفات

غالبًا يُحتفظ بالماكرو في ملف خاص به، ويُضم إلى كل مصدر يحتاجه باستخدام %include:

%include "patterns.mac"

يُدرج الملف المسمّى حرفيًا في ذلك الموضع، قبل التجميع، تمامًا وكأن محتوياته قد كُتبت في مكانها. وهذا يُبقي التعريفات في موضع واحد ويتيح لعدة ملفات مصدرية مشاركتها.

إذا كان ملف الماكرو قد يُجمَّع مستقلًا بذاته، فينبغي أن تكون امتداده .asm. لاحظ أن الماكرو ليس له ارتباط. فحتى إذا جُمّع ملف الماكرو، فإن ماكروه لا يكون مرئيًا إلا لملف آخر يضمّه بـ %include.

وإلا، فيمكن لملف مخصص لـ %include فقط أن يحمل أي امتداد. واستخدام .asm أو .mac عُرف شائع.