マクロ
手書きのアセンブリは繰り返しだらけです。
同じ短い命令の並びが、ほとんど変えることなく何度も何度も現れます。定型コードを減らしてくれる抽象化もほとんどありません。
それだけでなく、アセンブリでコードを書くときは、意味が自明でない値を管理する必要があります。
名前の付いた引数はなく、土台となる仕組みの細かい部分のほとんどは、プログラマーが手作業で扱わなければなりません。
このトラックで使われているアセンブラーであるNASMには、どちらの問題にも役立ついくつかのツールがあります。
これらのツールは、命令がプロセッサーに届く前の_アセンブル時_に動作します。
そして、ソーステキストが機械語に翻訳される前に、アセンブラーがどのようにソースを書き換えるべきかを指示します。
こうしたツールの中で最も重要なのがマクロです。マクロは、アセンブラーにとってのレシピのようなものだと考えられます。
マクロは使われた場所で展開され、あたかもそこに手でコードを書いたかのようになります。
マクロはいくつかのリテラルトークンを引数として受け取ることができ、さまざまな場面で再利用できます。
ただし、マクロは関数ではありません。callもretもなく、コードの別の地点へ制御を移すこともありません。
1行マクロ
最も単純な定義は、%defineで値や短い式に名前を付けるものです。
%define WIDTH 8
%define BUFFER_SIZE (WIDTH * 16)
以降に現れるWIDTHはすべて、アセンブル前に8へ置き換えられます。
置き換えはテキストとして行われるため、名前はオペランドの中でも、別の定義の中でも、現れる場所すべてで置き換えられます。
数値の_定数_には、%defineよりもequを優先しましょう。
%defineで宣言した1行マクロは、使われたときにだけ展開され、再定義したり未定義にしたりできます。
一方、equの定数は定義した時点で評価され、あとから変更されることはありません。
%defineは_名前付き_の引数を取ることもでき、小さなインライン関数のようにふるまいます。
%define double(x) ((x) + (x))
mov eax, double(WIDTH) ; assembled as mov eax, ((8) + (8))
本体全体と各引数の両方を、括弧（()）で囲みます。
%define square(x) x*xだと、square(1+1)という呼び出しは1+1*1+1、つまり3に展開されます。
%define square(x) ((x)*(x))と書けば、同じ呼び出しは((1+1)*(1+1))、つまり4に展開されます。
%defineで定義した名前は大文字と小文字を区別します。
大文字と小文字を区別しない名前にしたい場合は、%idefineという書き方もあります。
1行マクロは、コードのさまざまな部分に意味を与えるのに役立ちます。
注意して使えば、読みやすさが上がり、タイプミスの可能性も減ります。
たとえば、関数の中で専用の役割を持つレジスターは、その役割で定義できます。
%define COUNTER rcx
...
.loop:
...
dec COUNTER
jnz .loop
...
複数行マクロ
何行にもわたるコードの並びをまるごと取り込むには%macroを使い、%endmacroで閉じます。
名前のあとの数値は、そのマクロが受け取る引数の数を表します。0個でもかまいません。
引数を渡すときは、カンマ（,）で区切ります。
%macro example_macro 0
...
%endmacro
複数行マクロの引数には名前がありません。
渡された順に%1、%2、…として参照します。
; Multiplies two values, returning the result in the first argument
%macro mult_two 2 ; %1 = accumulator, %2 = value
imul %1, %2
%endmacro
mult_two eax, ecx ; multiplies eax and ecx and returns the result into eax
mult_two r8, r9 ; multiplies r8 and r9 and returns the result into r8
引数は、マクロ本体で行う操作にとって有効な構文でなければならない点に注意してください。
ここではmult_two eax, ecxもmult_two r8, r9もアセンブルできますが、mult_two eax, clはできません。imul eax, clが定義されていないからです。
マクロの中のラベル
普通のラベルを定義するマクロは、2回使った時点で壊れてしまいます。同じラベルが2回定義されることになるからです。
何度も呼ばれる可能性のあるマクロの中でラベルを使うには、そのラベルに%%を付けます。
こうすると、アセンブラーは展開のたびにそのラベルへ異なる一意な名前を付けます。
; clobbers rcx
%macro clear_n 2 ; %1 = base address, %2 = count of dwords to clear
xor ecx, ecx
%%loop:
mov dword [%1 + rcx*4], 0
inc ecx
cmp ecx, %2 ; %2 is compared with ecx: it is an immediate or a 32-bit operand
jb %%loop
%endmacro
clear_n rdi, 4 ; gets its own %%loop
clear_n rsi, 8 ; a different %%loop, no clash
アセンブル時の繰り返し
timesを使うと、1行のコードを繰り返せます。
メモリーに同じ値を繰り返し宣言するときに特に役立ちます。
section .data
negative_block: times 16 db -1
; this assembles to 16 db -1 in sequence, i.e., an array of 16 bytes, all equal to -1
複数行のコードを繰り返すときは、代わりに%repを使います。
%rep 2 ; number of repetitions: 2
add rcx, 32
mov dword [rsi + rcx], 0
%endrep
繰り返しの回数は%repのすぐあとに指定し、繰り返すブロックは%endrepで閉じます。
実行時のループがカウンターを使うのと同じように、%repブロックの中ではアセンブル時のカウンターを使うのが一般的です。
アセンブル時の整数定数はequで宣言できますが、アセンブル時の整数_変数_には代わりに%assignを使います。
%defineと違って、%assignはすぐに数値として評価され、再代入もできます。
xor eax, eax
%assign i 0
%rep 4
add eax, i ; add 0, then 1, then 2, then 3
%assign i i + 1
%endrep
プリプロセッサーが動いたあと、ループは消え、4つのadd命令だけが残ります。即値0、1、2、3が埋め込まれています。
これはアセンブラーによるループ展開です。カウンターレジスターも分岐もなく、ただ一直線のコードが残ります。
条件付きアセンブル
プリプロセッサーでは、いくつかの条件付き構文が使えます。
これらは複数の異なる経路から1つを選び、条件が真のときにだけ本体をその場で展開します。
%if ... %elif ... %else ... %endifは、数値の判定によって分岐を選びます。
%if WIDTH > 4
mov eax, 2
%elif WIDTH > 2
mov eax, 1
%else
mov eax, 0
%endif
ファイルに分割する
マクロはよく専用のファイルにまとめておき、必要なソースそれぞれに%includeで取り込みます。
%include "patterns.mac"
指定したファイルは、アセンブルの前にその場所へそのまま挿入されます。中身をそこに直接書いたかのように展開されます。
こうすると定義を1か所にまとめられ、複数のソースファイルで共有できます。
マクロファイルを単体でアセンブルする可能性があるなら、拡張子は.asmにします。
マクロにはリンケージがない点に注意してください。
マクロファイルをアセンブルしても、そのマクロは%includeした別のファイルからしか見えません。
そうでなければ、%include専用のファイルはどんな拡張子でもかまいません。
.asmと.macのどちらを使うのもよくある慣習です。
学習演習
