Cómo probar en el track de Vim script

Este track usa dos herramientas para ejecutar el conjunto de pruebas y garantizar las buenas prácticas:

1. vader.vim
2. vint

Ejecutar las pruebas

1. Instala vader.vim.
2. Abre tu solución:

   $ vim exercise.vim
   

3. Carga el archivo actual para que sus funciones globales estén disponibles en Vim:

   :source %
   

4. Ejecuta las pruebas:

   :Vader exercise.vader
   

Las rutas pueden variar.

Si quieres un atajo cómodo para los pasos anteriores, agrega esto a tu vimrc:

function! s:exercism_tests()
  if expand('%:e') == 'vim'
    let testfile = printf('%s/%s.vader', expand('%:p:h'),
          \ tr(expand('%:p:h:t'), '-', '_'))
    if !filereadable(testfile)
      echoerr 'File does not exist: '. testfile
      return
    endif
    source %
    execute 'Vader' testfile
  else
    let sourcefile = printf('%s/%s.vim', expand('%:p:h'),
          \ tr(expand('%:p:h:t'), '-', '_'))
    if !filereadable(sourcefile)
      echoerr 'File does not exist: '. sourcefile
      return
    endif
    execute 'source' sourcefile
    Vader
  endif
endfunction

autocmd BufRead *.{vader,vim}
      \ command! -buffer Test call s:exercism_tests()

Después, abre cualquier archivo .vim o .vader desde el directorio de un ejercicio y ejecuta el comando :Test.

Análisis estático de archivos de Vim

1. Instala vint.
2. Analiza de forma recursiva todos los archivos de Vim:

   $ vint .
   

Para obtener información más detallada sobre el track de Vim script, consulta la página de ayuda.