Reduce en

Acerca de Reduce

Supongamos que queremos sumar un array de números. Hay muchas formas de lograr este objetivo.

• En muchos lenguajes, este problema se expresa como un bucle con una variable acumuladora.

• Este problema se puede escribir como una función recursiva. En pseudocódigo, podríamos tener esto.

  function Add(X, Sum=0):
    if X is empty then
      return Sum
    else
      return Add(rest(X), Sum + first(X))
    end
  end
  

  Este método de dividir el problema en partes más pequeñas también se puede describir como «reducción hacia el caso base».

Reduce es una forma de combinar todos los elementos de una estructura de datos en un único valor. El proceso itera sobre la estructura de datos, aplicando una función a cada elemento para actualizar el resultado acumulado.

En jq, este proceso se implementa en el filtro reduce. En otros lenguajes, puede llamarse «fold», «fold-left», «inject» o «aggregate».

La expresión reduce de jq se ve así.

reduce STREAM_EXPRESSION as $var (INITIAL_VALUE; UPDATE_EXPRESSION)

• STREAM_EXPRESSION es un flujo de elementos, cada uno almacenado en la variable $var por turno.
  • Recuerda: para recorrer un array, usa el filtro iterador .[]: $myArray | .[].
• INITIAL_VALUE es el valor inicial del resultado acumulado (conocido como el «acumulador»).
• La UPDATE_EXPRESSION combina (o «pliega») el valor actual ($var) dentro del acumulador.
  • En el contexto de esta expresión, . es el valor del acumulador.
  • La salida de la expresión se almacena en el acumulador para usarla en la siguiente iteración.
  • Después de la última iteración, el resultado acumulado es la salida de reduce.

Veamos un ejemplo: sumar los números de un array. El filtro add hace justamente esto, pero veremos cómo implementarlo.

Si usamos [10, 20, 30, 40] como argumento y tomamos cero como estado inicial, así se ve cada paso.

En la sintaxis de jq, eso se ve así.

0 + 10 | . + 20 | . + 30 | . + 40

Podemos expresar eso con el filtro reduce.

[10, 20, 30, 40] | reduce .[] as $n (0; . + $n)     # => 100

def add: reduce .[] as $x (null; . + $x);

Algunas cosas para tener en cuenta

• En la expresión de reducción, . es el acumulador. Si el argumento es algún objeto que necesitas referenciar dentro de la función de reducción, debes guardarlo en una variable.

  {"apple": 10, "banana": 16, "carrot": 4}
  | . as $obj
  | reduce (keys | .[]) as $key (0; . + $obj[$key])     # => 30
  

• El acumulador puede ser de cualquier tipo de dato. Por ejemplo, quizás quieras invertir un array.

  ["A", "B", "C", "D"]
  | reduce .[] as $elem ([]; [$elem] + .)       # => ["D", "C", "B", "A"]