MapSets
MapSet एक ऐसा संग्रह है जिसमें हर वैल्यू सिर्फ एक बार रखी जाती है, और जो Elixir में सेट को दर्शाता है। इसमें किसी भी तरह की वैल्यू रखी जा सकती है, और इनका कोई क्रम नहीं होता।
ध्यान दीजिए कि Set मॉड्यूल भी मौजूद है, लेकिन अब वह पुराना पड़ चुका है और उसकी जगह MapSet इस्तेमाल करने की सलाह दी जाती है।
आप MapSet.new/0, MapSet.new/1 और MapSet.new/2 की मदद से सेट बना सकते हैं, और MapSet.to_list/1 से उन्हें ऐरे में बदल सकते हैं।
MapSet.new()
# => MapSet.new([])
MapSet.new([2, 3, 3, 3, 1, 1, 2, "hello"])
# => MapSet.new([1, 2, 3, "hello"])
MapSet.new([2, 3, 3, 3, 1, 1, 2], fn n -> 10 * n end)
# => MapSet.new([10, 20, 30])
[2, 3, 3, 3, 1, 1, 2] |> MapSet.new() |> MapSet.to_list()
# => [1, 2, 3]
ध्यान दीजिए कि MapSet में कोई क्रम नहीं होता, इसलिए इसकी कोई गारंटी नहीं है कि MapSet.to_list/1 हमेशा क्रम में लगे एलिमेंट ही लौटाएगा।
आप MapSet.put/2 और MapSet.delete/2 की मदद से एलिमेंट जोड़ या हटा सकते हैं।
आप MapSet.size/1 और MapSet.member?/2 फंक्शन से किसी सेट के बारे में जानकारी ले सकते हैं, और MapSet.equal?/2, MapSet.subset?/2 तथा MapSet.disjoint?/2 से सेटों की तुलना कर सकते हैं।
a = MapSet.new([1, 10])
b = MapSet.new([1, 2, 3, 4, 5, 6, 7, 8, 9, 10])
MapSet.size(b)
# => 10
MapSet.member?(a, 10)
# => true
MapSet.subset?(a, b)
# => true
MapSet.disjoint?(a, b)
# => false
MapSet को MapSet.union/2, MapSet.intersection/2, MapSet.difference/2 और MapSet.symmetric_difference/2 की मदद से आपस में मिलाया जा सकता है।
a = MapSet.new([1, 10, 100])
b = MapSet.new([1, 2, 3, 4, 5, 6, 7, 8, 9, 10])
MapSet.union(a, b)
# => MapSet.new([1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 100])
MapSet.intersection(a, b)
# => MapSet.new([1, 10])
MapSet.difference(a, b)
# => MapSet.new([100])
MapSet.difference(b, a)
# => MapSet.new([2, 3, 4, 5, 6, 7, 8, 9])
MapSet.symmetric_difference(b, a)
# => MapSet.new([2, 3, 4, 5, 6, 7, 8, 9, 100])
आप MapSet.filter/2, MapSet.reject/2 और MapSet.split_with/2 की मदद से सेट को फिल्टर कर सकते हैं और दो हिस्सों में बाँट सकते हैं।
a = MapSet.new([1, 2, 3, 4, 5, 6, 7, 8, 9, 10])
even = fn n -> rem(n, 2) == 0 end
MapSet.filter(a, even)
# => MapSet.new([2, 4, 6, 8, 10])
MapSet.reject(a, even)
# => MapSet.new([1, 3, 5, 7, 9])
MapSet.split_with(a, even)
# => {MapSet.new([2, 4, 6, 8, 10]), MapSet.new([1, 3, 5, 7, 9])}
सीखने का अभ्यास
