보물 공장

팬텀 타입

Elm의 타입은 제네릭 타입을 허용하는데, 이는 보통 인터페이스에 유연성을 더해 줘요. 예를 들어 Maybe a 타입은 어떤 타입의 값이든 담을 수 있어요.

type Maybe a = Nothing | Just a

위 예시에서 타입 매개변수 a는 등호 =의 양쪽에서 모두 사용됐어요. 이때 a는 타입 정의 안의 어떤 데이터에 묶여 있다고 말해요.

팬텀 타입 기법

그런데 어떤 경우에는 타입 매개변수가 등식의 왼쪽에만 나타나요.

type Distance unit = Distance Float

위 Distance 정의에서 unit은 자유 타입 매개변수로, 타입 안의 어떤 데이터에도 묶여 있지 않아요. 이런 타입을 팬텀 타입이라고도 불러요.

팬텀 타입은 컴파일 타임에 제약을 강제하고 싶을 때 놀랄 만큼 유용해요. 예를 들어 같은 단위의 거리끼리만 더하도록 보장하고 싶다고 해봐요.

-- Distance is an opaque type, since the module does not expose its variants.
-- This means that users may only use the functions meter, foot and add to manipulate distances.
module Distance exposing (Distance, Meter, Foot, meter, foot, add)

-- The Distance type has a phantom type 'unit'.
type Distance unit = Distance Float

-- We define two types that will be used in place
-- of the phantom type 'unit' in our constructor functions.
type Meter = Meter
type Foot = Foot

-- Constructor for Meter
meter : Distance Meter
meter = Distance 1.0

-- Constructor for Foot
foot : Distance Foot
foot = Distance 0.3048

-- The add function cannot take two parameters of different types.
-- So we cannot add meters and feet by mistake.
add : Distance unit -> Distance unit -> Distance unit
add (Distance d1) (Distance d2) = Distance (d1 + d2)

그 모듈 바깥의 코드는 Distance 타입의 내부에 접근할 수 없어요. 사용자는 두 개의 Distance Meter는 더할 수 있지만, Distance Meter와 Distance Foot은 더할 수 없어요.

import Distance exposing (Distance)

-- Compiles
twoMeters = Distance.add Distance.meter Distance.meter

-- Does not compile
errDist = Distance.add Distance.meter Distance.foot

팬텀 타입으로서의 확장 가능한 레코드

어떤 타입이 팬텀 타입이 될 수 있는지에 제한은 없고, 레코드 타입도 사용할 수 있어요. 레코드를 팬텀 타입으로 사용하면 함수를 거치면서 변환되는 복잡한 제약을 표현할 수 있어요.

이제 Distance 모듈 안에 LegoBlock이라는 새로운 거리 단위를 추가해 봐요. 실제 블록은 규격이 정해진 물건이라 언제나 두 가지 속성을 가져요. 바로 거리가 분수가 아니고 음수가 아니라는 점이에요.

type LegoBlock = LegoBlock

fourStuds : Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
fourStuds = Distance 4.0

nonFractional과 nonNegative는 타입 인자 밖에서는 존재하지 않는 레코드의 필드예요. 그래서 이 필드들에는 () 타입을 주는 게 어울리는데, 이 타입을 __유닛 타입__이라고 하고, 존재한다는 사실 외에는 아무 정보도 담지 않아요.

물론 임의의 LegoBlock 거리를 얻는 것도 가능해요. 예를 들어 거리의 차이나 비율을 계산한 뒤에는 그렇죠.

negativeStud : Distance { properties | unit: LegoBlock, nonFractional : () }
negativeStud = Distance -1.0

threeFiddyStud : Distance { properties | unit: LegoBlock, nonNegative : () }
threeFiddyStud = Distance 3.50

crazyStud : Distance { properties | unit: LegoBlock }
crazyStud = Distance -13.37

위의 모든 값은 유효하고 컴파일도 되지만, nonFractional과 nonNegative 속성을 모두 가진 fourStuds 같은 값에 특히 관심이 있어요. 이런 값은 서로 결합할 수 있는 실제 블록을 나타내기 때문이에요.

combineLegoBlocks
  :  Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
  -> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
  -> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
combineLegoBlocks = add

이제 사용자가 LegoBlock 거리를 만들고 다듬을 수 있도록 몇 가지 함수를 추가해 봐요.

newLegoBlock : Float -> Distance { properties | unit: LegoBlock }
newLegoBlock dist = Distance dist

floorDistance : Distance properties -> Distance { properties | nonFractional : () }
floorDistance (Distance dist) = Distance (toFloat (floor dist))

ceilingDistance : Distance properties -> Distance { properties | nonFractional : () }
ceilingDistance (Distance dist) = Distance (toFloat (ceiling dist))

absDistance : Distance properties -> Distance { properties | nonNegative : () }
absDistance (Distance dist) = Distance (abs dist)

floorDistance, ceilingDistance, absDistance는 LegoBlock이 아닌 단위도 다룰 수 있어요. 그리고 일반적으로 입력 속성에 대해 아무 가정도 하지 않고, 출력이 nonFractional이나 nonNegative 중 특정 속성을 가지도록 보장할 뿐이에요.

몇 가지 결과를 살펴봐요.

import Distance exposing (Distance)

-- Compiles
distance1 = combineLegoBlocks fourStuds fourStuds

-- Does not compile
distance2 = combineLegoBlocks fourStuds threeFiddyStud

-- Compiles
distance3 = combineLegoBlocks fourStuds (floorDistance threeFiddyStud)

-- Does not compile
distance4 = combineLegoBlocks fourStuds negativeStud

-- Compiles
distance5 = combineLegoBlocks fourStuds (absDistance negativeStud)

-- Does not compile
distance6 = combineLegoBlocks fourStuds crazyStud

-- Compiles
distance7 = combineLegoBlocks fourStuds (floorDistance (absDistance crazyStud))

-- Compiles
distance8 = combineLegoBlocks fourStuds (ceilingDistance (absDistance crazyStud))

일반적으로 floorDistance와 ceilingDistance는 서로 다른 결과를 내지만 보장은 같아요. 이것이 팬텀 타입 기법의 강점이에요. 사용자에게 유연한 선택지를 주면서도 강력한 보장을 유지할 수 있거든요.