مصنع الكنوز

الأنواع الشبحية

تسمح أنواع Elm بالأنواع العامة، التي تضيف عمومًا مرونة إلى الواجهة. على سبيل المثال، يمكن للنوع Maybe a أن يحمل قيمة من أي نوع.

type Maybe a = Nothing | Just a

لاحظ في المثال أعلاه أن معامل النوع a مستخدم على طرفي علامة المساواة =. نقول إن a مرتبط ببعض البيانات داخل تعريف النوع.

تقنية النوع الشبح

في بعض الحالات، مع ذلك، لا يظهر معامل النوع إلا على الجانب الأيسر من المعادلة.

type Distance unit = Distance Float

في تعريف Distance أعلاه، unit معامل نوع حر، غير مرتبط بأي بيانات في النوع. يمكننا أيضًا أن نسمي هذا النوع نوعًا شبحًا.

إنه مفيد بشكل مفاجئ عندما نريد فرض قيود في وقت التصريف. على سبيل المثال، نريد التأكد من أننا نجمع فقط مسافات من الوحدة نفسها.

-- Distance is an opaque type, since the module does not expose its variants.
-- This means that users may only use the functions meter, foot and add to manipulate distances.
module Distance exposing (Distance, Meter, Foot, meter, foot, add)

-- The Distance type has a phantom type 'unit'.
type Distance unit = Distance Float

-- We define two types that will be used in place
-- of the phantom type 'unit' in our constructor functions.
type Meter = Meter
type Foot = Foot

-- Constructor for Meter
meter : Distance Meter
meter = Distance 1.0

-- Constructor for Foot
foot : Distance Foot
foot = Distance 0.3048

-- The add function cannot take two parameters of different types.
-- So we cannot add meters and feet by mistake.
add : Distance unit -> Distance unit -> Distance unit
add (Distance d1) (Distance d2) = Distance (d1 + d2)

لا يمكن للكود خارج تلك الوحدة الوصول إلى داخل النوع Distance. يمكن للمستخدمين جمع قيمتين من Distance Meter، لكن لا يمكنهم جمع Distance Meter مع Distance Foot.

import Distance exposing (Distance)

-- Compiles
twoMeters = Distance.add Distance.meter Distance.meter

-- Does not compile
errDist = Distance.add Distance.meter Distance.foot

السجلات القابلة للتوسيع كأنواع شبحية

لا يوجد قيد على الأنواع التي يمكن أن تكون شبحية، ويمكن استخدام أنواع السجلات أيضًا. عند استخدام السجلات كأنواع شبحية، تصبح قادرة على التعبير عن قيود معقدة يمكن أن تتحول عبر الدوال.

لنضف وحدة مسافة جديدة داخل وحدة Distance تسمى LegoBlock. المكعبات الفيزيائية، بما أنها أجسام خاضعة للتنظيم، لها دائمًا خاصيتان: فهي ذات مسافات غير كسرية وغير سالبة.

type LegoBlock = LegoBlock

fourStuds : Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
fourStuds = Distance 4.0

nonFractional وnonNegative حقلان في سجل لا وجود له خارج وسيط نوع، لذا من المناسب إعطاؤهما النوع ()، المسمى نوع الوحدة، والذي لا يحمل أي معلومة تتجاوز كونه موجودًا.

من الممكن بالطبع الحصول على مسافات LegoBlock اعتباطية، على سبيل المثال بعد حساب فروق المسافات أو نسبها.

negativeStud : Distance { properties | unit: LegoBlock, nonFractional : () }
negativeStud = Distance -1.0

threeFiddyStud : Distance { properties | unit: LegoBlock, nonNegative : () }
threeFiddyStud = Distance 3.50

crazyStud : Distance { properties | unit: LegoBlock }
crazyStud = Distance -13.37

كل القيم أعلاه صحيحة وستُصرّف، لكننا نهتم بشكل خاص بقيم مثل fourStuds التي تملك خاصيتي nonFractional وnonNegative معًا، لأنها تمثل مكعبات فيزيائية قابلة للدمج بـ

combineLegoBlocks
  :  Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
  -> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
  -> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
combineLegoBlocks = add

لنضف بعض الدوال التي تتيح للمستخدمين إنشاء مسافات LegoBlock وصقلها.

newLegoBlock : Float -> Distance { properties | unit: LegoBlock }
newLegoBlock dist = Distance dist

floorDistance : Distance properties -> Distance { properties | nonFractional : () }
floorDistance (Distance dist) = Distance (toFloat (floor dist))

ceilingDistance : Distance properties -> Distance { properties | nonFractional : () }
ceilingDistance (Distance dist) = Distance (toFloat (ceiling dist))

absDistance : Distance properties -> Distance { properties | nonNegative : () }
absDistance (Distance dist) = Distance (abs dist)

لاحظ أن floorDistance وceilingDistance وabsDistance يمكنها التعامل مع وحدات غير LegoBlock، وهي عمومًا لا تفترض أي شيء عن خصائص المدخل، وإنما تضمن فقط أن يكون للمخرج خاصية محددة، إما nonFractional وإما nonNegative.

لنلقِ نظرة على بعض النتائج.

import Distance exposing (Distance)

-- Compiles
distance1 = combineLegoBlocks fourStuds fourStuds

-- Does not compile
distance2 = combineLegoBlocks fourStuds threeFiddyStud

-- Compiles
distance3 = combineLegoBlocks fourStuds (floorDistance threeFiddyStud)

-- Does not compile
distance4 = combineLegoBlocks fourStuds negativeStud

-- Compiles
distance5 = combineLegoBlocks fourStuds (absDistance negativeStud)

-- Does not compile
distance6 = combineLegoBlocks fourStuds crazyStud

-- Compiles
distance7 = combineLegoBlocks fourStuds (floorDistance (absDistance crazyStud))

-- Compiles
distance8 = combineLegoBlocks fourStuds (ceilingDistance (absDistance crazyStud))

عمومًا، تعطي floorDistance وceilingDistance نتائج مختلفة، لكن بضمانات متطابقة. هذه هي قوة تقنية النوع الشبح: تقديم خيارات مرنة للمستخدمين مع الحفاظ على ضمانات قوية.