Фантомні типи
У Elm типи можуть бути узагальненими, а це зазвичай додає гнучкості інтерфейсу.
Наприклад, тип Maybe a може містити значення будь-якого типу.
type Maybe a = Nothing | Just a
Звернімо увагу, що в наведеному вище прикладі параметр типу a використовується з обох боків знака рівності =.
Кажемо, що a звʼязаний з якимись даними всередині визначення типу.
Техніка фантомного типу
Однак у деяких випадках параметр типу трапляється лише в лівій частині рівності.
type Distance unit = Distance Float
У наведеному вище визначенні Distance параметр unit вільний і не звʼязаний з жодними даними в типі.
Такий тип ще називають фантомним типом.
Це напрочуд корисно, коли ми хочемо накладати обмеження під час компіляції.
Наприклад, ми хочемо переконатися, що додаємо лише відстані з однаковою одиницею виміру.
-- Distance is an opaque type, since the module does not expose its variants.
-- This means that users may only use the functions meter, foot and add to manipulate distances.
module Distance exposing (Distance, Meter, Foot, meter, foot, add)
-- The Distance type has a phantom type 'unit'.
type Distance unit = Distance Float
-- We define two types that will be used in place
-- of the phantom type 'unit' in our constructor functions.
type Meter = Meter
type Foot = Foot
-- Constructor for Meter
meter : Distance Meter
meter = Distance 1.0
-- Constructor for Foot
foot : Distance Foot
foot = Distance 0.3048
-- The add function cannot take two parameters of different types.
-- So we cannot add meters and feet by mistake.
add : Distance unit -> Distance unit -> Distance unit
add (Distance d1) (Distance d2) = Distance (d1 + d2)
Код поза цим модулем не має доступу до внутрішньої будови типу Distance.
Користувачі можуть додати два значення Distance Meter, але не можуть додати Distance Meter до Distance Foot.
import Distance exposing (Distance)
-- Compiles
twoMeters = Distance.add Distance.meter Distance.meter
-- Does not compile
errDist = Distance.add Distance.meter Distance.foot
Розширювані записи як фантомні типи
Немає жодних обмежень на те, які типи можуть бути фантомними, тож типи-записи теж підходять.
Коли записи використовують як фантомні типи, вони здатні виражати складні обмеження, які можуть перетворюватися за допомогою функцій.
Додамо до модуля Distance нову одиницю відстані під назвою LegoBlock.
Фізичні блоки, як обʼєкти, що підлягають регулюванню, завжди мають дві властивості: їхні відстані недробові та невідʼємні.
type LegoBlock = LegoBlock
fourStuds : Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
fourStuds = Distance 4.0
Поля nonFractional і nonNegative належать запису, який не існує поза аргументом типу, тож доречно надати їм тип (), який називають одиничним типом і який не несе жодної інформації, крім самого факту своєї наявності.
Отримати довільні відстані LegoBlock, звісно, можна, наприклад після обчислення різниць або відношень відстаней.
negativeStud : Distance { properties | unit: LegoBlock, nonFractional : () }
negativeStud = Distance -1.0
threeFiddyStud : Distance { properties | unit: LegoBlock, nonNegative : () }
threeFiddyStud = Distance 3.50
crazyStud : Distance { properties | unit: LegoBlock }
crazyStud = Distance -13.37
Усі наведені вище значення коректні й скомпілюються, проте нас особливо цікавлять такі значення, як fourStuds, що мають обидві властивості, nonFractional і nonNegative, бо вони представляють фізичні блоки, які можна поєднувати за допомогою
combineLegoBlocks
: Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
-> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
-> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
combineLegoBlocks = add
Додамо кілька функцій, які дадуть користувачам змогу створювати й уточнювати відстані LegoBlock.
newLegoBlock : Float -> Distance { properties | unit: LegoBlock }
newLegoBlock dist = Distance dist
floorDistance : Distance properties -> Distance { properties | nonFractional : () }
floorDistance (Distance dist) = Distance (toFloat (floor dist))
ceilingDistance : Distance properties -> Distance { properties | nonFractional : () }
ceilingDistance (Distance dist) = Distance (toFloat (ceiling dist))
absDistance : Distance properties -> Distance { properties | nonNegative : () }
absDistance (Distance dist) = Distance (abs dist)
Звернімо увагу, що floorDistance, ceilingDistance і absDistance можуть працювати з одиницями, відмінними від LegoBlock, і загалом не роблять жодних припущень щодо вхідних властивостей: вони лише гарантують, що вихідні дані матимуть певну властивість, або nonFractional, або nonNegative.
Погляньмо на деякі результати.
import Distance exposing (Distance)
-- Compiles
distance1 = combineLegoBlocks fourStuds fourStuds
-- Does not compile
distance2 = combineLegoBlocks fourStuds threeFiddyStud
-- Compiles
distance3 = combineLegoBlocks fourStuds (floorDistance threeFiddyStud)
-- Does not compile
distance4 = combineLegoBlocks fourStuds negativeStud
-- Compiles
distance5 = combineLegoBlocks fourStuds (absDistance negativeStud)
-- Does not compile
distance6 = combineLegoBlocks fourStuds crazyStud
-- Compiles
distance7 = combineLegoBlocks fourStuds (floorDistance (absDistance crazyStud))
-- Compiles
distance8 = combineLegoBlocks fourStuds (ceilingDistance (absDistance crazyStud))
Загалом floorDistance і ceilingDistance дають різні результати, але однакові гарантії.
У цьому й полягає сила техніки фантомного типу: надавати користувачам гнучкий вибір, зберігаючи сильні гарантії.
Навчальна вправа
