کارخانه‌ی گنج

نوع فانتوم

نوع‌های Elm امکان استفاده از نوع‌های پارامتری را می‌دهند که به‌طور کلی انعطاف‌پذیری را به یک رابط اضافه می‌کنند. برای مثال، نوع Maybe a می‌تواند مقداری از هر نوعی را نگه دارد.

type Maybe a = Nothing | Just a

توجه کنید که در مثال بالا، پارامتر نوع a در دو طرف علامت تساوی = استفاده شده است. می‌گوییم که a به داده‌ای درون تعریف نوع مقید شده است.

تکنیک نوع فانتوم

با این حال، در موارد خاصی، پارامتر نوع فقط در سمت چپ معادله ظاهر می‌شود.

type Distance unit = Distance Float

در تعریف Distance در بالا، unit یک پارامتر نوع آزاد است و به هیچ داده‌ای در نوع مقید نشده است. همچنین می‌توانیم این نوع را «نوع فانتوم» بنامیم.

زمانی که می‌خواهیم محدودیت‌ها را در زمان کامپایل اعمال کنیم، به‌طور شگفت‌آوری مفید است. برای مثال، می‌خواهیم مطمئن شویم که فقط فاصله‌هایی با یکای یکسان را جمع می‌کنیم.

-- Distance is an opaque type, since the module does not expose its variants.
-- This means that users may only use the functions meter, foot and add to manipulate distances.
module Distance exposing (Distance, Meter, Foot, meter, foot, add)

-- The Distance type has a phantom type 'unit'.
type Distance unit = Distance Float

-- We define two types that will be used in place
-- of the phantom type 'unit' in our constructor functions.
type Meter = Meter
type Foot = Foot

-- Constructor for Meter
meter : Distance Meter
meter = Distance 1.0

-- Constructor for Foot
foot : Distance Foot
foot = Distance 0.3048

-- The add function cannot take two parameters of different types.
-- So we cannot add meters and feet by mistake.
add : Distance unit -> Distance unit -> Distance unit
add (Distance d1) (Distance d2) = Distance (d1 + d2)

کدی خارج از آن ماژول نمی‌تواند به درون نوع Distance دسترسی داشته باشد. کاربران می‌توانند دو Distance Meter را جمع کنند، اما نمی‌توانند یک Distance Meter را با یک Distance Foot جمع کنند.

import Distance exposing (Distance)

-- Compiles
twoMeters = Distance.add Distance.meter Distance.meter

-- Does not compile
errDist = Distance.add Distance.meter Distance.foot

رکوردهای قابل گسترش به‌عنوان نوع فانتوم

هیچ محدودیتی وجود ندارد بر اینکه کدام نوع‌ها می‌توانند فانتوم باشند، و نوع‌های رکورد نیز می‌توانند استفاده شوند. وقتی به‌عنوان نوع فانتوم استفاده می‌شوند، رکوردها می‌توانند محدودیت‌های پیچیده‌ای را بیان کنند که می‌توانند از طریق توابع تغییر کنند.

بیایید یک یکای فاصله‌ی جدید درون ماژول Distance به نام LegoBlock اضافه کنیم. بلوک‌های فیزیکی، چون اشیای تنظیم‌شده هستند، همیشه دو ویژگی دارند: فاصله‌های غیرکسری و غیرمنفی دارند.

type LegoBlock = LegoBlock

fourStuds : Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
fourStuds = Distance 4.0

nonFractional و nonNegative فیلدهای رکوردی هستند که خارج از یک آرگومان نوع وجود ندارد، پس مناسب است که به آن‌ها نوع () را بدهیم که «نوع واحد» نامیده می‌شود و هیچ اطلاعاتی فراتر از این واقعیت که آنجاست، نگه نمی‌دارد.

به‌دست آوردن فاصله‌های LegoBlock دلخواه البته ممکن است، مثلاً پس از محاسبه‌ی تفاضل‌ها یا نسبت‌های فاصله.

negativeStud : Distance { properties | unit: LegoBlock, nonFractional : () }
negativeStud = Distance -1.0

threeFiddyStud : Distance { properties | unit: LegoBlock, nonNegative : () }
threeFiddyStud = Distance 3.50

crazyStud : Distance { properties | unit: LegoBlock }
crazyStud = Distance -13.37

همه‌ی مقادیر بالا معتبرند و کامپایل می‌شوند، اما ما علاقه‌ی ویژه‌ای به مقادیری مانند fourStuds داریم که هم ویژگی nonFractional و هم nonNegative را دارند، چون بلوک‌های فیزیکی‌ای را نمایندگی می‌کنند که می‌توان آن‌ها را با تابع زیر ترکیب کرد:

combineLegoBlocks
  :  Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
  -> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
  -> Distance { properties | unit: LegoBlock, nonFractional : (), nonNegative: () }
combineLegoBlocks = add

بیایید چند تابع اضافه کنیم تا کاربران بتوانند فاصله‌های LegoBlock را ایجاد و پالایش کنند.

newLegoBlock : Float -> Distance { properties | unit: LegoBlock }
newLegoBlock dist = Distance dist

floorDistance : Distance properties -> Distance { properties | nonFractional : () }
floorDistance (Distance dist) = Distance (toFloat (floor dist))

ceilingDistance : Distance properties -> Distance { properties | nonFractional : () }
ceilingDistance (Distance dist) = Distance (toFloat (ceiling dist))

absDistance : Distance properties -> Distance { properties | nonNegative : () }
absDistance (Distance dist) = Distance (abs dist)

توجه کنید که floorDistance، ceilingDistance و absDistance می‌توانند یکایی غیر از LegoBlock را هم مدیریت کنند، و به‌طور کلی هیچ فرضی درباره‌ی ویژگی‌های ورودی نمی‌سازند، فقط تضمین می‌کنند که خروجی ویژگی مشخصی خواهد داشت، یا nonFractional یا nonNegative.

بیایید به چند نتیجه نگاه کنیم.

import Distance exposing (Distance)

-- Compiles
distance1 = combineLegoBlocks fourStuds fourStuds

-- Does not compile
distance2 = combineLegoBlocks fourStuds threeFiddyStud

-- Compiles
distance3 = combineLegoBlocks fourStuds (floorDistance threeFiddyStud)

-- Does not compile
distance4 = combineLegoBlocks fourStuds negativeStud

-- Compiles
distance5 = combineLegoBlocks fourStuds (absDistance negativeStud)

-- Does not compile
distance6 = combineLegoBlocks fourStuds crazyStud

-- Compiles
distance7 = combineLegoBlocks fourStuds (floorDistance (absDistance crazyStud))

-- Compiles
distance8 = combineLegoBlocks fourStuds (ceilingDistance (absDistance crazyStud))

به‌طور کلی، floorDistance و ceilingDistance نتایج متفاوتی ارائه می‌دهند، اما تضمین‌های یکسانی دارند. این قدرت تکنیک نوع فانتوم است: ارائه‌ی گزینه‌های منعطف به کاربران در حالی که تضمین‌های قوی حفظ می‌شوند.