密码锁

Crystal 允许变量由多种类型组成。这称为联合类型。在 Crystal 中，联合类型通常由编译器推断得出。

声明联合类型时，用竖线（|）分隔各个类型。它们通常放在圆括号里，但不是必须的。最常见的联合类型是(T | Nil)，其中T是某种类型；这种类型会出现在可能返回Nil的方法中。这也称为变量可为 nil。

foo : String = "Hello"
foo = nil # Error: type must be String, not (String | Nil)

foo : (String | Nil) = "Hello"
foo = nil

联合类型不限于两种，可以是任意多种。

foo : (String | Int32 | Nil | Float64) = "Hello"
foo = 1
foo = nil
foo = 1.0

typeof vs Object#class

获取变量类型有两种方式：使用typeof，或者使用Object#class。区别在于，typeof返回变量在编译时的类型，而Object#class返回运行时的类型。这意味着，如果你想判断一个变量是不是联合类型，Object#class无法告诉你答案，因为它只返回运行时的类型，而运行时只有一个类型。

foo = 0 == 0 ? "a" : 1
typeof(foo) # => (String | Int32)
foo.class # => String

联合类型的运算

由于联合类型在运行时是单一类型，所有标准运算都可以作用于它。但在编译代码时，编译器需要知道它究竟是哪一种类型。因此，在使用特定类型的运算时，代码必须组织成能够确定它只能是其中某一种类型的形式。

foo : (String | Int32) = "Hello"
foo.downcase # Error: undefined method 'downcase' for (String | Int32)

Crystal 确实为联合类型提供了一个专门的方法：is_a?方法，它接收一个类型作为实参，并返回布尔值。nil?方法是is_a?(Nil)的简写。把is_a?方法放进控制表达式，就能告诉编译器它是哪一种类型，从而保证它确实是该类型。而在 else 分支中，则可以保证它不是该类型。

foo : (String | Int32) = "Hello"
if foo.is_a?(String)
  typeof(foo)  # => String
  foo.downcase # => "hello"
end

is_a?不限于接收单一类型作为实参，也可以接收联合类型。它还可以用&&组合多个类型。

as

把联合类型变成单一类型的一种方法，是让某个分支只有在类型为特定类型时才能进入。另一种方法是使用as方法。它通过运行时检查把联合类型变成单一类型。如果类型不是预期的类型，就会抛出异常。

foo : String | Int32 = "Hello"
foo.as(String).downcase # => "hello"

foo.as(Int32) # Error: can't cast String to Int32

as?

as?的工作方式与as非常相似，但如果类型不是预期的类型，它会返回nil，而不是抛出异常。这意味着它会返回预期类型与Nil组成的联合类型。

foo : (String | Int32) = "Hello"
foo.as?(String).downcase # => "hello"

foo.as?(Int32) # => nil

可为 nil 的简写

可为 nil 意味着变量可以是某种类型，也可以是Nil。这可以写成(T | Nil)。但由于可为 nil 的类型相当常见，所以有一个简写：T?。

# This:
foo : (String | Nil) = "Hello"
foo = nil

# Is the same as:
foo : String? = "Hello"
foo = nil