Κλείδωμα με κωδικό

Η Crystal επιτρέπει σε μια μεταβλητή να αποτελείται από πολλούς τύπους. Αυτό ονομάζεται τύπος ένωσης. Στη Crystal, είναι συνηθισμένο ένας τύπος ένωσης να συμπεραίνεται από τον μεταγλωττιστή.

Ένας τύπος ένωσης δηλώνεται χωρίζοντας τους τύπους με μια κάθετη γραμμή (|). Συχνά τοποθετούνται μέσα σε παρενθέσεις, αλλά αυτό δεν είναι υποχρεωτικό. Ο πιο συνηθισμένος τύπος ένωσης είναι ο (T | Nil), όπου το T είναι ένας τύπος, και μπορεί να εμφανιστεί σε μεθόδους που μπορούν να επιστρέψουν Nil. Αυτό είναι επίσης γνωστό ως nilable μεταβλητή.

foo : String = "Hello"
foo = nil # Error: type must be String, not (String | Nil)

foo : (String | Nil) = "Hello"
foo = nil

Δεν περιορίζεται σε δύο μόνο τύπους, αλλά μπορεί να έχει όσους θέλεις.

foo : (String | Int32 | Nil | Float64) = "Hello"
foo = 1
foo = nil
foo = 1.0

typeof έναντι Object#class

Υπάρχουν δύο τρόποι για να βρεις τον τύπο μιας μεταβλητής. Είτε χρησιμοποιώντας το typeof είτε χρησιμοποιώντας το Object#class. Η διαφορά είναι ότι το typeof επιστρέφει τον τύπο μιας μεταβλητής κατά τον χρόνο μεταγλώττισης, ενώ το Object#class επιστρέφει τον τύπο κατά τον χρόνο εκτέλεσης. Αυτό σημαίνει ότι αν θέλεις να δεις, για παράδειγμα, αν μια μεταβλητή είναι τύπος ένωσης, το Object#class δεν θα μπορέσει να σου το πει, καθώς θα επιστρέψει μόνο τον τύπο κατά τον χρόνο εκτέλεσης, που είναι ένας μόνο τύπος.

foo = 0 == 0 ? "a" : 1
typeof(foo) # => (String | Int32)
foo.class # => String

Πράξεις σε τύπους ένωσης

Εφόσον ένας τύπος ένωσης είναι ένας μόνο τύπος κατά τον χρόνο εκτέλεσης, όλες οι τυπικές πράξεις λειτουργούν πάνω του. Όμως, όταν μεταγλωττίζεται ο κώδικας, ο μεταγλωττιστής θα χρειαστεί να ξέρει ποιος τύπος είναι. Γι' αυτό ο κώδικας πρέπει να είναι γραμμένος με τέτοιον τρόπο ώστε να μπορεί να είναι μόνο ένας από τους τύπους, όταν θέλεις να χρησιμοποιήσεις πράξεις που είναι ειδικές για τον τύπο.

foo : (String | Int32) = "Hello"
foo.downcase # Error: undefined method 'downcase' for (String | Int32)

Η Crystal έχει όντως μια ειδική μέθοδο για τους τύπους ένωσης: τη μέθοδο is_a?, η οποία παίρνει έναν τύπο ως όρισμα και επιστρέφει Boolean (λογική τιμή). Η μέθοδος nil? είναι μια συντόμευση για το is_a?(Nil). Αν τοποθετήσεις τη μέθοδο is_a? σε μια έκφραση ελέγχου, θα πεις στον μεταγλωττιστή ποιος τύπος είναι και έτσι θα εγγυηθείς ότι είναι αυτός ο τύπος. Και στη διακλάδωση else θα είναι εγγυημένο ότι δεν είναι αυτός ο τύπος.

foo : (String | Int32) = "Hello"
if foo.is_a?(String)
  typeof(foo)  # => String
  foo.downcase # => "hello"
end

Αυτό το is_a? δεν περιορίζεται στο να έχει έναν μόνο τύπο ως όρισμα, αλλά μπορεί να δεχτεί και τύπο ένωσης. Μπορεί επίσης να συνδυαστεί με && για πολλούς τύπους.

as

Ένας τρόπος για να μετατρέψεις έναν τύπο ένωσης σε έναν μόνο τύπο είναι να φροντίσεις ώστε μια διακλάδωση να μπορεί να εκτελεστεί μόνο αν ο τύπος είναι κάποιος συγκεκριμένος τύπος. Μια άλλη προσέγγιση είναι να χρησιμοποιήσεις τη μέθοδο as. Αυτή μετατρέπει έναν τύπο ένωσης σε έναν μόνο τύπο κάνοντας έναν έλεγχο κατά τον χρόνο εκτέλεσης. Αν ο τύπος δεν είναι ο αναμενόμενος, θα πεταχτεί μια εξαίρεση.

foo : String | Int32 = "Hello"
foo.as(String).downcase # => "hello"

foo.as(Int32) # Error: can't cast String to Int32

as?

Το as? λειτουργεί με πολύ παρόμοιο τρόπο με το as, αλλά θα επιστρέψει nil αντί να πετάξει εξαίρεση, αν ο τύπος δεν είναι ο αναμενόμενος. Αυτό σημαίνει ότι θα επιστρέψει έναν τύπο ένωσης που αποτελείται από τον αναμενόμενο τύπο και το Nil.

foo : (String | Int32) = "Hello"
foo.as?(String).downcase # => "hello"

foo.as?(Int32) # => nil

Συντομογραφία για nilable

Nilable σημαίνει ότι μια μεταβλητή μπορεί να είναι είτε ένας τύπος είτε Nil. Αυτό μπορεί να γραφτεί ως (T | Nil). Αλλά επειδή οι nilable τύποι είναι σχετικά συνηθισμένοι, υπάρχει μια συντομογραφία γι' αυτό: T?.

# This:
foo : (String | Nil) = "Hello"
foo = nil

# Is the same as:
foo : String? = "Hello"
foo = nil