قفل رمز عبور

Crystal به یک متغیر اجازه می‌دهد که از چندین نوع تشکیل شود. به این «نوع اجتماع» می‌گویند. در Crystal معمول است که یک نوع اجتماع توسط کامپایلر استنتاج شود.

یک نوع اجتماع با جدا کردن نوع‌ها با یک خط عمودی (|) اعلام می‌شود. معمولاً آن‌ها را داخل پرانتز می‌گذارند، اما الزامی نیست. رایج‌ترین نوع اجتماع (T | Nil) است که در آن T یک نوع است و می‌تواند در متدهایی رخ دهد که می‌توانند Nil برگردانند. به این حالت، نیل‌پذیر بودن متغیر هم می‌گویند.

foo : String = "Hello"
foo = nil # Error: type must be String, not (String | Nil)

foo : (String | Nil) = "Hello"
foo = nil

محدود به دو نوع نیست، بلکه می‌تواند هر تعداد نوعی باشد که بخواهید.

foo : (String | Int32 | Nil | Float64) = "Hello"
foo = 1
foo = nil
foo = 1.0

typeof در برابر Object#class

دو راه برای گرفتن نوع یک متغیر وجود دارد. یا با استفاده از typeof یا با استفاده از Object#class. تفاوت این است که typeof نوع متغیر را در زمان کامپایل برمی‌گرداند، در حالی که Object#class نوع را در زمان اجرا برمی‌گرداند. این یعنی اگر بخواهید ببینید آیا یک متغیر نوع اجتماع است، Object#class نمی‌تواند این را به شما بگوید، چون فقط نوع را در زمان اجرا برمی‌گرداند، که یک نوع واحد است.

foo = 0 == 0 ? "a" : 1
typeof(foo) # => (String | Int32)
foo.class # => String

عملیات روی نوع اجتماع

از آنجا که نوع اجتماع در زمان اجرا یک نوع واحد است، همه‌ی عملیات استاندارد روی آن کار می‌کنند. اما هنگام کامپایل کد، کامپایلر باید بداند که کدام نوع است. بنابراین کد باید طوری تنظیم شود که هنگام استفاده از عملیات مخصوص یک نوع، فقط بتواند یکی از آن نوع‌ها باشد.

foo : (String | Int32) = "Hello"
foo.downcase # Error: undefined method 'downcase' for (String | Int32)

Crystal یک متد ویژه برای نوع‌های اجتماع دارد: متد is_a? که یک نوع را به عنوان آرگومان می‌گیرد و یک «مقدار منطقی» برمی‌گرداند. متد nil? میانبری برای is_a?(Nil) است. قرار دادن متد is_a? در یک عبارت کنترلی به کامپایلر می‌گوید که کدام نوع است و در نتیجه تضمین می‌کند که همان نوع است. و برای شاخه‌ی else تضمین می‌شود که آن نوع نیست.

foo : (String | Int32) = "Hello"
if foo.is_a?(String)
  typeof(foo)  # => String
  foo.downcase # => "hello"
end

این is_a? محدود به گرفتن یک نوع واحد به عنوان آرگومان نیست، بلکه می‌تواند یک نوع اجتماع هم بگیرد. همچنین می‌توان آن را با && برای چندین نوع ترکیب کرد.

as

یک راه برای تبدیل نوع اجتماع به یک نوع واحد این است که کاری کنید شاخه فقط زمانی وارد شود که نوع، یک نوع مشخص باشد. رویکرد دیگر استفاده از متد as است. این کار با انجام یک بررسی در زمان اجرا، نوع اجتماع را به یک نوع واحد تبدیل می‌کند. اگر نوع، نوع مورد انتظار نباشد، یک استثنا پرتاب می‌شود.

foo : String | Int32 = "Hello"
foo.as(String).downcase # => "hello"

foo.as(Int32) # Error: can't cast String to Int32

as?

as? بسیار شبیه as کار می‌کند، اما اگر نوع، نوع مورد انتظار نباشد، به جای پرتاب استثنا nil برمی‌گرداند. این یعنی یک نوع اجتماع از نوع مورد انتظار و Nil برمی‌گرداند.

foo : (String | Int32) = "Hello"
foo.as?(String).downcase # => "hello"

foo.as?(Int32) # => nil

کوتاه‌نویسی نیل‌پذیر

نیل‌پذیر یعنی یک متغیر می‌تواند یا یک نوع باشد یا Nil. این را می‌توان به صورت (T | Nil) نوشت. اما چون نوع‌های نیل‌پذیر نسبتاً رایج‌اند، یک کوتاه‌نویسی برایش وجود دارد: T?.

# This:
foo : (String | Nil) = "Hello"
foo = nil

# Is the same as:
foo : String? = "Hello"
foo = nil