パスワードロック

Crystalでは、変数が複数の型を持つことができます。これをユニオン型と呼びます。Crystalでは、コンパイラーがユニオン型を推論するのが一般的です。

ユニオン型は、型をパイプ（|）で区切って宣言します。多くの場合、括弧（()）で囲みますが、必須ではありません。もっともよく見るユニオン型は、Tを型とすると(T | Nil)で、これはNilを返す可能性があるメソッドに現れます。これは、その変数がnil可能であるとも言われます。

foo : String = "Hello"
foo = nil # Error: type must be String, not (String | Nil)

foo : (String | Nil) = "Hello"
foo = nil

型は2つに限らず、いくつでも組み合わせられます。

foo : (String | Int32 | Nil | Float64) = "Hello"
foo = 1
foo = nil
foo = 1.0

typeofとObject#classの違い

変数の型を調べる方法は2つあります。typeofを使うか、Object#classを使うかです。違いは、typeofがコンパイル時に変数の型を返すのに対し、Object#classは実行時に型を返すことです。つまり、たとえば変数がユニオン型かどうかを調べたいとき、Object#classではそれがわかりません。実行時に返るのは1つの型だけだからです。

foo = 0 == 0 ? "a" : 1
typeof(foo) # => (String | Int32)
foo.class # => String

ユニオン型の操作

ユニオン型は実行時には1つの型なので、通常の操作はすべて使えます。ただし、コンパイル時にはコンパイラーがどの型なのかを知っている必要があります。そのため、型ごとの操作を使いたいときは、その型のどれか1つにしかなり得ないようにコードを書く必要があります。

foo : (String | Int32) = "Hello"
foo.downcase # Error: undefined method 'downcase' for (String | Int32)

Crystalには、ユニオン型のための特別なメソッドがあります。is_a?メソッドです。これは型を引数に取り、真偽値を返します。nil?メソッドはis_a?(Nil)の省略形です。is_a?メソッドを制御式の中で使うと、コンパイラーにその型であることを伝えられ、その型であることが保証されます。また、elseの分岐では、その型ではないことが保証されます。

foo : (String | Int32) = "Hello"
if foo.is_a?(String)
  typeof(foo)  # => String
  foo.downcase # => "hello"
end

このis_a?は、引数に1つの型だけでなくユニオン型を取ることもできます。&&と組み合わせて複数の型を指定することもできます。

as

ユニオン型を1つの型にする方法の1つは、特定の型のときだけその分岐に入るようにすることです。もう1つの方法は、asメソッドを使うことです。これは実行時にチェックすることで、ユニオン型を1つの型にします。型が期待したものでなければ、例外が発生します。

foo : String | Int32 = "Hello"
foo.as(String).downcase # => "hello"

foo.as(Int32) # Error: can't cast String to Int32

as?

as?はasとよく似た働きをしますが、型が期待したものでないときに例外を発生させる代わりにnilを返します。つまり、期待した型とNilのユニオン型を返します。

foo : (String | Int32) = "Hello"
foo.as?(String).downcase # => "hello"

foo.as?(Int32) # => nil

nil可能の省略形

nil可能とは、変数が何らかの型かNilのどちらかになり得るという意味です。これは(T | Nil)と書けます。ただし、nil可能な型は比較的よく登場するので、省略形が用意されています。T?です。

# This:
foo : (String | Nil) = "Hello"
foo = nil

# Is the same as:
foo : String? = "Hello"
foo = nil