قفل كلمة المرور

تسمح Crystal للمتغير بأن يتكوّن من أنواع متعددة، ويُسمى هذا نوع الاتحاد. وفي Crystal، من الشائع أن يستنتج المترجم نوع الاتحاد بنفسه.

يُعرَّف نوع الاتحاد بفصل الأنواع بخط عمودي (|). وغالبًا ما تُوضع هذه الأنواع داخل الأقواس الهلالية، لكن ذلك ليس شرطًا. وأكثر أنواع الاتحاد شيوعًا هو (T | Nil) حيث T نوع ما، وقد يظهر في الطرق التي يمكنها إرجاع Nil. ويُعرف هذا أيضًا بأن المتغير قابل لأن يكون Nil.

foo : String = "Hello"
foo = nil # Error: type must be String, not (String | Nil)

foo : (String | Nil) = "Hello"
foo = nil

وهو ليس مقصورًا على نوعين فقط، بل يمكن أن يضم ما تشاء من الأنواع.

foo : (String | Int32 | Nil | Float64) = "Hello"
foo = 1
foo = nil
foo = 1.0

typeof مقابل Object#class

هناك طريقتان لمعرفة نوع المتغير: إما باستخدام typeof أو باستخدام Object#class. والفرق أن typeof تُرجع نوع المتغير في وقت الترجمة، بينما تُرجع Object#class النوع في وقت التشغيل. وهذا يعني أنه إذا أردت معرفة ما إذا كان المتغير من نوع اتحاد، على سبيل المثال، فلن تستطيع Object#class إخبارك بذلك، لأنها تُرجع النوع في وقت التشغيل فقط، وهو نوع واحد.

foo = 0 == 0 ? "a" : 1
typeof(foo) # => (String | Int32)
foo.class # => String

العمليات على أنواع الاتحاد

بما أن نوع الاتحاد نوع واحد في وقت التشغيل، فإن جميع العمليات القياسية تعمل عليه. لكن عند ترجمة الكود سيحتاج المترجم إلى معرفة أي نوع هو. ولذلك يجب أن يُبنى الكود بطريقة تضمن أنه لا يكون إلا أحد الأنواع عند الرغبة في استخدام العمليات الخاصة بنوع بعينه.

foo : (String | Int32) = "Hello"
foo.downcase # Error: undefined method 'downcase' for (String | Int32)

تمتلك Crystal طريقة خاصة لأنواع الاتحاد: طريقة is_a?، التي تأخذ نوعًا كوسيط وتُرجع قيمة منطقية. وطريقة nil? اختصار لـ is_a?(Nil). ووضع طريقة is_a? في تعبير تحكم سيخبر المترجم أي نوع هو، وبذلك يضمن أنه ذلك النوع. وفي فرع else سيضمن أنه ليس ذلك النوع.

foo : (String | Int32) = "Hello"
if foo.is_a?(String)
  typeof(foo)  # => String
  foo.downcase # => "hello"
end

ولا تقتصر is_a? على نوع واحد كوسيط، بل يمكنها أن تأخذ نوع اتحاد أيضًا. ويمكن دمجها أيضًا مع && لعدة أنواع.

as

أحد الأساليب لتحويل نوع الاتحاد إلى نوع واحد هو جعل الدخول إلى فرع معيّن ممكنًا فقط عندما يكون النوع نوعًا محدّدًا. وهناك أسلوب آخر هو استخدام طريقة as. وهي تحوّل نوع الاتحاد إلى نوع واحد عبر إجراء فحص في وقت التشغيل. وسيُرفع استثناء إذا لم يكن النوع هو النوع المتوقع.

foo : String | Int32 = "Hello"
foo.as(String).downcase # => "hello"

foo.as(Int32) # Error: can't cast String to Int32

as?

تعمل as? بشكل مشابه جدًا لـ as، لكنها ستُرجع nil بدلًا من رفع استثناء إذا لم يكن النوع هو النوع المتوقع. وهذا يعني أنها ستُرجع نوع اتحاد من النوع المتوقع وNil.

foo : (String | Int32) = "Hello"
foo.as?(String).downcase # => "hello"

foo.as?(Int32) # => nil

اختصار النوع القابل لـ Nil

النوع القابل لـ Nil يعني أن المتغير يمكن أن يكون إما نوعًا ما أو Nil. ويمكن كتابته على الصورة (T | Nil). ولكن بما أن الأنواع القابلة لـ Nil شائعة نسبيًا، فهناك اختصار لها: T?.

# This:
foo : (String | Nil) = "Hello"
foo = nil

# Is the same as:
foo : String? = "Hello"
foo = nil