生产线

SIMD

单指令多数据（SIMD） 是一种硬件层面的并行方式。CPU 会同时对多个元素执行相同的计算。

例如，考虑把两个各含四个 32 位浮点数的数组逐元素相加。标量实现会发出四条独立的addss指令，每个元素一条。SIMD 实现只用一条addps就并行完成全部四次加法。这样每条指令完成的工作量就变成了四倍。

在 x86-64 汇编中，SIMD 指令通常使用xmm寄存器来执行。其中一些指令处理整数，另一些处理浮点数。

这些整数或浮点数被称为打包数据。每个值都占据同一寄存器中的一块空间，称为通道。SIMD 指令通常会并行处理两个源操作数中处于相同通道位置的值。每次运算的结果存储在目标操作数中相同位置的通道里。

通道并不是硬性限制。它是每条指令对一段字节序列给出的解读。一个 128 位操作数包含 16 个字节。根据指令的不同，这些字节可以被解读为 16 个 1 字节 通道、8 个 2 字节 通道、4 个 4 字节 通道、2 个 8 字节 通道，甚至单个 16 字节 通道。

例如，addps指令把打包的单精度（4 字节）浮点值相加。对这条指令而言，操作数中每个 4 字节的数据块就是一条不同的通道。在一个 128 位宽（16 字节）的操作数中：

而在mulpd的情况下，一个 128 位操作数会被解读为只有 2 条通道。这是因为该指令对双精度（8 字节）值做打包乘法：

本节我们将重点介绍一小部分 SIMD 指令。它们使用xmm寄存器对打包的浮点值进行运算。

浮点 SIMD 指令

一般来说，处理浮点值的 SIMD 指令采用双操作数形式。它们的名称遵循一定的结构：

1. 所执行的操作，名称与非 SIMD（也称 标量）版本相同（例如add、mul等）。
2. 一个后缀p，表示该指令处理 打包 数据，位置与之前的s（表示 标量 数据）相同。
3. 一个后缀，表示每条通道的大小，语义与非 SIMD 版本相同（s表示单精度，d表示双精度）。

因此，打包名称可以由标量名称得到：把助记符中间的s（标量）替换为p（打包）。操作名和大小后缀保持不变：

算术运算

算术 SIMD 指令遵循上面的规则。来看几个例子：

addps xmm0, xmm1 ; xmm0 = xmm0 + xmm1 (each 32-bit float at the same position)
subpd xmm2, xmm3 ; xmm2 = xmm2 - xmm3 (each 64-bit float at the same position)
mulps xmm4, xmm5 ; xmm4 = xmm4 * xmm5 (each 32-bit float at the same position)
divpd xmm6, xmm7 ; xmm6 = xmm6 / xmm7 (each 64-bit float at the same position)

精度之间的转换

还有一些 SIMD 指令，用于在打包的单精度浮点值和打包的双精度浮点值之间转换。它们遵循相同的命名规则，把表示 标量 的s替换为表示 打包 的p：

这些指令印证了前面提到的观点：通道是一种解读，而不是硬性限制。源操作数和目标操作数的通道大小不同，因此通道数量也不同。

对于cvtps2pd，源操作数（ps）有 4 条单精度通道。目标操作数（pd）有 2 条双精度通道。只会读取源操作数的低 2 条通道，高 2 条则被忽略：

对于cvtpd2ps，源操作数（pd）有 2 条双精度通道。目标操作数（ps）有 4 条单精度通道。源操作数的两条通道都会被转换，并写入目标操作数的低 2 条通道。目标操作数的高 2 条通道则置为零：

来看几个例子：

cvtps2pd xmm0, xmm1 ; xmm0 = xmm1 as 2 doubles (low 2 lanes of xmm1 are read)
cvtpd2ps xmm0, xmm1 ; xmm0 = xmm1 as 2 floats (in low 2 lanes; upper 2 zeroed)

内存操作数

上面这些 SIMD 指令展示的都是寄存器到寄存器的操作数。它们也可以把内存操作数作为源操作数（但不能作为目标操作数）。

从内存读取的字节数由指令决定。例如，addps读取 16 个字节（4 个单精度浮点数）。相比之下，cvtps2pd只读取 8 个字节（2 个单精度浮点数），因为它需要的输入就这么多。

addps    xmm0, [rsi]      ; xmm0 = xmm0 + 4 floats at [rsi]
mulpd    xmm1, [rsi + 16] ; xmm1 = xmm1 * 2 doubles at [rsi + 16]
cvtps2pd xmm2, [rsi + 8]  ; xmm2 = (2 floats at [rsi + 8]) converted to 2 doubles

当内存操作数宽 16 字节时，它必须_按 16 字节对齐_。所谓对齐的内存位置，是指地址为该操作大小（这里是 16 字节）整数倍的位置。

要声明对齐的内存，可以在 section .data 和 .rodata 上使用align指示符，或在 section .bss 上使用alignb：

section .rodata
align 16
mem1: dd 4.0, 3.5, 2.0, -1.0

section .data
align 16
mem2: dq 6.0, 2.1

section .bss
alignb 16
mem3: resb 16

section .text
fn:
    movaps xmm0, oword [rel mem1] ; loads 4 packed 32-bit floats in xmm0
    movapd xmm1, oword [rel mem2] ; loads 2 packed 64-bit floats in xmm1
    movaps oword [rel mem3], xmm0 ; stores 4 packed 32-bit floats in mem3
    ret

小于 16 字节的内存操作数，例如cvtps2pd的 8 字节源操作数，没有对齐要求。

加载与存储数值

有四条指令用于复制 128 位的打包浮点值。它们在两个xmm寄存器之间操作，或者在一个xmm寄存器和一个内存位置之间操作：

这些指令都可以用来在两个xmm寄存器之间复制数值。

如果操作涉及内存位置，movaps和movapd要求它必须是_对齐_的。如果给出的地址未对齐，movaps和movapd会触发故障。它们同时也起到安全检查的作用，确保你的数据布局和你想的一致。

而movups和movupd则可以用于任何内存位置，无论是否对齐。

在 NASM 中，16 字节值的大小前缀是oword。

SIMD 扩展

几十年来，SIMD 一直是 x86-64 生态中活跃开发的领域。架构的每一次扩展都会带来新指令，或者让旧指令有新用法。

具体来说，AVX 和 AVX2 扩展带来了一些相关的变化。

第一，支持名为ymm的 256 位 SIMD 寄存器。它们扩展了对应的xmm寄存器，就像rax包含eax那样。

第二，对于大多数操作xmm（以及ymm）寄存器的指令，它们支持三操作数变体。这不仅包括 SIMD 指令，也包括处理标量浮点值的指令。这些变体的记法与对应的 SSE 版本相同，只是在前面加上一个v：

vaddsd xmm0, xmm1, xmm2   ; xmm0 = xmm1 + xmm2 (scalar sum of 64-bit floats)
vmulps xmm1, xmm3, xmm4   ; xmm1 = xmm3 * xmm4 (packed multiplication of 32-bit floats)
vmovupd ymm5, yword [mem] ; this copies 32 bytes from the location at mem to ymm5

第三，对 SIMD 内存操作数的对齐要求放宽了。只有显式对齐的移动指令，例如vmovaps，才要求这种对齐。

在本课程中，我们只限定使用到此前 SSE 扩展为止的指令和寄存器。这足以讲解基础知识，并确保与众多 CPU 兼容。

不过，测试运行器完全支持 AVX 和 AVX2，甚至支持属于 AVX-512 的更新扩展。你可以随意使用它们。