生產線

SIMD

**單指令多資料（SIMD）**是一種硬體層級的平行處理。 CPU 會在同一時間對多個元素執行相同的運算。

舉例來說，試想將 2 個各含 4 個 32 位元浮點數的陣列逐元素相加。 純量實作會發出 4 道獨立的addss指令，每個元素各一道。 SIMD 實作則使用單一個addps，平行完成全部 4 次加法。 這相當於每道指令完成 4 倍的工作量。

在 x86-64 組合語言中，SIMD 指令通常使用xmm暫存器來執行。 其中一些指令處理整數。 另一些則處理浮點數。

這些整數或浮點數稱為打包值。 每一個都佔用同一個暫存器內的一個空間，稱為通道。 SIMD 指令通常會平行處理兩個來源運算元中位於相同通道位置的值。 每次運算的結果會存入目的運算元中相同位置的通道。

通道並不是硬性限制。 它是每道指令對一串位元組所做的解讀。 一個 128 位元的運算元包含 16 個位元組。 視指令而定，這些位元組可以解讀為 16 個 _1 位元組_通道、8 個 _2 位元組_通道、4 個 _4 位元組_通道、2 個 _8 位元組_通道，甚至單一個 _16 位元組_通道。

舉例來說，addps指令會將打包的單精度（4 位元組）浮點數相加。 對這道指令而言，運算元中每個 4 位元組的區塊各自屬於不同的通道。 在一個 128 位元寬（16 位元組）的運算元中：

另一方面，在mulpd的情況下，一個 128 位元的運算元會被解讀為具有 2 個通道。 這是因為這道指令對雙精度（8 位元組）的值執行打包乘法：

在這個概念中，我們會聚焦於一小部分的 SIMD 指令。 它們使用xmm暫存器來處理打包的浮點數值。

浮點數 SIMD 指令

大致說來，處理浮點數值的 SIMD 指令採用雙運算元形式。 它們的名稱遵循一定的結構：

1. 所執行的運算，其名稱與非 SIMD（也稱為_純量_）的對應指令相同（例如add、mul等）。
2. 一個後綴p，表示這道指令處理的是_打包_資料，位置就在原本s（代表_純量_資料）所在之處。
3. 一個表示每個通道大小的後綴，其語意與非 SIMD 對應指令相同（s代表單精度，d代表雙精度）。

因此，打包名稱的取得方式，就是把助憶符中間代表純量的s換成代表打包的p。 運算名稱與大小後綴則維持不變：

算術運算

算術 SIMD 指令遵循上述規則。 一些例子：

addps xmm0, xmm1 ; xmm0 = xmm0 + xmm1 (each 32-bit float at the same position)
subpd xmm2, xmm3 ; xmm2 = xmm2 - xmm3 (each 64-bit float at the same position)
mulps xmm4, xmm5 ; xmm4 = xmm4 * xmm5 (each 32-bit float at the same position)
divpd xmm6, xmm7 ; xmm6 = xmm6 / xmm7 (each 64-bit float at the same position)

精度之間的轉換

也有 SIMD 指令可以在打包的單精度與打包的雙精度浮點數之間進行轉換。 它們遵循相同的命名規則，把代表_純量_的s換成代表_打包_的p：

這些指令印證了先前的論點：通道是一種解讀，而不是硬性限制。 來源與目的運算元有不同的通道大小，因此通道數量也不同。

對cvtps2pd而言，來源（ps）有 4 個單精度通道。 目的（pd）有 2 個雙精度通道。 只會讀取來源中較低的 2 個通道。 較高的 2 個通道會被忽略：

對cvtpd2ps而言，來源（pd）有 2 個雙精度通道。 目的（ps）有 4 個單精度通道。 來源的兩個通道都會被轉換，並寫入目的中較低的 2 個通道。 目的中較高的 2 個通道會設為零：

一些例子：

cvtps2pd xmm0, xmm1 ; xmm0 = xmm1 as 2 doubles (low 2 lanes of xmm1 are read)
cvtpd2ps xmm0, xmm1 ; xmm0 = xmm1 as 2 floats (in low 2 lanes; upper 2 zeroed)

記憶體運算元

上述的 SIMD 指令都是以暫存器對暫存器運算元來示範。 它們也可以接受記憶體運算元作為來源（但不能作為目的）。

從記憶體讀取的位元組數量由指令決定。 舉例來說，addps會讀取 16 個位元組（4 個單精度浮點數）。 相較之下，cvtps2pd只讀取 8 個位元組（2 個單精度浮點數），因為這就是它所需的全部輸入。

addps    xmm0, [rsi]      ; xmm0 = xmm0 + 4 floats at [rsi]
mulpd    xmm1, [rsi + 16] ; xmm1 = xmm1 * 2 doubles at [rsi + 16]
cvtps2pd xmm2, [rsi + 8]  ; xmm2 = (2 floats at [rsi + 8]) converted to 2 doubles

當記憶體運算元寬達 16 位元組時，就必須是_16 位元組對齊_。 所謂對齊的記憶體位置，是指其位址為該運算大小的倍數（在此例中為 16 位元組）。

若要宣告對齊的記憶體，你可以在 .data 與 .rodata 區段上使用align指示詞，或在 .bss 區段上使用alignb：

section .rodata
align 16
mem1: dd 4.0, 3.5, 2.0, -1.0

section .data
align 16
mem2: dq 6.0, 2.1

section .bss
alignb 16
mem3: resb 16

section .text
fn:
    movaps xmm0, oword [rel mem1] ; loads 4 packed 32-bit floats in xmm0
    movapd xmm1, oword [rel mem2] ; loads 2 packed 64-bit floats in xmm1
    movaps oword [rel mem3], xmm0 ; stores 4 packed 32-bit floats in mem3
    ret

小於 16 位元組的記憶體運算元，例如cvtps2pd的 8 位元組來源，則沒有對齊要求。

載入與儲存值

有四道指令會複製 128 位元的打包浮點數值。 它們作用於兩個xmm暫存器之間，或一個xmm暫存器與一個記憶體位置之間：

上述所有指令都可以用來在兩個xmm暫存器之間複製值。

如果運算涉及記憶體位置，movaps與movapd會要求該位置必須_對齊_。 若給定未對齊的位址，movaps與movapd會引發錯誤。 它們同時也扮演安全檢查的角色，確認你的資料配置正如你所想。

另一方面，movups與movupd則可搭配任何記憶體位置使用，無論是否對齊。

在 NASM 中，16 位元組值的大小前綴是oword。

SIMD 擴充

數十年來，SIMD 一直是 x86-64 生態系中積極發展的目標。 架構的每一次擴充，都會帶來新指令，或是舊指令的新用途。

特別是 AVX 與 AVX2 這兩個擴充，帶來了一些相關的變革。

首先，支援稱為ymm的 256 位元 SIMD 暫存器。 它們會擴充對應的xmm暫存器，就像rax包含eax一樣。

其次，它們為大多數處理xmm（以及ymm）暫存器的指令，加入了三運算元變體的支援。 這不僅包括 SIMD 指令，也包括處理純量浮點數值的指令。 這些變體沿用其 SSE 對應指令的相同標記法，並在前面加上一個v：

vaddsd xmm0, xmm1, xmm2   ; xmm0 = xmm1 + xmm2 (scalar sum of 64-bit floats)
vmulps xmm1, xmm3, xmm4   ; xmm1 = xmm3 * xmm4 (packed multiplication of 32-bit floats)
vmovupd ymm5, yword [mem] ; this copies 32 bytes from the location at mem to ymm5

第三，SIMD 記憶體運算元所要求的對齊變得寬鬆了。 只有像vmovaps這樣明確對齊的搬移指令，才會要求這種對齊。

在這個 track 中，我們限定只使用到先前 SSE 擴充為止的指令與暫存器。 這足以傳授基礎知識，並確保與各式各樣的 CPU 相容。

不過，test-runner 完整支援 AVX 與 AVX2，甚至支援屬於 AVX-512 的較新擴充。 你可以自由使用它們。