生産ライン

SIMD

**Single instruction, multiple data（SIMD）**は、ハードウェアレベルでの並列性の一形態です。 CPUは同じ計算を、複数の要素に対して同時に実行します。

たとえば、32ビットの浮動小数点数4つからなる2つの配列を、要素ごとに足し合わせることを考えてみましょう。 スカラーでの実装では、要素ごとにaddss命令を4つ別々に発行することになります。 SIMDでの実装では、1つのaddpsで4つの加算をまとめて並行に行います。 これにより、1命令あたり4倍の仕事をこなせます。

x86-64アセンブリでは、SIMD命令は通常xmmレジスタを使って実行されます。 これらの命令には、整数を扱うものもあれば、浮動小数点数を扱うものもあります。

こうした整数や浮動小数点数は、パックドと呼ばれます。 それぞれは、同じレジスタ内でレーンと呼ばれる区画を1つ占めます。 SIMD命令は通常、2つのソースオペランドをまたいで、同じレーン位置にある値を並行して処理します。 各演算の結果は、デスティネーションオペランドの同じ位置にあるレーンに格納されます。

レーンは、あらかじめ決まった区切りではありません。 命令それぞれが、バイトの並びに与える解釈です。 128ビットのオペランドには16バイトが入っています。 命令によって、これらのバイトは16個の_1バイト_レーン、8個の_2バイト_レーン、4個の_4バイト_レーン、2個の_8バイト_レーン、あるいは1個の_16バイト_レーンとして解釈できます。

たとえば、命令addpsはパックド単精度（4バイト）の浮動小数点数を加算します。 この命令では、オペランド内の4バイトごとのまとまりがそれぞれ別のレーンになります。 128ビット幅（16バイト）のオペランドでは、次のようになります。

一方、mulpdの場合、128ビットのオペランドは2つのレーンを持つものとして解釈されます。 この命令は、パックド倍精度（8バイト）の値に対して乗算を行うからです。

このコンセプトでは、SIMD命令の中からいくつかを選んで詳しく見ていきます。 それらはxmmレジスタを使い、パックド浮動小数点数を扱います。

浮動小数点SIMD命令

おおよその目安として、浮動小数点数を扱うSIMD命令は2オペランド形式をとります。 その名前は、次のような構造に従っています。

1. 行われる演算の名前です。SIMDでないほう（_スカラー_とも呼ばれます）の対応する命令と同じ名前になります（例：add、mulなど）。
2. 命令が_パックド_データを扱うことを示す接尾辞pです。これは、以前にs（_スカラー_データを表す）が置かれていたのと同じ位置に入ります。
3. 各レーンのサイズを示す接尾辞です。SIMDでないほうの対応する命令と同じ意味を持ちます（sは単精度、dは倍精度）。

したがって、パックド版の名前は、スカラー版の名前のニーモニック中央にあるs（スカラー）をp（パックド）に置き換えることで得られます。 演算名とサイズの接尾辞は変わりません。

算術演算

算術演算のSIMD命令は、上で説明した規則に従います。 いくつか例を示します。

addps xmm0, xmm1 ; xmm0 = xmm0 + xmm1 (each 32-bit float at the same position)
subpd xmm2, xmm3 ; xmm2 = xmm2 - xmm3 (each 64-bit float at the same position)
mulps xmm4, xmm5 ; xmm4 = xmm4 * xmm5 (each 32-bit float at the same position)
divpd xmm6, xmm7 ; xmm6 = xmm6 / xmm7 (each 64-bit float at the same position)

精度間の変換

パックド単精度とパックド倍精度の浮動小数点数を相互に変換するSIMD命令もあります。 これらも同じ命名規則に従い、_スカラー_を表すsがパックドを表すpに置き換わります。

これらの命令は、先ほど述べた「レーンは解釈であり、固定された区切りではない」という点をよく示しています。 ソースオペランドとデスティネーションオペランドではレーンのサイズが異なるため、レーンの数も異なります。

cvtps2pdでは、ソース（ps）は4つの単精度レーンを持ちます。 デスティネーション（pd）は2つの倍精度レーンを持ちます。 ソースの下位2レーンだけが読み取られ、上位2レーンは無視されます。

cvtpd2psでは、ソース（pd）は2つの倍精度レーンを持ちます。 デスティネーション（ps）は4つの単精度レーンを持ちます。 ソースの2つのレーンはどちらも変換され、デスティネーションの下位2レーンに書き込まれます。 デスティネーションの上位2レーンは0に設定されます。

いくつか例を示します。

cvtps2pd xmm0, xmm1 ; xmm0 = xmm1 as 2 doubles (low 2 lanes of xmm1 are read)
cvtpd2ps xmm0, xmm1 ; xmm0 = xmm1 as 2 floats (in low 2 lanes; upper 2 zeroed)

メモリオペランド

これまでに見てきたSIMD命令は、すべてレジスタ間のオペランドを使っていました。 これらの命令は、ソースとしてメモリオペランドを取ることもできます（ただし、デスティネーションにはできません）。

メモリから読み取るバイト数は、命令によって決まります。 たとえばaddpsは16バイト（単精度の浮動小数点数4つ）を読み取ります。 一方cvtps2pdは、8バイト（単精度の浮動小数点数2つ）だけを読み取ります。必要な入力がそれだけだからです。

addps    xmm0, [rsi]      ; xmm0 = xmm0 + 4 floats at [rsi]
mulpd    xmm1, [rsi + 16] ; xmm1 = xmm1 * 2 doubles at [rsi + 16]
cvtps2pd xmm2, [rsi + 8]  ; xmm2 = (2 floats at [rsi + 8]) converted to 2 doubles

メモリオペランドの幅が16バイトの場合、そのアドレスは_16バイト境界に整列_していなければなりません。 整列したメモリ位置とは、アドレスが演算のサイズ（この場合は16バイト）の倍数になっている位置のことです。

整列したメモリを宣言するには、.dataセクションと.rodataセクションではalignディレクティブを、.bssセクションではalignbを使います。

section .rodata
align 16
mem1: dd 4.0, 3.5, 2.0, -1.0

section .data
align 16
mem2: dq 6.0, 2.1

section .bss
alignb 16
mem3: resb 16

section .text
fn:
    movaps xmm0, oword [rel mem1] ; loads 4 packed 32-bit floats in xmm0
    movapd xmm1, oword [rel mem2] ; loads 2 packed 64-bit floats in xmm1
    movaps oword [rel mem3], xmm0 ; stores 4 packed 32-bit floats in mem3
    ret

cvtps2pdの8バイトのソースのように、16バイトより小さいメモリオペランドには整列の要件はありません。

値のロードとストア

パックド浮動小数点数を128ビット分コピーする命令が4つあります。 これらは2つのxmmレジスタ間、または1つのxmmレジスタとメモリ位置の間で動作します。

これらの命令はすべて、2つのxmmレジスタ間で値をコピーするのにも使えます。

演算がメモリ位置を伴う場合、movapsとmovapdはそのアドレスが_整列_していることを要求します。 movapsとmovapdは、整列していないアドレスが渡されるとフォールトを発生させます。 これは、データの配置が思い描いていたとおりになっているかを確認する安全チェックも兼ねています。

一方、movupsとmovupdは、整列していてもいなくても、どのメモリ位置に対しても使えます。

NASMで16バイトの値に付けるサイズ接頭辞はowordです。

SIMD拡張

SIMDは、何十年にもわたってx86-64エコシステムで活発に開発が続けられてきた領域です。 アーキテクチャへの拡張はそれぞれ、新しい命令や、既存の命令の新しい使い方をもたらします。

とくに、AVXとAVX2という拡張では、いくつか重要な変更が導入されています。

第一に、ymmと呼ばれる256ビットのSIMDレジスタがサポートされました。 これらは対応するxmmレジスタを拡張したもので、ちょうどraxがeaxを含んでいるのと同じ関係です。

第二に、xmm（およびymm）レジスタを扱うほとんどの命令に、3オペランドの変種が加わりました。 これはSIMD命令だけでなく、スカラーの浮動小数点数を扱う命令にも当てはまります。 これらの変種は、対応するSSEの命令と同じ表記に従い、先頭にvが付きます。

vaddsd xmm0, xmm1, xmm2   ; xmm0 = xmm1 + xmm2 (scalar sum of 64-bit floats)
vmulps xmm1, xmm3, xmm4   ; xmm1 = xmm3 * xmm4 (packed multiplication of 32-bit floats)
vmovupd ymm5, yword [mem] ; this copies 32 bytes from the location at mem to ymm5

第三に、SIMDのメモリオペランドに求められる整列が緩和されました。 この整列を要求するのは、vmovapsのように明示的に整列を指定する移動命令だけです。

このトラックでは、扱う命令とレジスタを、以前のSSE拡張までのものに限定しています。 これは基礎を教えるのに十分であり、幅広いCPUとの互換性も確保できます。

ただし、テストランナーはAVXとAVX2、さらにはAVX-512に含まれる新しい拡張まで完全にサポートしています。 自由に使ってかまいません。